複数htmlファイル内の特定のテキストに番号を付ける

質問

たとえば
test001.html
test002.html
test003.html
.
.
.

という風な複数HTML内にある特定のテキスト
image.jpgをHTMLの番号に合わせてimage001.jpgという風に番号を付けていきたいのです。

test001.html内のテキストimage.jpg→image001.jpg
test002.html内のテキストimage.jpg→image002.jpg
test003.html内のテキストimage.jpg→image003.jpg
.
.
.

こんな感じに自動で置換していきたいのですが
なにか出来る方法はあるのでしょうか？
その部分だけを変えてHTMLを複製していく形でもかまいません。

SEの人がエクセルを駆使して作っているのを見たことがあるのですが、自分にはまったくわかりませんでした・・・
一応Dreamweaverを使っていますが、出来るのであればどんなソフトでもかまいません。
よろしくお願いいたします。

回答No.1

BLUEPIXY · ベストアンサー

VBScriptは使える環境（Windows）でしょうか？
もしそうなら
以下の部分をchange.vbsとか名前をつけて保存し、
test001.htmlとかのファイルをまとめて選択してchange.vbsにドロップしてください。
------8<------8<------8<------8<------8<------8<------8<------8<-----
'ドロップしたファイルのimage.jpgを置き換える
'test001.html の場合image001.jpg
Dim fso, wsho, file, fileList
Dim tempFile, outFile, readFile
Dim strLine, fileName
Dim regEx, matches, NO

Set fileList =WScript.Arguments 'ドロップしたファイルのリスト
Set fso = WScript.CreateObject("Scripting.FileSystemObject")
Set wsho = WScript.CreateObject("WScript.Shell")
Set regEx = New RegExp
regEx.pattern="\d+$"
For Each file in fileList
tempFile = fso.BuildPath(fso.GetParentFolderName(file), fso.GetTempName)
fileName=fso.GetBaseName(file)' c:\work\test001.html→test001
If regEx.Test(fileName) then 'マッチするか
Set matches =regEx.Execute(fileName)
NO = matches(0).Value '数字の部分を取り出す
Set outFile = fso.CreateTextFile(tempFile, true) '作業ファイルを作る
Set readFile = fso.OpenTextFile(file)
Do until readFile.AtEndOfStream
strLine = readFile.ReadLine '一行読み出し
strLine = Replace(strLine, "image.jpg", "image" & NO & ".jpg")'置換
outFile.WriteLine(strLine)
loop
readFile.Close
outFile.Close
Set file=fso.GetFile(file)
fileName = file.Name '元のファイル名の保存
file.Delete '元のファイルを削除
Set file=fso.GetFile(tempFile)
file.Name=fileName '作業ファイルを元のファイルにリネームする
end if
next

お礼

BLUEPIXYさん
早速の返答ありがとうございます
OSはWindowsXPを使っています。
ファイルを作って実験してみたところ
見事に置換されていました。

わざわざスクリプトを書いていただいてありがとうございました。
早速つかわせていただきたいと思います。