左側数字と同じ位置の右側で数字のチェック方法は？

質問

いつも大変お世話になっております。
ご存知の方はぜひ回答をよろしくお願い致します。

【質問】
A1~E5、G1~K5にそれぞれ25個の1~99迄の数字がランダムに重複無しで入っています。
A1=G1、B1=H1、C1=I1、D1=J1．E1＝K1、A2=G2・・・最後はE5=K5と、
A1~E5からG1~K5と同じ位置にある数字とその数字から８方向の数字と
同じ数字であれば”同じ”、８方向（上、下、左、右、左上、右上、右下、左下）
に同じ数字が上にあれば”上”、下にあれば”下”、左にあれば”左”、
右にあれば”右”、左上にあれば”左上”、右上にあれば”右上”
右下にあれば”右下”、左下にあれば”左下”、
同じ数字が無ければ”無し”とA1~E5の数字をG1~K5でチェックした結果を
A7から下にA1~E5までの数字25個を縦に並べて右側に載せる方法が知りたいです。

〇例題
　　Ａ　Ｂ　Ｃ　Ｄ　Ｅ　Ｆ　Ｇ　Ｈ　Ｉ　Ｊ　Ｋ　
1　11　16　18　20　31　　　12　18　19　22　25
2　03　04　19　26　28　　　03　04　26　17　28
3　02　10　17　22　29　　　01　10　15　29　31
4　05　06　13　21　27　　　02　05　13　14　16
5　01　07　12　23　25　　　06　08　30　23　21

〇結果　とその説明
11：無し　※G1に11があるとみなすと、そもそもG1には12、8方向は03,04,18なので
　　　　　　"無し”。
16：無し　※H1に16があるとみなすと、そもそもH1には18、8方向は12,03,04,26,19
　　　　　　なので、無し”。
18：左　　※I1に18があるとみなすと、そもそもI1には19、8方向は18,04,26,17,22
　　　　　　なので、”左”。
20：無し　※J1に20があるとみなすと、そもそもJ1には22、8方向は19,26,17,28,25
　　　　　　なので、”無し”。
31：無し　※K1に31があるとみなすと、そもそもK1には25、8方向は22,17,28なので、
　　　　　　”無し”。
03：同じ　※G2に03があるとみなすと、そもそもG2には03、8方向は12,18,04,10,01
　　　　　　なので、”同じ”。
04：同じ　※H2に04があるとみなすと、そもそもH2には04、8方向12,18,19,26,15,10,
　　　　　　01,03なので、”同じ”。
19：上　　※I2に19があるとみなすと、そもそもI2には26、8方向は18,19,22,17,29,15,
　　　　　　10,04なので、”上”。
26：左　　※J2に26があるとみなすと、そもそもJ2には17、8方向19,22,25,28,31,29,15,
　　　　　　26なので、”左”。
28：同じ　※K2に28があるとみなすと、そもそもK2には28、8方向は25,22,17,29,31
　　　　　　なので、”同じ”。
02：下　　※G3に02があるとみなすと、そもそもG3には01、8方向は03,04,10,05,02
　　　　　　なので、”下”。
10：同じ　※H3に10があるとみなすと、そもそもH3には10、8方向03,04,26,15,13,03,
　　　　　　02,01なので、”同じ”。
17：右上　※I3に17があるとみなすと、そもそもI3には15、8方向は04,26,17,29,14,13,
　　　　　　05,10なので、”右上”。
22：無し　※J3に22があるとみなすと、そもそもJ3には29、8方向26,17,28,31,16,14,13,
　　　　　　15なので、”無し”。
29：無し　※K3に29があるとみなすと、そもそもK3には31、8方向は28,17,29,14,16
　　　　　　なので、”無し”。
05：右　　※G4に05があるとみなすと、そもそもG4には02、8方向は01,10,05,08,05
　　　　　　なので、”右”。
06：左下　※H4に06があるとみなすと、そもそもH4には05、8方向01,10,15,13,30,08,
　　　　　　06,02なので、”左下”。
13：同じ　※I4に13があるとみなすと、そもそもI4には13、8方向は10,15,29,14,23,30,
　　　　　　08,05なので、”同じ”。
21：右下　※J4に21があるとみなすと、そもそもJ4には14、8方向15,29,31,16,21,23,30,
　　　　　　13なので、”右下”。
27：無し　※K4に27があるとみなすと、そもそもK4には16、8方向は31,29,14,23,21
　　　　　　なので、”無し”。
01：無し　※G5に01があるとみなすと、そもそもG5には06、8方向は02,05,08なので、
　　　　　　”無し”。　　
07：無し　※H5に07があるとみなすと、そもそもH5には08、8方向は06,02,05,13,30
　　　　　　なので、”無し”。
12：無し　※I5に12があるとみなすと、そもそもI5には30、8方向は08,05,13,14,23
　　　　　　なので、”無し”。
23：同じ　※J5に23があるとみなすと、そもそもJ5には23、8方向は30,13,14,16,21
　　　　　　なので、”同じ”。
25：無し　※K5に25があるとみなすと、そもそもK5には21、8方向は16,14,23なので
　　　　　　”無し”。

〇注意事項
　・使用するエクセルは2010です。
　・セルの数字は表示上、2桁で表しています。（例：1ではなく01）
　・セルの数字は毎回、ランダムに変わります。

以上、よろしくお願いします。

回答No.1

HohoPapa · ベストアンサー

暇だったので作ってみました。

複数ヒットした場合
(例えば、右上と下に該当値があった場合）の説明がないように思います。
また、
>29：無し　※K3に29があるとみなすと、そもそもK3には31、8方向は28,17,29,14,16
>　　　　　　なので、”無し”。
とのことですが、
左となるのが正解ではないでしょうか？

Option Explicit

Sub abc()
　Dim MyRow1 As Long
　Dim MyCol1 As Long
　Dim MyRow2 As Long
　Dim MyCol2 As Long
　Dim MyLCnt As Long
　Dim Rng1 As Range
　Dim Rng2 As Range

　For MyLCnt = 0 To 24
　　MyRow1 = Int(MyLCnt / 5) + 1
　　MyCol1 = MyLCnt Mod 5 + 1
　　MyRow2 = Int(MyLCnt / 5) + 1
　　MyCol2 = MyLCnt Mod 5 + 1 + 6
　　With ThisWorkbook.Sheets(1)
　　　Set Rng1 = .Cells(MyRow1, MyCol1)
　　　Set Rng2 = .Cells(MyRow2, MyCol2)
　　　.Cells(MyLCnt + 7, 1).Value = .Cells(MyRow1, MyCol1).Value
　　　.Cells(MyLCnt + 7, 2).Value = getHIkaku(Rng1, Rng2)
　　End With
　Next MyLCnt
End Sub

Function getHIkaku(Rng1 As Range, Rng2 As Range) As String

　getHIkaku = "無し"

　If Rng2.Row <> 1 Then
　　If Rng2.Column <> 1 Then
　　　If Rng1.Value = Rng2.Offset(-1, -1).Value Then
　　　　getHIkaku = "左上"
　　　　Exit Function
　　　End If
　　End If

　　If Rng1.Value = Rng2.Offset(-1, 0).Value Then
　　　getHIkaku = "上"
　　　Exit Function
　　End If

　　If Rng1.Value = Rng2.Offset(-1, 1).Value Then
　　　getHIkaku = "右上"
　　　Exit Function
　　End If
　End If

　If Rng2.Column <> 1 Then
　　If Rng1.Value = Rng2.Offset(0, -1).Value Then
　　　getHIkaku = "左"
　　　Exit Function
　　End If
　End If

　If Rng1.Value = Rng2.Offset(0, 0).Value Then
　　getHIkaku = "同じ"
　　Exit Function
　End If

　If Rng1.Value = Rng2.Offset(0, 1).Value Then
　　getHIkaku = "右"
　　Exit Function
　End If

　If Rng2.Column <> 1 Then
　　If Rng1.Value = Rng2.Offset(1, -1).Value Then
　　　getHIkaku = "左下"
　　　Exit Function
　　End If
　End If

　If Rng1.Value = Rng2.Offset(1, 0).Value Then
　　getHIkaku = "下"
　　Exit Function
　End If

　If Rng1.Value = Rng2.Offset(1, 1).Value Then
　　getHIkaku = "右下"
　　Exit Function
　End If

End Function

補足

新年早々回答を頂きありがとうございます。
今年もよろしくお願いします。
＞複数ヒットした場合
＞(例えば、右上と下に該当値があった場合）の説明がないように思います。
　質問文に書いてましたが、判り難かったですね。
　A1~E5、G1~K5それぞれ1~99迄の数字は”重複無し”で入っている前提ですので
　Ｇ１~Ｋ５で複数ヒットすることは無いです。

>29：無し　※K3に29があるとみなすと、そもそもK3には31、8方向は28,17,29,14,16
>　　　　　　なので、”無し”。とのことですが、左となるのが正解ではないでしょうか？

私が間違っていました。29は”左”が正しいです。