特定のセルに文字が入力されているページの印刷VBA

質問

エクセルＶＢＡで質問が２つあります。
エクセルシートは改ページプレビューでページ毎の印刷範囲が見えるようになっています。

(1)コマンドボックスを押したらＥ４～Ｅ９６３又はＢ４～Ｂ９６３のセルに文字が入力されているページのみ印刷するＶＢＡはどの様にすれば宜しいでしょうか？

(2)コマンドボックスを押すとインプットボックスが表示され、その中に数字を入力したら、その入力されたページのみを印刷するVBAはどの様にすれば宜しいでしょうか？

回答No.3

HohoPapa · ベストアンサー

(1)については、
印刷するページ群が縦方向にのみ並んでいるのであれば、
作業列としてZ列を使う前提で
こんなコードになるんじゃないかと思います。

(2)はすでにNo.2で掲示されたコードでいいんじゃないかと思います。
（どこが期待と異なるのかがわかりません）

Sub Sample1()

　Dim C As HPageBreak
　Dim PageNum As Long
　Dim RowCounter As Long
　Dim PSLine As Long
　Dim PELine As Long
　Dim PrinPage As Long
　Dim PrinSW As Boolean

　Const wkCol = 26　'作業列Z

　'作業列クリアー
　ActiveSheet.Columns(wkCol).ClearContents

　'印刷範囲開始行、終了行を取得
　With Range(ActiveSheet.PageSetup.PrintArea)
　　PSLine = .Rows.Row
　　PELine = PSLine + .Rows.Count - 1
　End With

　'作業列、ページ末行にページ番号を格納
　PageNum = 0
　For Each C In ActiveSheet.HPageBreaks
　　PageNum = PageNum + 1
　　ActiveSheet.Cells(C.Location.Row - 1, wkCol).Value = PageNum
　Next C
　ActiveSheet.Cells(PELine, wkCol).Value = PageNum + 1

　'印刷対象か?を判断して印刷
　PrinSW = False
　With ActiveSheet
　　For RowCounter = PSLine To PELine
　　　'B列orE列がNull以外？
　　　If ((.Cells(RowCounter, 2).Value <> "") Or _
　　　　　(.Cells(RowCounter, 5).Value <> "")) Then
　　　　PrinSW = True
　　　End If
　　　PrinPage = Val(.Cells(RowCounter, wkCol).Value)
　　　If ((PrinSW = True) And _
　　　　　(PrinPage <> 0)) Then
　　　 PrinSW = False
　　　 .PrintOut from:=PrinPage, To:=PrinPage
　　　End If
　　Next RowCounter
　End With

End Sub

お礼

ありがとうございます。
私が求めたVBAでした。