【ACCESS】 VBA

質問

accessのVBAからエクセルファイルを参照する仕組みを作成しています。
エクセルファイルのシート名は数字になっており
下記のように記述するとエラーとなります。対応方法を教えてください。

STR_sheetは1
Set Xls_sheet = Xls_book.Worksheets(STR_sheet)
こうしてみてもダメ
Set Xls_sheet = Xls_book.Worksheets(Format(STR_sheet))

ちなみに、エクセルのシート名は変更不可です。

回答No.2

imogasi

シート名が数字でも数字文字であっても、
エクセルＶＢＡの世界のはなしですが
Sub test02()
s = 2
Worksheets(Trim(Str(s))).Activate
Worksheets("2").Activate
End Sub
（Ｔｒｉｍ関数は、余分な前後の空白を取り除くため。）
のようにすると、うまく行くことからして、それを参考にアクセスでのＶＢＡコードをつくってテストしてください。
Worksheets（数字）はシートの画面のシート名のタブの左からの順番をさすことになり、０はダメだし、シートの数以上の数字を指すと「みつかりません」的エラーになるはず。要注意。
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q1338225338
こういう記事が参考になるのでは。

お礼

シート名が半角＋数字になっていたことがエラーの原因でした。
ご回答ありがとうございました。

回答No.1

mitarashi

回答するには情報が不足しておりますが、エクセルのシート名が1,2,...でも下記コードは問題なく動作しました。当方、Office2010(32bit)、Win7(64bit)です。
ご参考まで。
'Book1.xlsxの一番左のシート名を「2」、二番目のシート名を「1」とする。
Sub test001()
Dim xlApp As Excel.Application
Dim Xls_book As Excel.Workbook
Dim Xls_sheet As Excel.Worksheet
Dim STR_sheet As Long

'普通STR_sheetという変数名には文字列型を割り当てると思うのですが...
STR_sheet = 1
Set xlApp = New Excel.Application
' xlApp.Visible = True
Set Xls_book = xlApp.Workbooks.Open(GetDesktopPath & "\Book1.xlsx")
Set Xls_sheet = Xls_book.Worksheets(STR_sheet)
Debug.Print Xls_sheet.Name
Set Xls_sheet = Xls_book.Worksheets(CStr(STR_sheet))
Debug.Print Xls_sheet.Name
Xls_book.Close savechanges:=False
xlApp.Quit
Set xlApp = Nothing
End Sub
'実行結果
'2
'1

Sub test002()
Dim xlApp As Excel.Application
Dim Xls_book As Excel.Workbook
Dim Xls_sheet As Excel.Worksheet
Dim STR_sheet As String

STR_sheet = "1"
Set xlApp = New Excel.Application
' xlApp.Visible = True
Set Xls_book = xlApp.Workbooks.Open(GetDesktopPath & "\Book1.xlsx")
Set Xls_sheet = Xls_book.Worksheets(STR_sheet)
Debug.Print Xls_sheet.Name
Set Xls_sheet = Xls_book.Worksheets(CLng(STR_sheet))
Debug.Print Xls_sheet.Name
Xls_book.Close savechanges:=False
xlApp.Quit
Set xlApp = Nothing
End Sub

'実行結果
'1
'2

Private Function GetDesktopPath() As String
Dim wScriptHost As Object, strInitDir As String
Set wScriptHost = CreateObject("Wscript.Shell")
GetDesktopPath = wScriptHost.SpecialFolders("Desktop")
Set wScriptHost = Nothing
End Function

お礼

シート名が半角＋数字になっていたことがエラーの原因でした。
ご回答ありがとうございました。