Excel→PPTで日付データを和暦にするには？

質問

以前、OKWAVEさんに掲載されていた質疑
http://okwave.jp/qa/q6023881.html　を参考に、
Excelのデータごとに１枚のPPTスライドをつくって転記するVBAを書きました。

元のエクセルは
A列：姓
B列：名
C列：文字データ
D列：日付データ
E列：整理番号　という５列のデータです。

下記のVBAでうまく動いたのですが、
元のエクセルでは和暦（例：平成28年8月8日）と表記していた
「日付」データ（D列→Lines(4)に該当　が、自動的に2016/08/08　と変換されてしまいます。

文字サイズやフォントの種類をlineごとに指定する方法はわかるのですが
日付のフォーマット変更のやり方がわからず・・・
いろいろと検索して、
Long Date　"gee年mm月dd日"　localdatetime　などがポイントなのかなと思い
いろいろと記述して試したのですが、もともとが初心者なのでうまくいきません。

何かヒントをいただけないでしょうか？

よろしくお願いいたします。

------

Sub ExceltoPowerPoint()
Dim objRng As Range
Dim varRng As Variant
Dim intSNum As Integer
Dim i, j As Integer

Dim PpApp As PowerPoint.Application
Dim PpPrs As PowerPoint.Presentation

Set objRng = Worksheets("Sheet1").Range("A2:E6")
varRng = objRng.Value
Set objRng = Nothing

Set PpApp = CreateObject("PowerPoint.Application")
Set PpPrs = PpApp.Presentations.Add

PpApp.Visible = True

intSNum = 1

For i = 1 To UBound(varRng, 1)
PpPrs.Slides.Add i, ppLayoutBlank

PpPrs.Slides(i).Shapes.AddTextbox msoTextOrientationHorizontal, 0, 0, 710, 540
Next

For i = 1 To UBound(varRng, 1)
For j = 1 To UBound(varRng, 2)
With PpPrs.Slides(intSNum).Shapes(1).TextFrame.TextRange
If j = UBound(varRng, 2) Then
.Text = .Text & CStr(varRng(i, j)) & vbNewLine
intSNum = intSNum + 1
Else
.Text = .Text & CStr(varRng(i, j)) & vbNewLine
End If
End With
Next
Next

For i = 1 To UBound(varRng, 1)
With PpPrs.Slides(i).Shapes(1).TextFrame.TextRange
.Font.NameAscii = "Arial"
.Font.NameFarEast = "HG正楷書体-PRO"
.Font.NameOther = "Arial"
.Lines(1).Font.Size = 44
.Lines(2).Font.Size = 44
.Lines(3).Font.Size = 32
.Lines(4).Font.Size = 32
.Lines(5).Font.Size = 20
End With
Next

MsgBox "処理が終了しました。"

Set PpPrs = Nothing
Set PpApp = Nothing

End Sub

回答No.1

ushi2015 · ベストアンサー

こんにちは
　　If j = UBound(varRng, 2) Then
　　　　.Text = .Text & CStr(varRng(i, j)) & vbNewLine
　　　　intSNum = intSNum + 1
　　Else
　　　　.Text = .Text & CStr(IIf(j = 4, Format(varRng(i, j), "ggge年mm月dd日"), varRng(i, j))) & vbNewLine
　　End If
としてみて下さい。

お礼

ushi2015さま、ありがとうございました。
ばっちりできました。
ほかの列でフォーマット操作するときにも応用できそうです。
もっといろいろ勉強してみますm(__)m

回答No.2

imogasi

エクセルVBAの世界では、下記は確実なので、文字列変数化（下記ではX）して、その段階でPPT（VBA)に渡せばどうですか。
エクセルで、確認テスト用
A1セルに　2016/8/9
A1は日付シリアル値の日付が入っているものとします（文字列とかでないということ。ｐｐｔ側で以後個のデータを日付演算などに使わないという仮定で。また文字列を日付シリアル値化（変換）する関数はあるので、使いたければ使えると思うが）。
標準モジュールに
Sub test01()
x = WorksheetFunction.Text(Range("A1"), "ggge年mm月dd日")
MsgBox x
End Sub
PPTシステム側でも日付は日付シリアル値で持っているかどうかよくわからないので。
（日付は、多分文字列で入力されるのだろう。
エクセル側（セル野値）では、セルの値は「日付シリアル値」で入れてないと、日付書式の設定や日数演算や日付関数利用にうまく使えない。
初めて日付シリアル値とい言葉を聞くようなら、WEBで照会し勉強すること。

お礼

imogasiさま、さっそくのご回答ありがとうございます。
最初は、パワポ側でテキストボックスの表示形式を変えられるのでは・・・と思っていたのですが、文字列で入力されており変更できませんでした。

日付（シリアル値）を（関数で）文字列に変換した日付の列を挿入してからマクロを動かせばいいか、とも考えておりましたが、imogasiさんの教えてくださったモジュールも試しながら勉強してみます。
VBAは初心者にも満たない素人なのですが、みなさんが私の稚拙な説明でも状況を理解してくださって、本当に助かりました。ありがとうございました。