エクセルで空白文字の前後を入れ替えることってできますか？

質問

エクセルでひとつのセルにある文字列の中で、空白の文字列が間にある時、前後を入れ替えた文字列を作りたいのです。
例えば　
UTADA HIKARU
HAMASAKI AYUMI
KURAKI MAI
・・・・・
を
HIKARU UTADA
AYUMI HAMASAKI
MAI KURAKI
・・・
にしたいのです。

なるべく簡単な方法で変換したいのですが・・・・関数を使って出来ないでしょうか。または、マクロを使わないと出来ないでしょうか？(マクロはよく分からないので・・・）
データ数が１００件くらいあるので、上手い方法は無いものでしょうか？宜しくお願いします。

回答No.2

s_yoshi_6 · ベストアンサー

Ａ列にＡ１からデータが入っているとして、例えばＢ１に
=RIGHT(A1,LEN(A1)-FIND(" ",A1))&" "&LEFT(A1,FIND(" ",A1)-1)
と入力して以下コピーでできます。

RIGHT(A1,LEN(A1)-FIND(" ",A1))
は、空白が前から何番目に入っているかを調べて、一番後ろからその後までの文字列を取り出したもの

LEFT(A1,FIND(" ",A1)-1)
は、同じく空白が前から何番目に入っているかを調べて、先頭からその前までの文字列を取り出したもの

上記２つと間の空白を「＆」でつなげたものが上記の式の意味です。

お礼

FIND関数を使った方法もあるのですね。非常に勉強になりました。ありがとうございました。

回答No.3

imogasi

Mid関数利用例
=MID(A1&" "&A1,FIND(" ",A1)+1,LEN(A1))
とか
=MID(A1,FIND(" ",A1)+1,LEN(A1)-FIND(" ",A1))&" " &MID(A1,1,FIND(" ",A1)-1)
前者は例えば「UTADA HIKARU UTADA HIKARU」をつくって
HIKARUのHから真中部を抜き出しする。

お礼

いろいろな方法があるのですね。勉強になりました。
ありがとうございました。

回答No.1

MSZ006

A1セルに入っている文字列を加工する場合、

=MID(A1,SEARCH(" ",A1)+1,99)&" "&LEFT(A1,SEARCH(" ",A1)-1)

という計算式を適当なセルに入力します。

お礼

早々とご回答ありがとうございます。SEARCH関数を使えば出来るのですね。本当に助かりました。