Excel２列の重複チェック（左右逆も）

質問

1 A B
2 C D
3 E F
4 G H
5 D H
6 B A
7 A B
8 Z N
9 A C

ExcelのA列B列に上記のようにアルファベットが記載されているとします。
このときに列ごとに重複が無いかをチェックする関数をご教授頂きたく思います。
単純な重複だけではなく、
ABもBAも同じとして認識するような関数を希望しております。
データの結果として

1 A B
2 C D
3 E F
4 G H
5 D H
6 B A　重複
7 A B　重複
8 Z N
9 A C

このように記載されるか

1 A B
2 C D
3 E F
4 G H
5 D H
6
7
8 Z N
9 A C

このようにデータが消えるかのどちらかのデータがでる形だと助かります。
関数で実現できるのかどうか色々調べましたがまったくわからず、こちらの
方々に助けていただければ幸いです。

回答No.4

keithin · ベストアンサー

あぁ、最初のＡＢが重複じゃないのは間違いじゃなかったんですかね。説明も無かったのでタダの書き漏らしだと判断してました。

Ｃ１：
=IF(COUNTIFS($A$1:A1,A1,$B$1:B1,B1)+COUNTIFS($A$1:A1,B1,$B$1:B1,A1)>1+(A1=B1),"重複","")
以下コピーとかで。

回答No.3

mshr1962

No.2です。すみません。検証したら式が少し違ってました。

=IF(SUMPRODUCT(((($A$1:$A1&$B$1:$B1=$A1&$B1)+($A$1:$A1&$B$1:$B1=$B1&$A1)-($A$1:$A1=$B$1:$B1))>0)*1)>1,"重複","")

が正解です。
これで　A　A　の様にA,B列が同じアルファベットでも最初の行を除いて重複がでます。

回答No.2

mshr1962

関数で消すのは出来ません。やるとしたら条件付き書式でセルの背景色と文字色を同じにして見えなくする位ですね。

重複とC列に表示でいいなら、C1の数式は

=IF(SUMPRODUCT(($A$1:$A1&$B$1:$B1=$A1&$B1)+($A$1:$A1&$B$1:$B1=$B1&$A1)-($A$1:$A1=$B$1:$B1))>1,"重複","")

でこれを下方にコピーしてください。

回答No.1

keithin

ご利用のエクセルのバージョンが不明ですが、エクセル２００７以降を使い
Ｃ１：
=IF(COUNTIFS(A:A,A1,B:B,B1)+COUNTIFS(A:A,B1,B:B,A1)>1,"重複","")
以下コピーします。