ifステートメント 大文字も小文字も区別なく

質問

Sub test()
Dim moji As String
moji = "a"
If moji = "A" Then
MsgBox "Aかaです"
End If
End Sub

これだと、変数が小文字のaだからmsgboxが表示されません。

小文字も大文字も区別なく認識させるにはどうすればいいでしょうか？
バイナリモードになってるようです。

Replace関数の場合は、vbTextCompareを付ければ
Sub Sample()
Dim moji As String
moji = "ａ"
Debug.Print Replace(moji, "A", "b", , , vbTextCompare)
End Sub

このように大文字小文字区別なく置換できますが
このような事をifステートメントでやる方法を教えてください。

回答No.2

cj_mover · ベストアンサー

こんにちは
TectCompareを実現したい
というのと
大文字小文字を分けずに比較したい
というのは少し意味が違います。
前者は[大文字|小文字][全角|半角][ひらがな|カタカナ]などを
区別しないで比較するという意味ですから、
　A　a　Ａ　ａ
皆、同じ、ということになります。
まず、TextCompareの例。
StrComp関数を使います。

Sub test1c()
Dim moji As String
moji = "a"
If StrComp("A", moji, vbTextCompare) = 0 Then
MsgBox "AかaかＡかａです"
End If
End Sub

「文字数が同じであることを前提にできる場合」や
「文字列に含まれるかを問う場合」などは
InStr関数を優先的に使うことが多いです。

Sub test2c()
Dim moji As String
moji = "a"
If InStr("A", moji, vbTextCompare) Then ' 目的に合わせて↓使い分け
' If InStr("A", moji, vbTextCompare) > 0 Then
' If InStr("A", moji, vbTextCompare) = 1 Then
MsgBox "AかaかＡかａです"
End If
End Sub

もうひとつは、
モジュールの先頭に
Option Compare Text
と宣言しておいて
Like演算子を使う例。

Sub test3c()
Dim moji As String
moji = "a"
If moji Like "A" Then
MsgBox "AかaかＡかａです"
End If
End Sub

次に
[大文字|小文字]だけを分けずに比較するということならば
UCase関数やLCase関数（←どちらでも同じ）を両辺に使うこともあります。

Sub test4c()
Dim moji As String
moji = "a"
If UCase(moji) = UCase("A") Then
MsgBox "Aかaです"
End If
End Sub

似たような記述ですが、より応用力が高い方法として
StrConv関数を使うこともあります。
単一の文字コードのみ扱ってる場合は、
こういう書き方はあまりしませんけれど。

Sub test5c()
Dim moji As String
moji = "a"
If StrConv(moji, vbUpperCase) = StrConv("A", vbUpperCase) Then
MsgBox "Aかaです"
End If
End Sub

上に挙げた例、すべて使い途が違いますから、
一通り"引き出し"に揃えて置いた方が良いです。
目的に応じて「必要なこと」「十分なこと」を確認しながら
使い分けるように出来たら理想ですね。

とりあえず、以上です。

お礼

ありがとうございました。

回答No.1

KURUMITO

次のようにすればよいでしょう。

Sub test()
Dim moji As String
moji = "a"
If UCase(moji) = "A" Then
MsgBox "Aかaです"
End If
End Sub

お礼

ありがとうございました。