配列数式の怪

質問

お世話になります。
配列数式の入力方法にて解せない部分がありましたのでご教示願います。
ソフトウェア開発の工数見積をしようと思って、Excel2003で添付の様な
WBSを作りました。

ここで、機能１～３を実装するか否かをD2～F2に○で指定し、
各機能毎に必要な作業項目をD3～F6でマッピングしました。
※５は作業対象の工数合計で、
=SUMIF(C3:C6,"○",B3:B6)
になっています。
（実際には、機能、作業項目共に数十項目のマトリクスになってます）

各作業項目１～４が見積対象になるかどうかを実装する機能に従って
表示しようと思って、C3～C6に配列数式を使って
※１：{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
※２：{=IF(SUM(($D$2:$F$2="○")*(D4:F4="○"))>0,"○","")}
※３：{=IF(SUM(($D$2:$F$2="○")*(D5:F5="○"))>0,"○","")}
※４：{=IF(SUM(($D$2:$F$2="○")*(D6:F6="○"))>0,"○","")}
と入力しようと思いましたが、どう入力しても下記の様に行番号を可変に
したいところが全て同じ行番号になってしまいます。（D3:F3）
※１：{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
※２：{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
※３：{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
※４：{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
ここで、例えば※２のD3:F3だけをD4:F4に変えても他の行も全てD4:F4に
変わってしまいます。

いろいろと試行錯誤した結果、一旦全て削除してまっさらな状態から
※１に{=IF(SUM(($D$2:$F$2="○")*(D3:F3="○"))>0,"○","")}
を入力した後に１行開けて※３にコピーしたところ、無事に
D3:F3がD5:F5に変わりました。

そこで、その後に
※２に{=IF(SUM(($D$2:$F$2="○")*(D4:F4="○"))>0,"○","")}
を入力した後に※４にコピーして目的を達成できました。
（実際には、奇数行、偶数行でそれぞれ数十行ずつのコピーをしました）

これは、配列数式入力時の仕様なのでしょうか？
また、本来はどの様に入力するのが正解なのでしょうか？

回答No.1

keithin · ベストアンサー

Ｃ３：Ｃ６を選んだ状態で数式を記入、Ｃｔｒｌ＋Ｓｈｉｆｔ＋Ｅｎｔｅｒするとそうなります。
Ｃ３単独を選んで配列数式として記入、下向けにオートフィルドラッグすればＯＫです。

＃参考
Ｃ３に
=IF(SUMPRODUCT(($D$2:$F$2="○")*(D3:F3="○")),"○","")
をふつーに記入、下向けにコピーしても出来ます

＃参考
○しか記入しないなら
Ｃ３に
=IF(SUMPRODUCT(1*(D$2:F$2=D3:F3)),"○","")
以下コピーでも出来ます。

お礼

早速の回答ありがとうございます。

確かに最初にC3に配列数式として入力してからオートフィルするか普通にコピーすればできました。
最初にC3:C6を選択してしまったのが敗因のようです。
これは、C3:C6も1つの配列として扱われてしまうということですかね。

また、SUMPRODUCTを使う方法では、配列数式を使わなくて済むのですね。
他の人が見た時にはこちらの方が分かり易いかもしれませんね。
ただ、この場合、SUMPRODUCTの引数として渡している配列としては１つしかありませんが、これは、
SUMPRODUCT(($D$2:$F$2="○")*1,(D3:F3="○")*1)
として計算されていると考えて良いのでしょうか？

回答No.2

keithin

SUMPRODUCT関数を使う事で、「配列入力(Ctrl+Shift+Enter)」をしなくても「配列計算」をしてくれます。

エクセルが実際にどのように計算を進めているのかは、数式タブにある「数式の検証」の機能を使い、計算を１ステップずつトレースして理解してください。
必ず「正しく作動する数式」をキチンと作成して（教わって）から、それを数式の検証を使って勉強し、身に着けてください。

お礼

レスポンス遅くなりました。
回答ありがとうございました。
お陰様で配列数式でもSUMPRODUCTでも実現できました。
他の人がメンテナンスすることも考えてSUMPRODUCTで実装することにしました。