ExcelのVBAなんですが・・・教えて下さい。

質問

Userformを使って自分で作成しましたカレンダー(予定表)に文字数を入力しようとしています。

Userformには、Comboboxを使って指定の月を選択し、
予定表の月の列に文字数を入力したいと考えています。

自分なりに考えて作成してみたんですが・・・どうしても上手くいきません。
お手数をおかけしますが、教えて頂けますか？

下記のコードを作成しましたが、どこをどの様にしたら、きちんとした動作ができますでしょうか？

Private Sub UserForm_Initialize()
With ComboBox1
.AddItem "1月"
.AddItem "2月"
.AddItem "3月"
.AddItem "4月"
.AddItem "5月"
.AddItem "6月"
.AddItem "7月"
.AddItem "8月"
.AddItem "9月"
.AddItem "10月"
.AddItem "11月"
.AddItem "12月"
End With
End Sub

Private Sub CommandButton1_Click()
Dim s As Long
Dim rng
Select Case ComboBox1.Value
Case "1月": rng = "az46"
Case "2月": rng = "be46"
Case "3月": rng = "bj46"
Case "4月": rng = "ak11"
Case "5月": rng = "ap11"
Case "6月": rng = "au11"
Case "7月": rng = "az11"
Case "8月": rng = "be11"
Case "9月": rng = "bj11"
Case "10月": rng = "ak46"
Case "11月": rng = "ap11"
Case "12月": rng = "au11"
Case Else: Exit Sub
End Select
s = Range(rng, Rows.Count).End(xlDown).Row
Range(rng & s + 1).Value = TextBox1.Value
End Sub

初心者の為、すいませんが宜しくお願いします。

回答No.3

watabe007 · ベストアンサー

>Set myRng = Range(rng).End(xlUp).Offset(1)
>この部分の .Offset(1)が、そう言う意味になるんですか？

Range(rng).End(xlUp) は、最終行から上に向かってデータが入力されている位置を求めます
キー操作では　[End] + [↑] に当たります。
上記で求められた位置の一つ下の位置、すなわち.Offset(1)　が新たに入力する位置となります。

おまけ
>Private Sub UserForm_Initialize()
>With ComboBox1
>.AddItem "1月"
.>AddItem "2月"
　　　　↓

Private Sub UserForm_Initialize()
　　Dim i As Long

　　For i = 1 To 12
　　　　Me.ComboBox1.AddItem i & "月"
　　Next
End Sub
このようにコンパクトに書くことができます。

お礼

助かりました。本当に感謝です。

.Offset(1)が、入力開始位置になるんですか。
理解がようやくできました。
また、質問などする事がありますが、また宜しくお願いします。

補足

ありがとうございました。以下この様にしました。

Private Sub UserForm_Initialize()
Dim i As Long

For i = 1 To 12
Me.ComboBox1.AddItem i & "月"
Next
End Sub

Private Sub CommandButton1_Click()
Dim myRng As Range
Dim rng As String

Select Case ComboBox1.Value
Case "1月": rng = "az76"
Case "2月": rng = "be76"
Case "3月": rng = "bj76"
Case "4月": rng = "ak41"
Case "5月": rng = "ap41"
Case "6月": rng = "au41"
Case "7月": rng = "az41"
Case "8月": rng = "be41"
Case "9月": rng = "bj41"
Case "10月": rng = "ak76"
Case "11月": rng = "ap76"
Case "12月": rng = "au76"
Case Else: Exit Sub
End Select

Set myRng = Range(rng).End(xlUp).Offset(1)
myRng.Value = TextBox1.Value
End Sub

回答No.2

watabe007

>入力はできるようになったんですが・・・例えばComboboxで4月を選択し
>Textboxに英数字を入力しCommandbuttonで出力すると、
>最終行に入力しないようなんです。
どのセルに入力されましたか?
他の月を選択した場合は、どうですか?(10月～3月)

>Case "4月": rng = "ak46"
↓
Case "4月": rng = "ak45" 又は　ak44
などで試してください。
それでも希望どうりの動きでない場合はシートレイアウトを詳しく教えてください。

補足

ありがとうございます。
解決しました。実は、4月の最終行が"ak41"でした。
すべて最終行に合わせて使うんですね。
先ほどまでは、入力開始位置に合わせて行っていました。
従って、入力開始位置の上の行がタイトルとなっていますので
タイトル行に入力されたり開始位置に入力されたリの繰り返しでしたが、
すべて最終行に合わせたらきちんと希望する動作が得られました。
私、勘違いをしていました。

ここでちょっとした疑問なんですが・・・なぜ最終行に合わせないと、
希望した動作ができなかったんでしょうか？

Set myRng = Range(rng).End(xlUp).Offset(1)
この部分の .Offset(1)が、そう言う意味になるんですか？

回答No.1

watabe007

xlDown　だと１月を例に挙げるとセルAZ47が空白だとエラーになりますので
xlUpを使って最終行を求めましょう

Private Sub CommandButton1_Click()
　　Dim myRng As Range
　　Dim rng As String

　　Select Case ComboBox1.Value
　　　　Case "1月": rng = "az85"
　　　　Case "2月": rng = "be85"
　　　　Case "3月": rng = "bj85"
　　　　Case "4月": rng = "ak46"
　　　　Case "5月": rng = "ap46"
　　　　Case "6月": rng = "au46"
　　　　Case "7月": rng = "az46"
　　　　Case "8月": rng = "be46"
　　　　Case "9月": rng = "bj46"
　　　　Case "10月": rng = "ak85"
　　　　Case "11月": rng = "ap85"
　　　　Case "12月": rng = "au85"
　　　　Case Else: Exit Sub
　　End Select

　　Set myRng = Range(rng).End(xlUp).Offset(1)
　　myRng.Value = TextBox1.Value
End Sub

補足

回答ありがとうございます。早速試してみました。
入力はできるようになったんですが・・・例えばComboboxで4月を選択し
Textboxに英数字を入力しCommandbuttonで出力すると、
最終行に入力しないようなんです。
希望の動作は、4月を選択した時に入力の随時、最終行に入力ができると良いのですが・・・
4月だとセル"ak11"から下の行に入力していく様にしたいです。もちろん他の月も同様にしたいと考えています。