excel2010 マクロでの散布図作成

質問

excel2010で、ログを整理して複数のグラフを自動作成するマクロを作成しています

散布図の作成手順を記録した後、変数を当てなおしマクロを走らせると記録時と異なる挙動を示し、記録時にはひとつしか作成しなかった系列が25個くらい作成されました

下記マクロでおかしなところがあればご指摘ください

------------------------------

sheetname2 = ActiveSheet.Name

ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlXYScatterLinesNoMarkers
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(1).Name = "='" & sheetname2 & "'!$E$1"
ActiveChart.SeriesCollection(1).XValues = "='" & sheetname2 & "'!$A$2:$A$" & y3
ActiveChart.SeriesCollection(1).Values = "='" & sheetname2 & "'!$E$2:$E$" & y3

-------------------------------

作りたいグラフ：散布図

系列　「アクティブシート」のセルE1
x軸　　「アクティブシート」のセルA2～A「y3」
ｙ軸　　「アクティブシート」のセルE2～E「y3」

なお、シート名を固定すると色々と問題があるため、変数としてあります
また、変数y3は別途取得してありますが、省略いたします

回答No.1

xls88

（例1）系列1のみ残しあとの系列は削除する
Dim i As Integer
ActiveSheet.Shapes.AddChart.Select
ActiveChart.ChartType = xlXYScatterLinesNoMarkers
If ActiveChart.SeriesCollection.count > 1 Then
For i = ActiveChart.SeriesCollection.count To 2 Step -1
ActiveChart.SeriesCollection(i).Delete
Next
End If
ActiveChart.SeriesCollection(1).Name = "='" & sheetname2 & "'!$E$1"
ActiveChart.SeriesCollection(1).XValues = "='" & sheetname2 & "'!$A$2:$A$" & y3
ActiveChart.SeriesCollection(1).values = "='" & sheetname2 & "'!$E$2:$E$" & y3

（例2）SetSourceDataでやってみる
Dim drng As Range
Set drng = Union(Range("A2:A" & y3), Range("E2:E" & y3))
With ActiveSheet.Shapes.AddChart.Chart
.ChartType = xlXYScatterLinesNoMarkers
.SetSourceData Source:=drng, PlotBy:=xlColumns
.SeriesCollection(1).Name = "='" & sheetname2 & "'!$E$1"
End With

（例3）ChartObjectをAddしてみる
Dim crng As Range
Dim nrng As Range
Dim xrng As Range

With ActiveSheet
Set crng = .Range("H1:N13")
Set nrng = .Range("E1")
Set xrng = .Range("A2", .Range("A" & .Rows.count).End(xlUp))
With .ChartObjects.Add(crng.Left, crng.Top, crng.Width, crng.Height)
.Chart.ChartType = xlXYScatterLinesNoMarkers
With .Chart.SeriesCollection.NewSeries
.Name = "='" & ActiveSheet.Name & "'!" & nrng.Address
.XValues = xrng
.values = xrng.offset(, 4)
End With
End With
End With