VBAでオプションボタンを透過

質問

ワークシート上にOLEオブジェクトのオプションボタンを設置するため、以下のようなマクロを書きました。
意図したように作動するのですが、一箇所だけ不具合があります。
.Object.BackStyle = fmBackStyleTransparent　と、透過に設定してるのですが透過してくれません。（エラーにもなりません。）
どこがおかしいのでしょうか？

Sub test02()
Dim n As Long, i As Long
Dim myRng As Range
With ActiveSheet
For n = 3 To 5
For i = 3 To 10
Set myRng = .Cells(i, n)
Set opt = .OLEObjects.Add(ClassType:="Forms.OptionButton.1", _
Left:=myRng.Left + 2, Top:=myRng.Top + 2, Width:=myRng.Width * 0.8, Height:=myRng.Height * 0.9)
opt.LinkedCell = myRng.Offset(, 4).Address
opt.Object.Value = False
opt.Object.GroupName = "OptG" & i
opt.Object.Caption = Choose(n - 2, "Yes", "No", "N/A")
opt.Object.BackStyle = fmBackStyleTransparent
Next i
Next n
End With
End Sub

回答No.1

doara_2011 · ベストアンサー

Next i の前の行あたりに、以下を挿入すると取りあえずできます。
opt.Interior.Pattern = xlNone
上記で取りあえずと書いたのは、Excel2003だと、フォーカスのあるコントロール
は透過はされないようですが、フォーカスが別のコントロールに移っても透過
されないままの場合があるようです。透過してくれる場合もあって、その法則性
はよくわからないです。
Excel2010では、透過されないのは現在フォーカスのあるコントロールのみだけ
で、他のコントロールはちゃんと透過してくれています。

以上

お礼

早速ありがとうございます。
opt.Interior.Pattern = xlNone
試しました。

ちゃんと透過したオプションボタンが現われました。
でもおっしゃるとおり、クリックすると透過されませんし、一旦そうなると別のボタンをクリックしても透過されないままですね。（何度かいじるとまた透過されたりする・・・）
何か変な動きですね。

補足

今日、エクセル2007にさわる機会があったので試しました。
2003と同じ結果でした。
2010じゃなきゃだめなんですね。
これはエクセルのバグなんでしょうか。

回答No.2

merlionXX

わたし（エクセル2000使用）はOLEオブジェクトはあまりつかわないので、旧来のフォームのオプションボタンを使ってやってみました。
フォームのオプションボタンとOLEのそれの違いは当然ご存知とは思いますが、一番の違いのグループボックスを非表示にすることでだいぶ近いものにしました。
ただ、リンク先の表示がOLEの場合と違って数字になるのはどうしようもないです。
また、サイズに制約があるので勝手に行高も変えてしまいました。
こんな感じですが、新しいシートでお確かめ下さい。

Sub test03() 'Formの場合
　　Dim n As Long, i As Long
　　Dim Rng As Range
　　Dim gb As GroupBox, opt As OptionButton
　　With ActiveSheet
　　　　.Cells.RowHeight = 19.5 '行高を19.5に設定
　　　　For i = 3 To 10 '先にグループボックス挿入
　　　　　　Set Rng = .Range(.Cells(i, "C"), .Cells(i, "E"))
　　　　　　Set gb = .GroupBoxes.Add(Left:=Rng.Left, _
　　　　　　Top:=Rng.Top, Width:=Rng.Width, Height:=Rng.Height)
　　　　　　gb.Characters.Text = ""
　　　　　　gb.Visible = False '非表示に
　　　　　　For n = 3 To 5 'オプションボタン挿入
　　　　　　　　Set Rng = .Cells(i, n)
　　　　　　　　Set opt = .OptionButtons.Add(Left:=Rng.Left + 2, _
　　　　　　　　Top:=Rng.Top + 2, Width:=Rng.Width * 0.8, Height:=Rng.Height * 0.9)
　　　　　　　　opt.LinkedCell = .Cells(Rng.Row, "G").Address
　　　　　　　　opt.Value = xlOff
　　　　　　　　opt.Characters.Text = Choose(n - 2, "Yes", "No", "N/A")
　　　　　　　　opt.ShapeRange.Fill.Visible = msoFalse '透明に
　　　　　　　　opt.ShapeRange.Line.Visible = msoFalse '線無しに
　　　　　　Next n
　　　　Next i
　　　　Set Rng = Nothing
　　　　Set gb = Nothing
　　　　Set opt = Nothing
　　End With
End Sub

お礼

有難うございます。
フォームのオプションボタンなら簡単に透過させられることは知っていました。
ただ、グループボックスが見えるのがいまいちで、ボタンがグループボックスをはみ出したりするととんでもない結果を招くので二の足を踏んでいました。

なるほど、このように非表示にする手があったのですね！
勉強になりました。