集計の関数について

質問

F１~F50までにいろいろ数字が入ってるのですが、そこに1～10迄の場合にのみその列のIとJの合計を集計したいです。すいませんが解るかたよろしくです。

回答No.1

mshr1962 · ベストアンサー

EXCEL2003までなら
=SUMIF(F1:F50,">0",I1:I50)-SUMIF(F1:F50,">10",I1:I50)+SUMIF(F1:F50,">0",J1:J50)-SUMIF(F1:F50,">10",J1:J50)

EXCEL2007以降なら新関数で
=SUMIFS(i1:i50,F1:F50,">0",F1:F50,"<=10")+SUMIFS(J1:J50,F1:F50,">0",F1:F50,"<=10")

回答No.5

chiemegu_2

やり方はいろいろあると思いますが。。。

1.条件付き書式でIF文を使う（条件付き書式はご存知ですか？）
2.マクロをご存知であればマクロ（マクロを組んだことはありますか？）
3.上記１と加えてピボットテーブル（ピボットテーブルをご存知ですか？）

回答No.4

某HN クロメート(Chromate)（@CoalTar）

もう一案 1以上10以下として(1も10含む)
=SUMPRODUCT((1<=F1:F50)*(F1:F50<=10)*I1:J50)

回答No.3

imogasi

質問例を変えている。
例データ
Ａ列　　　Ｂ列　　　　Ｃ列　　該当行
6 1 3 *
2 2 2
3 3 5
9 4 4 *
6 5 6 *
2 6 7
3 7 7
4 8 3
7 9 2 *
2 2 1
ーー
Ａ列が５を越える例で説明すると
=SUMPRODUCT((A1:A10>5)*(B1:B10)+(A1:A10>5)*(C1:C10))
結果
３４
ーー
注意
バージョンを書くこと（２００７以後かどうかが大切）
質問異は簡単なデータ例を挙げること。
上記は常套手段。ＳＵＭＩＦでもきる。
=SUMIF(A1:A10,">5",B1:B10)+SUMIF(A1:A10,">5",C1:C10)
結果
３４
式のダブリ的な部分はなくせないようだ。

回答No.2

jcctaira

SUMPRODUCT関数でできると思います。

> IとJの合計なら以下の通りです。
=SUMPRODUCT((F1:F50>=1)*(F1:F50<=10)*(I1:I50+J1:J50))

> IとJのそれぞれの合計なら以下の通りです。
=SUMPRODUCT((F1:F50>=1)*(F1:F50<=10)*I1:I50)
=SUMPRODUCT((F1:F50>=1)*(F1:F50<=10)*J1:J50)