Excelでの比較、データチェックを行うには？

質問

Excel2000を使用しています。
全て数字で
No、数量、金額、コード・・・・
といった感じにデータを入力しており、
量が多いので、同じものをもう一回入力して
比較し、違っている部分に色をつけることはできないか
調べています。入力自体はマクロを使ったファイルにて
入力しており、CSVで保存してあります。比較はExcelにて
そのcsvのファイルをシート1、シート2にそれぞれ開いて
行おうとしています。
違っている部分に色をつけることはできそうなのですが
その部分だけでなく、その行の一番左にあるNoにも色を
つけたいと思うのですが、そのようなことは可能でしょうか？また、もっとよい方法があればどなたか教えてください。

回答No.2

ja7awu · ベストアンサー

マクロをお使いでしたらマクロで対処されたらいいと思います。
例えば、こんな感じです。
"Sheet1"と"Sheet2"間で比較し、相違しているセルをベージュ色で塗り潰します。
そのときは、A列のセルも黄色で塗り潰します。
さらに違っている個所数をメッセージボックスで表示します。

Sub シート間データチェック()
Dim OrgSH As Worksheet
Dim ChkSH As Worksheet
Dim ColMax As Integer
Dim Rng As Range
Dim Cnt As Long
Dim ColChk As Boolean
Set OrgSH = Worksheets("Sheet1")
Set ChkSH = Worksheets("Sheet2")
ColMax = OrgSH.UsedRange.Columns.Count
ChkSH.Activate
For Each Rng In OrgSH.UsedRange
　　If Rng.Column = 1 Then ColChk = False
　　If Rng.Value = Range(Rng.Address).Value Then
　　　　Range(Rng.Address).Interior.ColorIndex = xlNone
　　Else
　　　　Range(Rng.Address).Interior.ColorIndex = 40
　　　　Cnt = Cnt + 1
　　　　ColChk = True
　　End If
　　If Rng.Column = ColMax And ColChk = True Then
　　　　If Range("A" & Rng.Row).Interior.ColorIndex <> 40 Then
　　　　　　Range("A" & Rng.Row).Interior.ColorIndex = 6
　　　　End If
　　ElseIf Rng.Column = ColMax And ColChk = False Then
　　　　Range("A" & Rng.Row).Interior.ColorIndex = xlNone
　　End If
Next Rng
Range("A1").Activate
MsgBox "違っているセルは " & Cnt & " ヶ所です。", vbExclamation
Set OrgSH = Nothing
Set ChkSH = Nothing
End Sub

お礼

ご回答ありがとうございました。
申し訳ありません、入力するためのマクロは私が作ったものではありません。
私はマクロというものが全くわかりません。
せっかくアドバイスしていただいたのですが何のことかさっぱりわかりません。関数について本を調べつつ手探りでやっている状態です。
どこかにこれを貼り付ければできるものなのでしょうか？

回答No.3

ja7awu

> どこかにこれを貼り付ければできるものなのでしょうか？

そうです。簡単に実行出来ますよ。

操作手順を詳しく説明しますので、テストしてみてください。

１．Alt + F11 で VBE(Visual Basic Editor)を開きます。
２．VBE のメニューから[挿入] -->[標準モジュール] を指定します。
３．モジュールウィンドウに先のコードをコピーして貼り付けます。
４．Alt + Q （または、右上隅の×）でウィンドウを閉じ、シートに戻ります。
５．実行するときは、Alt ＋ F8 (メニューから[ツール]-->[マクロ]-->[マクロ])で
　「シート間データチェック」を指定し、[実行]ボタンを押します。

お礼

丁寧なご指導ありがとうございます。
早速チャレンジしてみます。
ありがとうございました。

回答No.1

happypoint

>csvのファイルをシート1、シート2にそれぞれ開いて

この仕様は変更できないのでしょうか？
２つのファイルを同一のシートに展開して良いのなら、
「条件付き書式」を使用するのが簡単だと思います。
（書式-条件付き書式）

たとえばNoがそれぞれA-E列とF-J列に入っているとします。
A1とF1セルの値が異なるときにA1に色をつけるには、
A1の条件付き書式を、次のように設定します。

　セルの値が　次の値に等しくない　=F1

そして右下の「書式」ボタンを押して、「パターン」タブから、塗りつぶす色を選びます。

このセルの書式をコピーし、
すべての行・列（A-E列）に書式だけ貼り付けすれば、ＯＫです。

お礼

回答ありがとうございました。
早速チャレンジしてみました。
できたのですが、かなりボリュームがあるので横に貼り付けるのが大変でした。
とても参考になりました。
ありがとうございました。