変数の定義について

質問

変数の定義について

変数の定義について
他のブックから検索値をVLOOKで転記させるマクロをこちらの掲示板ログなどを
拝見しながら、ツギハギして作成しました。

転記先のシートのＡ列に区別コードを設けています。
これを基に転記元のブックから社名などを転記させようと思っているのですが、
変数の型宣言が上手くないらしく？転記処理が出来ません。

「Option Explicit」と「変数宣言」をコメントアウトすると動作します。
変数の宣言が違うのだろうか？と宣言部分をコメントアウトして動作確認して
いったら、「Dim 検索値 As Double」があると動作しないようなのです。
これをValiantに変更しても動作しませんでした。

この原因が分かる方、どうぞ助けてください。

////////////////////////////////////////////////////////

Dim Base As Workbook, Code As Workbook
Dim 範囲 As Range
Dim i As Long
Dim 会社名 As String
Dim 検索値 As Double　←←←←←←←←←←←←←←←←←ここの部分？

Sub 一覧()
Set Base = Workbooks("転記元.xls")
Set Code = Workbooks("転記先.xls")
Set 範囲 = Base.Worksheets("転記元").Range("A4:AX5000")
On Error GoTo ErrorHandler
Do
検索値 = Code.Worksheets("転記先のシート").Cells(i + 2, 1)
If 検索値 = "" Then Exit Do
会社名 = Application.WorksheetFunction.VLookup(検索値, 範囲, 6, False)
Code.Worksheets("転記先のシート").Cells(i + 2, 2) = 会社名
i = i + 1
Loop
Error トラップ開始
ErrorHandler:
会社名 = ""
Resume Next
End Sub
////////////////////////////////////////////////////////

回答No.2

Wendy02 · ベストアンサー

普通、モジュールレベルの変数の宣言をする必要はないと思います。Sub プロシージャ内に入れてあげればよいと思います。どういう目的なのか分かりませんから、会社名と検索値だけは、外に出しておきます。

If 検索値 = "" Then Exit Do
文字比較しているのですから、Double型で比較したら、エラーが発生します。
Double型ですと、何もデータが入っていないのか、それとも、0　なのか比較できません。
Range 型のまま、IsEmpty という方法もありますが、一般的には、セルの値には、If 検索値 = ""としますから、検索値のデータ型は、Variant 型でおけばよいです。慣例的なものです。

また、On Error Goto ErrorHandler では、ピンポイントエラーは検出できません。
掲示板では、違った書き方が流れているようですが、一般的には、以下のような方法が良いと思います。

ところで、VBAは、なるべく、2バイト文字の変数は使いづらいのでやめたほうがよいです。私の場合は、Excel の他のバージョンも入れていますので、検索が使えないという不具合があるからです。

'//
Dim 会社名 As String
Dim 検索値 As Variant　'Double

Sub 一覧()
Dim Base As Workbook, Code As Workbook
Dim 範囲 As Range
Dim i As Long
　　Set Base = Workbooks("転記元.xls")
　　Set Code = Workbooks("転記先.xls")
　　Set 範囲 = Base.Worksheets("転記元").Range("A4:AX5000")
　　Do
　　　　検索値 = Code.Worksheets("転記先のシート").Cells(i + 2, 1).Value
　　　　If 検索値 = "" Then Exit Do
　　　　On Error Resume Next
　　　　会社名 = ""　'一旦、空にする。そうしないとエラー時に更新されない
　　　　会社名 = Application.WorksheetFunction.VLookup(検索値, 範囲, 6, False)
　　　　On Error GoTo 0
　　　　If 会社名 <> "" Then
　　　　　 Code.Worksheets("転記先のシート").Cells(i + 2, 2) = 会社名
　　　　End If
　　　　i = i + 1
　　Loop
End Sub

お礼

回答ありがとうございます。希望通りの動作になりました。
モジュールレベルの変数にしたのは、同モジュール内で取り込んだリストをソートする等
といった小さなマクロでも使用するためです。ご指摘いただいた2バイト変数名についても
修正したいと思います。ありがとうございました。

回答No.1

mar00

間違っていたらすいません。
検査値がどのような値になっているかわかりませんが
整数型なら
　　Dim 検索値 As Integer(-32,768 ～ 32,767 の範囲の値)
長整数型なら
　　Dim 検索値 As Long(-2,147,483,648 ～ 2,147,483,647 の範囲の値)
文字列型なら
　　Dim 検索値 As String
あたりではないでしょうか。

お礼

お返事ありがとうございました。
情報が中途半端で申し訳ありません。検査値は6桁の整数です。
変数の型名を調べる～TypeName関数を使って調べたら、「Double」と出たので
それを用いました。
また、回答をいただいた「Integer」「Long」「String」でテストしましたが
同じ結果となりました。
貴重な時間を割いていただきありがとうございました。