エクセルマクロで複数列のセルを選択した時でも正しく動作するようにしたい

質問

エクセルマクロで複数列のセルを選択した時でも正しく動作するようにしたい。
今、３列目に入力された値によって１５列から１７列の値を自動入力するように次の
マクロを作りました。

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column <> 3 Then Exit Sub
For Each r1 In Selection
If r1.Cells(1, 1) <> "部品表" Then
Cells(r1.Row, 15) = "－"
Cells(r1.Row, 16) = "－"
Cells(r1.Row, 17) = "－"
End If
Next
End Sub

３列目のみのセルをペーストすると正しく動作しますが、１列目から３列目のセルにペーストすると何も動きません。
正しく動くようにするには、どう修正すればいいでしょうか？

回答No.1

chie65535 · ベストアンサー

＞If Target.Column <> 3 Then Exit Sub

これだと、変更した領域の左上隅のセルが「３列目以外」だと何もしません。

＞１列目から３列目のセルにペーストすると

であれば、変更した領域の左上のセルが「１列目」つまり「３列目以外」ですから、何もしません。

ですので「変更領域の左隅が３列目より右にある」または「変更領域の右隅が３列目より左にある」と言う判断をしなければなりません。

また「変更された範囲が複数列に渡る場合」を考慮して「For Eachの中で、r1が３列目を指している時だけ処理する」という制限も必要です。

その２点を踏まえて修正すると、以下のようになります。

Private Sub Worksheet_Change(ByVal Target As Range)
If (Target.Column > 3) Or (Target.Column + Target.Columns.Count < 4) Then Exit Sub
For Each r1 In Selection
If r1.Column = 3 Then
If r1.Cells(1, 1) <> "部品表" Then
Cells(r1.Row, 15) = "－"
Cells(r1.Row, 16) = "－"
Cells(r1.Row, 17) = "－"
End If
End If
Next
End Sub

お礼

ありがとうございます。
意図した動作になりました。

回答No.2

keithin

修正例：
private sub Worksheet_Change(byval Target as excel.range)
　dim h as range
　application.enableevents = false
　on error resume next

　for each h in application.intersect(target, range("C:C"))
　　if h <> "部品表" then
　　　h.offset(0, 12).resize(1, 3) = "－"
　　end if
　next
　application.enableevents = true
end sub

今は
＞３列目のみのセルをペーストすると

の部分を
　If Target.Column <> 3 Then Exit Sub
のようにして担保しています。
いまのマクロは比較的間違いのない，そこそこ良いプログラムになっています。

それを直そうというのですから
＞正しく動作します

「正しい」とは一体どういう動作なのか，漏れや間違いの無いようちゃんとあなたが見直さないといけませんね。

お礼

回答ありがとうございます。