必要な数字を抜き出す方法

質問

こんにちは。

エクセルでこんなことをしたいのですができますでしょうか？

「******** 34 page ******」
上のような感じのセルがいくつもある列があります。
「*」は数字だったりアルファベットだったりします。
各セルで「*」の数は違います。
スペースは、ページ数の前だけでなく、数箇所にあったりします。

このページ数の数字だけを別のセルに抜き出したいのですが、どういう方法がありますでしょうか？

「page」の前の文字を抜き出す、みたいな関数があればいいんですけど、そういうものはあるんでしょうか？
マクロになってしまいますか？

エクセルのバージョンは2003だと思います。

どうぞ宜しくお願い致します。

回答No.3

_Kyle · ベストアンサー

桁数不定版です。
　※ただし「数字部分の始まりから"page"の直前まで」が「カンマ・スペースを含めて8文字以内」。

　=--RIGHT(LEFT(A1,FIND("page",A1)-1),9-MATCH(0,--ISERR(-(RIGHT(LEFT(A1,FIND("page",A1)-1),{8,7,6,5,4,3,2,1}))),0))

●動作の概要
　A1セルの文字列から、"page"を探し、その直前8文字について、
　「数値と解釈しうる最長の文字列」を切り出して、数値化して返す。

Ex.
・１桁でも可
　abcdef 2 page ghijklmnopqrstu　⇒　2

・全角数字やカンマを含んでも可
　abcdefghijklmn 1，２3４ page opqrstu　⇒　1234

・前後のスペースの有無は問わない
　abcdef56789pageghijklmnopqrstu　⇒　56789

Excel2003で動作確認。ご参考まで。

お礼

お礼がすっかり遅くなってしまい申し訳ありません

どうもありがとうございました

回答No.4

KURUMITO

A1セルにデータがあるとしたら次の式ではどうでしょう。
なお、ページ数は4桁までの対応ができます。ページ数の前後には半角のスペースがあるものとします。
=IF(ISNUMBER(VALUE(MID(A1,FIND("page",A1)-5,1))),MID(A1,FIND("page",A1)-5,5),IF(ISNUMBER(VALUE(MID(A1,FIND("page",A1)-4,1))),MID(A1,FIND("page",A1)-4,4),IF(ISNUMBER(VALUE(MID(A1,FIND("page",A1)-3,1))),MID(A1,FIND("page",A1)-3,3),IF(ISNUMBER(VALUE(MID(A1,FIND("page",A1)-2,1))),MID(A1,FIND("page",A1)-2,2)))))

お礼

お礼がすっかり遅くなってしまい申し訳ありません

どうもありがとうございました

回答No.2

noname#204879

「上のような感じのセル」A1 に使われない文字を仮に「_」とすれば、
=MID(A1,FIND("_",SUBSTITUTE(A1," ","_",LEN(LEFT(A1,FIND(" page",A1)-1))-LEN(SUBSTITUTE(LEFT(A1,FIND(" page",A1)-1)," ",""))))+1,FIND(" page",A1)-FIND("_",SUBSTITUTE(A1," ","_",LEN(LEFT(A1,FIND(" page",A1)-1))-LEN(SUBSTITUTE(LEFT(A1,FIND(" page",A1)-1)," ",""))))-1)

お礼

お礼がすっかり遅くなってしまい申し訳ありません

どうもありがとうございました

回答No.1

mshr1962

" page"の前の数値の桁数は固定でしょうか？固定なら
=MID(A1,FIND(" page",A1)-桁数,桁数)*1

お礼

お礼がすっかり遅くなってしまい申し訳ありません

どうもありがとうございました