エクセル関数を用いて判定したいのですが・・・

質問

エクセル関数初心者です。

ＩＦ関数を用いて数値を判定したいのですが、
男性と女性で判定基準が異なります。

セルＡが"男性"なら、セルＢが２以上の場合で"●"
セルＡが"女性"なら、セルＢが４以上の場合で"●"、
それ以外は"▲"

このような条件で判定分けできる方法はありますか？

さらに、
セルＡが"男性の場合、Ｂが２～４なら"●"、４より大きい場合は"▲"、２未満なら"×"
セルＡが"女性の場合、Ｂが３～５なら"●"、５より大きい場合は"▲"、３未満なら"×"

何かやり方があれば、教えてください。
よろしくお願いします。

回答No.3

ASIMOV · ベストアンサー

１問目
　=IF(OR(AND(A2="男性",B2>=2),AND(A2="女性",B2>=4)),"●","▲")

２問目
　=IF(OR(AND(A2="男性",AND(B2>=2,B2<=4)),AND(A2="女性",AND(B2>=3,B2<=5))),"●",IF(OR(AND(A2="男性",B2<2),AND(A2="女性",B2<3)),"×","▲"))

で、どうでしょう

お礼

回答ありがとうございます。
この方法は、理解しやすかったです。

回答No.5

imogasi

質問前半は質問に値しないぐらい、易しい。ただＩＦ関数をネスとして、式に順に書いていくだけ。略。
ーー
後半
ちょっとひねって
ＶＬＯＯＫＵＰ関数のＴＲＵＥ型を使うが、「名前」の応用で
式が１つ（男性・女性とも区別不要で・１つの形で）で出来そうだ（うまく行くようだ）。
例データ　Ａ５以下に
Ａ列　　Ｂ列　　Ｃ列（式の結果で、後述）
男性 4 ▲
男性 2 ●
ーーー
Ｅ４：Ｆ７
0 Ｘ
2 ●
4 ▲
100
と入れて、セル範囲名を「男性」としておく。名前ボックスに「男性」と入れるだけ。
ーーー
Ｇ４：Ｈ７に
0 Ｘ
3 ●
5 ▲
100
と入れて、セル範囲名を「女性」としておく。
ーーー
Ｃ５の式に　=VLOOKUP(B5,INDIRECT(A5),2,TRUE)
と入れて
下方向に式を複写。
結果
上記Ｃ列。
ーー
ＩＦ関数を表に出さないのが私の理想なので考えてみた。

お礼

回答ありがとうございます。
さらに複雑な判定も、VLOOKUPを使ってうまくいきました。

回答No.4

gyouda1114

回答番号：No.1です
後段です
Vlookup関数を使って
画像で
E1:G6に男女別に●▲×の表
C2に　=VLOOKUP(B2,$E$1:$G$7,IF(A2="男",2,3))

お礼

回答ありがとうございます。
VLOOKUP関数は知らなかったのですが、大変勉強になりました。

回答No.2

kokorone

IF(
AND(A1="男性",B1>=2,B1<=4),"●",
IF(
AND(A1="男性",B1>4),"▲",
IF(
AND(A1="男性",B1<2),"×",
IF(
AND(A1="女性",B1>=3,B1<=5),"●",
IF(
AND(A1="女性",B1>5),"▲","×")
)
)
)
)
と言うように、場合わけを列記すれば可能ですね。
（分かりやすいよう、改行をいれています。）
作業用にセルを使えるのであれば、
D1=IF(A1="男性",2,3)
E1=IF(A1="男性",4,5)
とした上で、
IF(
AND(B1>=D1,B1<=E1),"●",
IF(
B1>E1,"▲","×")
)
ということも可能です。

お礼

回答ありがとうございます。
解決いたしました。

回答No.1

gyouda1114

前段だけですが
＞セルＡが"男性"なら、セルＢが２以上の場合で"●"セルＡが"女性"なら、セルＢが４以上の場合で"●"、それ以外は"▲"

C2に　=IF(AND(A2="男",B2>=2),"●",IF(AND(A2="女",B2>=4),"●","▲"))　下方にオートフィル