２個の引数を使用して、テーブルの行、列に該当する値を求める方法は？

質問

Excel2003で、２個の引数を使用して、テーブルの行、列に該当する値を求める方法を、教えて下さい。

例）
Ａテーブル
　A　 B　　C　　D　　E
1　　　5　　4　　3　　2
2 1 260 200 150 100
3 2 460 370 280 180
4 3 670 540 400 270
5 4 880 700 530 350

Ｂテーブル
　A B　 C
1　　5
2　　2 460

ＢテーブルのB1のセルに5、B2のセルに2を、入力した場合、Ａテーブルから460を探し出して、ＢテーブルのC2のセルに460と、表示させたい。
この時、C2のセルには、どんな関数がいいのでしょうか？

よろしく、ご教示下さい。

回答No.6

gyouda1114

Bテーブルの形式は違いますが

C10に　
=INDEX($B$3:$E$6,MATCH($A10,$A$3:$A$6,0),MATCH($B10,$B$2:$E$2,0))
下方にオートフィル

回答No.5

bbit68

これはどうでしょうか？

=INDEX(B2:E5,MATCH(B2,A2:A5,0),MATCH(B1,B1:E1,0))

回答No.4

maron--5

◆こんな方法もありかな
=HLOOKUP(A1,Aテーブル!$B$1:$E$5,A2+1,0)

回答No.3

noname#204879

オーソドックスに(?)、
=VLOOKUP(B2,Ａテーブル!A2:E5,MATCH(B1,Ａテーブル!A1:E1,0),FALSE)

回答No.2

noname#99913

AテーブルがSheet1だとして……

=INDEX(Sheet1!B2:E5,B2,6-B1)

回答No.1

zap35

もし１行目に[5」が、A列に「2」が必ず存在するなら以下の式をC2に貼り付けてください
　=OFFSET(Aテーブル!A1,MATCH(B2,Aテーブル!A:A,0)-1,MATCH(B1,Aテーブル!1:1,0)-1)

でも合致する値がないと#N/A!エラーになります
もし条件が一致しない可能性があるなら、例えば以下のような式でエラーを回避することが可能です

　=IF(AND(COUNTIF(Aテーブル!1:1,B1)>0,COUNTIF(Aテーブル!A:A,B2)>0),OFFSET(Aテーブル!A1,MATCH(B2,Aテーブル!A:A,0)-1,MATCH(B1,Aテーブル!1:1,0)-1),"該当なし")