VBEで「名前を付けて保存」する方法

質問

名前を付けて保存するマクロが知りたいのですが、いくつか条件があります。

1.ファイル名は変数（4日後の日付をMMDDで。月を跨いでもきちんと認識されるように）

2.保存するディレクトリはC:\Program Files直下。
C:\Program Files\0422.xls
C:\Program Files\0423.xls
という感じで毎日ファイルを増やしたいのです。

3.ファイルに読み取りのパスワードを付ける。
（パスワードはファイル名と同一）

4.保存したらファイルを閉じるかどうかのダイアログを出す。

上記条件の場合、どのような構文になりますでしょうか？
識者の方々ご指導よろしくお願いいたしますm(_ _)m

回答No.1

DOUGLAS_ · ベストアンサー

簡単な操作かと存じますので、ベタ打ちのコードを呈示するだけではなくて、少し解説させていただきます。

　先ず、お示しの条件で [新しいマクロの記録] を取ってみましょう。

ChDir "C:\Program Files"
ActiveWorkbook.SaveAs Filename:="C:\Program Files\0423.xls", FileFormat:= _
　　xlNormal, Password:="0423", WriteResPassword:="", ReadOnlyRecommended:= _
　　False, CreateBackup:=False

というコードが得られます。

＞ファイル名は変数（4日後の日付をMMDDで。
　これは、ワークシートでは
=TEXT(TODAY()+4,"MMDD")
という式になりますね。

　ＶＢＡ では [TEXT 関数] は [Format 関数] に、[TODAY 関数] は [Date 関数] になりますので、そのまま、
Format(Date + 4, "MMDD")
でよいでしょう。

＞月を跨いでもきちんと認識されるように
Debug.Print Format(Date + 11, "MMDD")
を実行すると、イミディエイトウィンドウ に「0430」と表示され、「11」を「12」に変更して実行すると「0501」と表示されます。
　問題ありませんね。

　ということで、
"C:\Program Files\0423.xls"
の部分が
"C:\Program Files\" & Format(Date + 4, "MMDD") & ".xls"
に、
Password:="0423"
の部分は、そのまま
Password:=Format(Date + 4, "MMDD")
になります。

＞保存したらファイルを閉じるかどうかのダイアログを出す。
　[MsgBox 関数の使用例] のヘルプをご覧ください。

Dim Response
Response = MsgBox("保存しました。ブックを閉じますか？", vbYesNo, "保存後の処理")
If Response = vbYes Then
　ThisWorkbook.Close
End If

でどうでしょうか？

　ということで、ベタ打ちのコードは下記のようなことになりますが、既に同名のブックが存在する場合の処理はしておりませんので、別途お考えください。

Sub TEST()
　Dim MyFolder As String
　Dim MyDate As String
　Dim Response As Integer
　MyFolder = "C:\Program Files"
　MyDate = Format(Date + 4, "MMDD")
　ChDir MyFolder
　ActiveWorkbook.SaveAs Filename:=MyFolder & "\" & MyDate & ".xls", _
　　Password:=MyDate
　Response = MsgBox("保存しました。ブックを閉じますか？", vbYesNo, "保存後の処理")
　If Response = vbYes Then
　　ThisWorkbook.Close
　End If
End Sub

　なお、要らぬお節介ですが、「C:\Program Files直下」に ユーザーファイル を保存するのはいかがかと存じます。
　せめて、ワンクッション置いて
　MyFolder = "C:\Program Files\hoge"
みたいにされる方がよいかと。。。

お礼

ありがとうございます！
素晴らしく役に立ちました。
しかも解説まで付けていただいて、とても分かりやすかったです！