エクセルマクロの高速化をしたい

質問

合計の数字を指定し、リストからどの数字の組み合わせか抽出する
マクロを作成中です。

↓の質問を参考にしています。
http://oshiete1.goo.ne.jp/qa1229646.html

やり方はすごく参考になるのですが、処理速度が遅く、実用的には
だいたい３０個の数字リスト程度が限度です。

１００個の数字リストから組み合わせを抽出できるように
マクロの高速化ははかれないものでしょうか？

回答No.3

NNAQ

A列にリスト、B1セルに目標値を入力しておく。
目標値以下で最大になるような組み合わせを1つだけC列に書き出す。
(その目標値になるような組み合わせが何通りかあっても、1つだけしか出せない。)

Sub BubunSyuugouWa() '部分集合和
　Const n As Integer = 100 'リスト範囲=A1:An
　Dim x As Long '目標値=B1セルの値
　Dim Dic As Object, dicKey 'dictionary
　Dim arr '配列
　Dim xx As Long '途中経過
　Dim i As Integer, j As Long

　Set Dic = CreateObject("scripting.dictionary")
　x = Range("b1").Value
　arr = Range("a1").Resize(n).Value

　With Dic
　　.Add 0, 0
　　i = 1 'To n
　　Do '計算開始
　　　For Each dicKey In .keys
　　　　j = dicKey + arr(i, 1) 'j = 和
　　　　If j <= x And Not .exists(j) Then '和が目標値以下なら
　　　　　.Add j, i '辞書に追加
　　　　　If j > xx Then
　　　　　　xx = j
　　　　　　Application.StatusBar = xx '途中経過をステータスバーに表示
　　　　　　If j = x Then Exit Do '目標値ぴったりなら計算終了
　　　　　End If
　　　　End If
　　　Next
　　　i = i + 1
　　Loop While i <= n

　　For i = n To 1 Step -1
　　　If i = .Item(xx) Then
　　　　xx = xx - arr(i, 1)
　　　Else
　　　　arr(i, 1) = ""
　　　End If
　　Next i
　End With 'Dic
　Set Dic = Nothing

　With Range("c1").Resize(n)
　　.Select: .Value = arr '組み合わせ出力
　End With
　Application.CommandBars("AutoCalculate").Controls(7).Execute
　Application.StatusBar = False

End Sub

アルゴリズムは"動的計画法"っつーのです(多分)。
どのくらい時間かかるかは、データによるので一概に言えません。
30個位なら、あっという間に終わります。

補足

レスありがとうございます。

できましたら、やはり、複数の組み合わせがでたほうがいいですね。
その合計を構成する数の組み合わせをリストから探しだすというのが
もくてきですので、、、