excel VBA

質問

昨日VBAをさわり始めた超初心者です。質問ですが、excelからパワーポイントのシート内を削除の仕方と、テキスト追加方法を教えて下さい。パワーポイントは既存であり、テキスト内容はexcelのセル内の文字で、変数に入れることができました。まだまだ無知なので、ご教授下さいますようよろしくお願いします。

回答No.1

pkh4989

以下の例を参考にしてください。

'Excel VBAで PowerPointへテキストを挿入及びExcelのセル内容設定
Sub EXCEL_PowerPoint_TEXT追加()
　　Dim objPw As Object　　 'Object型
　　'
　　With ActiveSheet
　　　　'PPのオブジェクトを作る
　　　　Set objPw = CreateObject("PowerPoint.application")
　　　　objPw.Visible = True
　　　　'PowerPointファイルをオープン
　　　　objPw.Presentations.Open ("C:\TEST.ppt")
　　　　'
　　　　'パワーポイントのシート内のObjectの削除
　　　　For wI = 1 To objPw.Presentations(1).Slides(1).Shapes.Count
　　　　　　objPw.Presentations(1).Slides(1).Shapes(1).Delete
　　　　Next
　　　　'
　　　　'テキスト追加1→文字列挿入
　　　　objPw.Presentations(1).Slides(1).Shapes.AddTextbox(msoTextOrientationHorizontal _
　　　　, 100, 100, 200, 50).TextFrame.TextRange.Text = "図１"
　　　　'テキスト追加2→Excelのセル(1,A)の内容設定
　　　　objPw.Presentations(1).Slides(1).Shapes.AddTextbox(msoTextOrientationHorizontal _
　　　　, 100, 200, 200, 50).TextFrame.TextRange.Text = .Cells(1, "A")
　　End With
End Sub

'Excel で PowerPoint をオープンして印刷する例
Sub EXCEL_フォルダー内印刷ppt()
　　Dim ff As Office.FoundFiles
　　Dim p As Variant
　　With Excel.Application.FileSearch
　　　　.LookIn = "C:\"
　　　　.Filename = "*.ppt"
　　　　If .Execute() > 0 Then
　　　　　　Set ff = .FoundFiles
　　　　　　With CreateObject("PowerPoint.Application")
　　　　　　　　For Each p In ff
　　　　　　　　　　With .Presentations.Open(CStr(p))
　　　　　　　　　　　　.PrintOut
　　　　　　　　　　　　.Close False
　　　　　　　　　　End With
　　　　　　　　Next
　　　　　　　　.Quit
　　　　　　End With
　　　　　　Set ff = Nothing
　　　　　　MsgBox "全プレゼンテーションの印刷が終わりました。"
　　　　Else
　　　　　　MsgBox "このフォルダにPowerPointプレゼンテーションはありません。"
　　　　End If
　　End With
End Sub