波線

質問

エクセル２０００で波線は引く事は可能ですか？

回答No.3

xls88

フリーフォームで代用します。試しにマクロを組んでみました。

Sub test波線()
　　Dim myrng As Range
　　Dim L As Double
　　Dim T As Double
　　Dim W As Double
　　Dim H As Double
　　Dim i As Integer
　　Dim ti As Double
　　Dim wi As Double

　　Const n As Integer = 50 '頂点数
　　Const s As Double = 2 '振幅

　　Set myrng = ActiveSheet.Range("F5:I5")
　　'**データ収集
　　With myrng
　　　　L = .Left
　　　　T = .Top
　　　　W = .Width
　　　　H = .Height
　　End With
　　'**フリーフォーム描画
　　With ActiveSheet.Shapes.BuildFreeform(msoEditingAuto, L, T + H / 2 - s)
　　　　'**頂点の編集
　　　　For i = 1 To n - 1
　　　　　　'*各頂点のY座標
　　　　　　If i Mod 2 = 1 Then
　　　　　　　　ti = T + H / 2 + s
　　　　　　Else
　　　　　　　　ti = T + H / 2 - s
　　　　　　End If
　　　　　　'*各頂点のX座標
　　　　　　If i = 1 Then
　　　　　　　　wi = W / (n - 2) / 2
　　　　　　ElseIf i <= n - 2 Then
　　　　　　　　wi = wi + W / (n - 2)
　　　　　　ElseIf i = n - 1 Then
　　　　　　　　wi = wi + W / (n - 2) / 2
　　　　　　　　ti = T + H / 2
　　　　　　End If
　　　　　　'*頂点の追加挿入
　　　　　　.AddNodes msoSegmentCurve, msoEditingAuto, L + wi, ti
　　　　Next i
　　　　.ConvertToShape
　　End With
End Sub

回答No.2

gyouda1114

どんなところに使う波線かわかりませんが
エクセルには波線はないようです

代替案　
テキストボックス（幅は、必要に応じて適宜設定）に「波線～又はチルド~」を続けて複数入力し線の色を「なし」にして、図形として貼付、必要に応じ、テキストボックスの高さをトリミングをして使う

下線を波線に
http://detail.chiebukuro.yahoo.co.jp/qa/question_detail.php?queId=7588845

エクセルのグラフで途中省略の波線
http://oshiete1.goo.ne.jp/qa591187.html

回答No.1

milknmilkn

基本的にはできません
いちお　参考URLよりコピーするなどして　引くしかないと思います。

参考URL：

http://www.geocities.jp/chiquilin_site/data/060310_autoshape2.html