エクセルVBAで再質問です。

質問

QNo4011183で質問したもので、また質問です。
前回の回答で、以下のような良回答をいただきました。
A1セルで名前を選択して、その名前と同じ定義済みの別シートの範囲
を、違うシートにコピーする、というものです。
使っているうちに気づいたのですが、コードを書いてあるシート
のどこを入力しても反応(メッセージがでます)してしまいます。
これは、回答者様からのコードを自分の設定に合わせて変更した
ものですが、このように使っています。この場合、「入力」シート
のG10セルのリスト(入力規則)で選択されたものに反応してくれ
たらいいのですが、他のどのセルでも反応し、“変更しました。”
と書いてあるメッセージが出ます。これをなんとかできないでし
ょうか？度々すみませんが宜しくお願いします。

Private Sub Worksheet_Change(ByVal Target As Range)
Sheets("組版").Select
ActiveSheet.Range("A13:V21").Clear
Sheets("入力").Select
If Target.Address = "$G$10" Then
Sheets("登録").Range(Target.Value).Copy
Sheets("組版").Range("A13").PasteSpecial Paste:=xlAll
Application.CutCopyMode = False
End If
MsgBox "変更しました。"
End Sub

回答No.1

mitarashi · ベストアンサー

wait4uさんは飲み込みの良い方の様ですので、もう少し考えればご自分でも分かると思いますが、さわりだけ、説明いたします。
>他のどのセルでも反応し、“変更しました。”
この様な事態を防ぐために、
If Target.Address = "$G$10" Then
略
End If
がありますので、その外にコードを書いてはダメです。
また、おまけに付け加えますが、このイベント処理内でセルをいじって、イベントが重複して発生するのを防止するために、
application.enableevent = false/true
というのもあります。今回は、1セルに限定しているので、これを使うまでもありませんが、ご参考まで。

お礼

たびたび申し訳ございませんでした。
>その外にコードを書いてはダメです。
この辺りがまだわかっていないのですね。お教えいただきありがとうございました。

回答No.2

Wendy02

こんばんは。

本来、入力規則ではなく、ComboBox などのほうがよいですね。

また、シートモジュール上で、また、イベント・ドリブン型で、シートのSelect を連発するのは、ちょっとまずいですね。

>A1セルで名前を選択して、その名前と同じ定義済みの別シートの範囲
この意味がはっきりしないけれども、

Sheets("登録").Range(Target.Value).Copy
Target.Value が、入力規則から取った、「名前定義」の名前だとしたら、それは、「登録シート」になくてはならないと思います。そうして、その登録シートに「名前定義」してあるなら、そのままで、Rangeオブジェクトは、取れるはずだと思います。シート名を入れると、逆に二重の手間になってしまいます。

ただ、マクロに慣れている人なら、名前定義など使わないで、実際、登録シートに製品名を探したほうが確実で、ミスが少ないです。

たぶん、こんなところかな？
なお、イベント・ドリブン型では、除外条件を先に置くのが一般的です。

-----------------------------------------

Private Sub Worksheet_Change(ByVal Target As Range)
　　Dim rng As Range
　　If Target.Address <> "$G$10" Then Exit Sub
　　If Target.Value = "" Then Exit Sub

　　On Error Resume Next
　　　Set rng = Application.Range(Target.Value) '入力値をチェック
　　　If Err.Number > 0 Then Exit Sub
　　On Error GoTo 0
　　Worksheets("組版").Range("A13:V21").ClearContents
　　rng.Copy Worksheets("組版").Range("A13")
　　Beep　'MsgBox "変更しました。
End Sub

----------------------------
なお、「名前定義」を使ったコードは、他人には、完全にコードは読みきれませんから、うまくいかないかもしれません。

お礼

ご回答ありがとうございました。まだお教えいただいたことのすべてを理解できるとはいきませんが、覚えたいと思っているモノにとって大変有益なことも教えていただき、ありがたいです。コードも完璧でした。今回#1さんの再回答いただけたということで次点にさせていただきますが、順番を付けるのはいつも大変気が引けます。。。