エクセル関数で文字を一つ飛ばしにリンクさせたいのですが。。。

質問

エクセルで子供に英単語の暗記カードを作ってあげたいのです。
シート１に英単語のデータ（単語、意味、発音記号）があり、それをシート２に印刷用としてリンクさせたいのですが、
１単語のカードが（単語、意味、発音記号）の３行で出来ているため普通にリンクを貼って３行をセットに下へドラッグしても、
単語のデータが２行とばしでしかリンクされなくて困っています。

印刷用シートは横２行になっているので、データを１行目→２行目１行目→２行目…と交互に入るように設定したいのですが。。。

　-データ-（シート１）　　　　　　　　-印刷用-（シート２）
television　　テレビ　記号　　　　　　television　　telephone
telephone　　 電話　 記号　　→　　　　テレビ　　　　電話
floor　　　　　床　　 記号　　　　　　　 記号　　　　 記号
calculator　 電卓　 記号　　　　　　　floor　　　 calculator
　　　　　　　　　　　　　　　　　　　　床　　　　　電卓
　　　　　　　　　　　　　　　　　　　 記号　　　　 記号

１行目には奇数の単語、２行目には偶数の単語がリンクされる様にすれば良いのではないか？と考えたのですが、どの様な関数を使えば
良いか分かりません。

あと関数とは別なのですが、それぞれのカードの裏に単語の意味の
イラストをつけて印刷したいのですが、エクセルにイラストを沢山
つけて保存することは可能でしょうか？

よろしくお願いいたします。

回答No.2

imogasi · ベストアンサー

リンクという言葉を使う人（質問が）がありますが、色々の意味で使われるので、関数関係なら、参照や代入が良いのでは無いでしょうか。
Ｓｈｅｅｔ２で（持ってくる方を中心に関数は考えます）ので
行と列の番号を並べると
　Ｃ列　　Ｇ列と仮定
（１，１）　　（２，１）
（１，２）　　（２，２）
（１，３）　　（２，３）
（３，１）　　（４，１）
（３，２）　　（４，２）
（３，３）　　（４，３）
・・
関数は式の複写の仕組みを使えてこそ便利なのでそれに便利なように
列の式を構成します
Ｃ１は３単位でカウントアップし、行が１つづつ増えてもすぐには
アップしない。
それは、定石があって,iを行番号として
=(i-1)/3+1　
=(INT((ROW()-1)/3)+1)
とすれば
1
1
1
2
2
2
3
のようになります。しかし印刷のことを考えると空白行をはさむ必要もあるでしょう
1
1
1
--
--
2
2
2
--
になってほしいでしょう。
すると３－＞５にして
=IF(MOD(ROW()-1,5)>2,"",(INT((ROW()-1)/5)+1))
とすると
1
1
1
-
-
2
2
2
-
-
3
3
のようになります。
これで行の決定は終ります。
ーーー
列ですが
これも行と関連付けて
=IF(MOD((ROW()-1),5)>2,"",MOD((ROW()-1),5)+1)
とします。下方向に式を引っ張ると
1
2
3
-
-
1
2
3
-
のようになります。
（１，１）　
（１，２）　
などでなく実際のセルの値を採ってくるのは
ＩＮＤＥＸ関数でぎょう、列を指定してデータを採ってくる関数なので
=INDEX(範囲、行、列）
で範囲はＳｈｅｅｔ１のＡ，Ｂ，Ｃ列です。
行は（１，１）の初めの数字に当たる数。
列は（１，１）の後めの数字に当たる数です。
Ｓｈｅｅｔ２の塊として２列目は
行は１列目の塊の対応行の数に＋１
列は１列目の塊の対応行の数と同じ
ーー
これだけで考えは終わり。
ーーー
具体的には
質問どおりのＳｈｅｅｔ１のデータを使う・
Ｓｈｅｅｔ２の
Ｃ１に
=INDEX(Sheet1!$A$1:$E$101,IF(MOD(ROW()-1,5)>2,101,(INT((ROW()-1)/5)+1)),IF(MOD((ROW()-1),5)>2,5,MOD((ROW()-1),5)+1))
と入れて、下方向に式を複写する。
television
テレビ
X
ー
ー
telephone
電話
Y
ー
ー
floor
床
Z
ー

(注）余白に当たるセルに、空白を出すためＥ１０１を使いそのセルを
１スペース入れてます。
ーー
間額なるのでＳｈｅｅｔ２の第2の塊列の説明は略。
＝＝＝＝＝＝
こんなに面倒くさくなるのも関数に固執するため。
ＶＢＡでやらないと普通はダメな問題でしょう。
印刷の自動化、１枚の紙に何セット１語のデータの塊を印刷するか
などの課題からも。

お礼

こちらもスゴイ！出来ました～！！
いろいろ丁寧にご説明下さってありがとうございます。
やはりＶＢＡでするのが良いのですよね。ですが私のレベルではサッパリで。。。
空白を入れずに作っていたので少し戸惑いましたが、今後使うことがありそうなので
参考にさせて頂きます！
ありがとうございました～！！

回答No.3

noname#79209

エクセルを使うより、以下のソフトをつかうほうが楽なのでは？
http://www.labelyasan.com/index.html
元データとしてエクセルファイルが使えます。

お礼

こんな便利なものがあるのですね！今後も何かと使えそう！
一度手作りで気の済むまでやってみてから検討したいと思います！
ありがとうございました～。

回答No.1

maron--5

◆Sheet1
　　　　　A　　　　　　　　B　　　　　C
1　　　television　　　テレビ　　　○
2　　　telephone　　　電話　　　　▲
3　　　floor　　　　　　　床　　　　　■
4　　　calculator　　　電卓　　　　★

◆Sheet2
　　　　　　A　　　　　　　　　　B
1　　　television　　　　telephone
2　　　　テレビ　　　　　　　電話
3　　　　　　○　　　　　　　　　▲
4　　　　floor　　　　　　　calculator
5　　　　　床　　　　　　　　　電卓
6　　　　　　■　　　　　　　　　★

A1=INDEX(Sheet1!$A:$C,INT((ROW(A1)-1)/3)*2+COLUMN(A1),MOD(ROW(3:3),3)+1)
★右と下にコピー

お礼

出来ましたー！！スゴイ！嬉しい～ ヽ(感'∀'激)ノ
３日間 悩み続けていたことがこんなに早く解決できちゃうなんて、
もっと早く皆さんにお伺いすれば良かった！
（数式を見て、私が考えても全くムダであったことを知りました。。。）
ありがとうございました～！