2次配列について Null値?

質問

例えば、あるセル範囲（ここではA1:B3としておきます）に

[ 1 ] [ 4 ]
[ 2 ] [ 5 ]
[ 3 ] [ ]

というように数値が入力されているとします。

RefEdit1つと[実行]ボタン1つ、[キャンセル]ボタン1という簡単なユーザーフォームを作成して以下のようなコードを書きます。

' 実行ボタンに登録したコード
Private Sub CommandButton1_Click()
Dim myRange As String
Dim dat As Variant

myRange = RefEdit1.Text
dat = Range(myRange) '選択したセル範囲のデータをdatに代入

Unload UserForm1 'ユーザーフォームの終了
End Sub

' キャンセルボタンに登録したコード
Private Sub CommandButton2_Click()
Unload UserForm1 'ユーザーフォームの終了
End Sub

それで質問なのですが、この場合、dat(3,2)には何が入っていることになっているのでしょうか。Null値なるものが代入されているのでしょうか、、、

最終的にデータ行列において、各列のデータ数を取得したいのですがどうすればよいでしょうか。1列目=3、2列目=2といったように。

もしNull値?が代入されていることになっており、2次配列においてNull値を判断する関数でもあればそれをカウントして、列数-Nullの数で取得できるだろうと考えてはいるのですが。

回答No.1

redfox63 · ベストアンサー

RangeのValueプロパティを IsEmpty関数で判断することになります

Private Sub CommandButton1_Click()
　　Dim r As Range, r1 As Range
　　Set r = Range(RefEdit1.Text)
　　For Each r1 In r
　　　　If IsEmpty(r1.Value) Then
　　　　　　MsgBox r1.Address(0, 0) & "未入力です"
　　　　End If
　　Next
End Sub
といった具合に
# 字下げは全角スペースです

お礼

回答ありがとうございます。

IsEmpty()で数値が入力（代入）されているかどうか判断できたのですね。これを使ってうまく各列のデータ数を取得することができました。

回答No.3

imogasi

（１）RefEdit1コントロールは、ＶＢのコントロールですが、エクセルとの連携で使うことを考えられているようです。余談ですが
A=Application.inputbox("範囲",type:=8)と同じ用途のようです。
（２）そこで、エクセルに話題を移すと、
＞2次配列について　Null値?は、質問者の独断ではないですか。表のイメージ的には、エクセルのセル範囲や表は配列とイメージできますが、ＶＢやエクセルＶＢＡの配列と言ってよいのでしょうか。もちろんＣｅｌｌｓ（行、列）の指定などしょっちゅう使っておりますが。
（３）RefEdit1で範囲指定したとき、その影として配列ｄ（ｘ、ｙ）が背後で作られている確証はお持ちですか。
多分作られてない
（４）従って、質問は、エクセルのセルそのものの、空白セルの判別法の話題として聞けばよいことになります。
実行時にRefEdit1で範囲指定ーー＞ＶＢのRefEdit1の機能で配列に
セルのデータが移る。その際、セルの値と違う移り方をする、
なら本質問は成り立ちます。
しかしそうではない＝別に配列を作らないと思う。
（５）結局実行時にRefEdit1で範囲指定でＶＢから返してもらえる
データは、範囲を表す、文字列だけ、ではないですか。
エクセルＶＢＡの、．Ａｄｄｒｅｓｓで返る文字列ではないですか。
（６）既存回答も（５）のとおり、その範囲文字列を、エクセルＶＢＡで使って処理して、そのエクセルのセルの値を問題にし、エクセルでいう、空白セルはどうして判別できるかの答えとなっていると思う。
（７）ただし結局、実行時にRefEdit1で範囲指定でＶＢから返してもら得るデータは範囲の文字列を使うには、エクセルの世界では、
Ｒａｎｇｅ（範囲文字列）で捉えられるが、今はエクセル世界ではないので、橋渡しがどうかとなると、同じくＲａｎｇｅ（範囲文字列）
で使えるようです。
そして、ＦｏｒＥｅａｃｈが使えて、メンバーのセルを捉えられる
（８）そして、空白はＩｓＥｍｐｔｙで捉えられる。
（９）エクセルの世界でも
Sub test08()
If IsEmpty(Cells(10, "B")) Then
MsgBox "空白" & Cells(10, "B").Address
Else
MsgBox "空白でない" & Cells(10, "B").Address
End If
はできる。
ーー
Sub test09()
If Cells(10, "B") = "" Then
MsgBox "空白" & Cells(10, "B").Address
Else
MsgBox "空白でない" & Cells(10, "B").Address
End If
End Sub
でもできる。
（１０）ＶＢの世界で
test09()ができるか。
Private Sub CommandButton1_Click()
MsgBox RefEdit1.Value
Dim rng As Range, r As Range
Set rng = Range(RefEdit1.Value)
For Each r In rng
If r.Value = "" Then
MsgBox r.Address & "空白です"
Else
MsgBox r.Address & "空白でないです"
End If
Next
End Sub
が可能と思うが。
ーー
（１０）Ｎｕｌｌという言葉は他言語やアクセスでは使うようですが
エクセルＶＢＡではＩｓＮｕｌｌ関数があり、シートのワークシート関数ではＮｕｌｌという言葉は出てきません。
ＮｕｌｌとＥｍｐｔｙ
http://www.moug.net/tech/acvba/0050010.htm

お礼

回答ありがとうございます。

随分と丁寧に説明してくださってありがとうございます。コンピュータ内部のことは複雑なので、本来的には理解しておかなければならんのでしょうが、、、私にはけっこう難しいないようです(^_^;)

回答No.2

tom11

こんにちは、

以下のコードを実行すると

*************************************************

Private Sub CommandButton1_Click()

Dim c As Variant
Dim x As Integer
Dim y As Integer

c = Range(RefEdit1.Value)

Debug.Print RefEdit1.Value

For x = LBound(c, 1) To UBound(c, 1)
For y = LBound(c, 2) To UBound(c, 2)

Debug.Print x, y, c(x, y), IsNull(c(x, y)), IsEmpty(c(x, y))

Next
Next

End Sub
******************************************************
実行結果
Sheet1!$A$1:$B$3
1 1 1 False False
1 2 4 False False
2 1 2 False False
2 2 5 False False
3 1 3 False False
3 2 False True
*******************************************************

配列の空白部分は、nullでは、表現できないようです。
emptyで、表現できるようです。
あとlbound,uboundを利用すれば、
行の数と、列の数は、計算できますね。

お礼

回答ありがとうございます。

具体的なプログラムを提示してくださってありがとうございます。
話は別になりますが、Debug.Printとするとイミディエイトウィンドウに出力できたのですね。私は今まで知りませんで、途中の計算結果はMsgBoxでイチイチ表示しておりましたからとても参考になりました。