VBA コマンドボタンにおけるコードについて

質問

下記のようなコードを作成しました。
これを簡略化するにはどうすれば良いのでしょうか？
よろしくお願いします。

Private Sub CommandButton1_Click()
Sheets("sheet2").Select

Select Case UserForm1.ComboBox1.Text

Case Is = Sheets("sheet2").Range("A1").Value
Sheets("sheet2").Range("B1").Value = "X"

Case Is = Sheets("sheet2").Range("A2").Value
Sheets("sheet2").Range("B2").Value = "X"

Case Is = Sheets("sheet2").Range("A3").Value
Sheets("sheet2").Range("B3").Value = "X"

Case Is = Sheets("sheet2").Range("A4").Value
Sheets("sheet2").Range("B4").Value = "X"

Case Is = Sheets("sheet2").Range("A5").Value
Sheets("sheet2").Range("B5").Value = "X"
・
・
・
End Select

End Sub

回答No.3

tom11 · ベストアンサー

訂正

Dim r As Integer

For r = 1 To 100

If UserForm1.ComboBox1.Text = Sheet2.Cells(r, 1) Then Sheet2.Cells(r, 2) = "X"

Next

お礼

ご回答ありがとうございます。
ループですね！
これなら私でもわかります。
助かりました。

回答No.5

imogasi

#4です。
＞A列にコンボボックスで選択した文字と同じ文字があったら、該当行のB列に"X"を設定する」ということです。
これで少しはっきりしましたが、私にはまだ２，３の状況のバリエーションがあると思うが。
ーー
ということなら
（１）ＦｏｒＮｅｘｔ繰り返し法（コード行数約５行
（２）Ｆｉｎｄメソッド利用法（10行近く
（３）Ｍａｔｃｈ関数利用法（コード行数約３行
などがある。
（２）は初心者には難しい。例はＷＥＢ照会すると沢山載ってます。
（３）の例を挙げます。
ーー
Private Sub CommandButton1_Click()
x = ComboBox1.Value
y = Application.WorksheetFunction.Match(x, Range("A1:A5"), 0)
Cells(y, "B") = "X"
End Sub
ーー
このようにエクセルやそのＶＢＡ固有の知識によるコードは、ＶＢ６．０式のコードに比べ、簡潔で、一見してやっていることが見えやすいものが多い（エクセルの知識があってのことだが）。
えくせるＶＢＡをやるなら、ＶＢのＦｏｒＮｅｘｔなど繰り回し一本でなく、上記で言う（２）（３）も無いか、その都度調べてください。質問するのも良い。
ーー
エラー対策を入れて
Private Sub CommandButton1_Click()
On Error GoTo errrtn
x = ComboBox1.Value
y = Application.WorksheetFunction.Match(x, Range("A1:A5"), 0)
Cells(y, "B") = "X"
Exit Sub
errrtn:
MsgBox "Ａ列に該当なし "
End Sub

お礼

ご回答ありがとうございます。
>えくせるＶＢＡをやるなら、ＶＢのＦｏｒＮｅｘｔなど繰り回し一本でなく、上記で言う（２）（３）も無いか、その都度調べてください
はい、わかりました。
関数はあまりわからないので、努力してみます。

回答No.4

imogasi

疑問点。
（１）ＩＳを必要とするのか
初等解説書では比較演算子以上などを使うときに使われていて、相等のケースは
Ｃａｓｅ　１
で相等のケースを担っている。
（２）こういう書き方をすると変数間の比較は、左辺の全ての値のケースを列挙し尽くして、書かなければならなくなる。
ちょっと奇妙。プログラムはそれをしないように考えるものだと思う。
（３）エクセルＶＢＡで、セルのことを問題にするとき
同一行の項目（データ）は、何かの主題の記述という点でつながっていて、無関係ではないことが多い。
その際右列は、ＯＦＦＳＥＴプロパティや、Cells(i,c+1)のようなのを使って、指し示せる。
こういうのを使ったらどうですか。
ーー
＜質問一般論＞
一般に、質問で、例示して説明するとき、
（１）例を列挙型
（２）特徴説明するため、文章記述型
があり、ケースバイケースでそれぞれ威力を発揮する。
（１）－＞（２）が読者にたやすいケースもある。
この質問は（１）の型だが、（２）の型で説明するとどうなるか、
説明を添えてほしかった。
回答者読者も忙しいし、質問の背景がわからないし、波長が合わない記述で（２）が帰納できないこともある。
我流でまさかという考え方で取り組んで質問しているケースもある。
ーー
本件質問も、何をしたいのか、文章で特徴を書いてくれれば、短いコードが紹介できるかもしれないと思いました。
システムを作る方は、両方の力が必要と思う。

お礼

ご回答ありがとうございます。
>説明を添えてほしかった。

「A列にコンボボックスで選択した文字と同じ文字があったら、該当行のB列に"X"を設定する」ということです。
よろしくお願いします。

回答No.2

tom11

こんにちは、

例えば、100行あれば、
以下のようでは、駄目でしょうか。

Private Sub CommandButton1_Click()
Dim r As Integer

For r = 1 To 100

If UserForm1.ComboBox1.Text = Sheet2.Cells(i, 1) Then Sheet2.Cells(i, 2) = "X"

Next
End Sub

回答No.1

dsuekichi

> これを簡略化する
要するに、「A列に、指定した文字と同じ文字があったら、該当行のB列に"X"を設定する」って事ですよね？
「Findメソッドで検索する」とか・・・

例えば
-----------------------------
Private Sub CommandButton1_Click()
Dim F As Range
Dim T As Range
Dim s As String

Sheets("sheet2").Select
s = UserForm1.ComboBox1.Text
Set T = Sheets("Sheet2").Range("A:A")
Set F = T.Find(s, , , xlWhole)
If Not (F Is Nothing) Then
F.Offset(0, 1) = "X"
End If
End Sub
-----------------------------
とか・・・

お礼

早速のご回答ありがとうございます。
Findメソッドですか。
今の私では完全には理解できませんが努力してみます。