VBAの構文を教えてください。

質問

エクセルVBAについて教えてください。

現在、Excelデータを使って注文書の管理をしています。

1.注文書という名前のフォルダ
　(1)注文No.の名前でBOOK名を付け、注文をした詳細Excelデータを作成。※No.ごとの名前でExcelデータBOOKを作成しています。なのでかなりのBOOK数があります。
　(2)　(1)で作成したデータはかなりのBOOK数なので、「注文書インデックス」という名前のExcelデータBOOKをつくり、注文したNo.順で一覧表に簡易詳細を入力したデータを入力。一覧のNo.と一致するBOOKにハイパーリンクを貼り付けてダブルクリックするとそのNo.のBOOKを開けるという作業を行っています。

ハイパーリンク貼り付けをやめて、VBAで行うにはどのような構文になるのでしょうか？
VBAの知識をお持ちの方！教えてください。お願いします。

回答No.3

Wendy02

こんにちは。

これは、単なる私のアイデアですが、

適当な場所に、
C:\Documents and Settings\UserName\My Documents\Excel\
まだ、他にあるなら、
C:\Documents and Settings\UserName\My Documents\

と、セルに書いておき、
まず、挿入－名前－登録で、それぞれを、
MyDocEx

MyDoc と登録して、

以下のマクロでは、４列目(D列）に、
=MyDocEx
とすると、それらの登録したものが出てきます。
（VBE画面で登録する場合もありますが、変更があったときに、そこに書き込まなくてはなりませんから、ちょっと面倒だと思いました。）

今回は、以下のようにして、.xls がついていない場合は、.xls を付けるようにしました。
つまり、.csv などの場合は、.csv と付けてあれば、.xls は付きません。
D列でなくて、もう少し、離れたところで、列を隠しておけば、見られません。

なお、今回は、D列にパス名がついていない場合は、Excelの設定されているデフォルトのフォルダを探すように作ってあります。

すでに開いていた場合は、メッセージが出て、単にアクティベートするだけになっています。そうしないと、変更し保存していない場合に不都合があったような気がします。ただ、そのオプションは、妙に反応が遅いときがあります。

十分にテストしてから、実践でお使いくださるようにお願いします。
気持ち的には、もう少し、レイアウト的にも、マクロの内容も洗練させてあげられるとよいのですが、今のところは、私個人の負担が多くなりますので、このぐらいにさせてください。

なお、参考にはならないと思いますが、このマクロの同様の内容のものが、未だ進行中です。現在、アドイン化に変更中です。ここで書くのでは、初めての大作で、ややこしい内容です。その質問者さんは、特別な事情のある方です。
http://oshiete1.goo.ne.jp/kotaeru.php3?qid=2899966

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim FileName As String
Dim myPath As String
Dim OrgName As String
Dim i As Integer
Dim dummy As Variant

Cancel = True
If Target.Column <> 2 Then Exit Sub 'ファイル名は、2列目に書く
If IsEmpty(Target) Then Exit Sub
If InStr(1, Target.Value, ".xls", vbTextCompare) = 0 Then
　 FileName = Target.Value & ".xls"
Else
　 FileName = Target.Value
End If
If Target.Offset(, 2).Value <> "" Then 'パスは、4列目　(2列目 + 2)
　 myPath = Target.Offset(, 2).Value
　 If Right(myPath, 1) <> "\" Then myPath = myPath & "\"
　 FileName = myPath & FileName
Else
　'ない場合は、設定されたデフォルトファイルパスになります。
　 FileName = Application.DefaultFilePath & "\" & FileName
End If

If Dir(FileName) = "" Then MsgBox FileName & vbCrLf & "ファイルが見つかりません。": Exit Sub
　'すでに開いていた場合を探す。
　On Error Resume Next
　 i = InStrRev(FileName, "\")
　 If i > 0 Then
　　　OrgName = Mid$(FileName, i + 1)　'元ファイル名を出す
　 Else
　　　OrgName = FileName
　 End If
　 dummy = Workbooks(OrgName).Worksheets(1).Cells(1, 1).Value
　 If Err.Number = 0 Then
　　　Workbooks(OrgName).Activate　　'←ここが遅いようです。
　　　MsgBox "すでにブックは開いています", vbInformation: Exit Sub
　 End If
　　Err.Clear
　On Error GoTo 0
　On Error Resume Next
　 Workbooks.Open (FileName)
　If Err.Number > 0 Then
　 MsgBox Err.Number & " : " & Err.Description
　 Err.Clear
　End If
　On Error GoTo 0
End Sub

回答No.2

Wendy02

こんばんは。

>ハイパーリンク貼り付けをやめて、VBAで行うにはどのような構文になるのでしょうか？

#1さんの、Excel+VBAがなんちゃってなのかというよりも、それは、技術力の問題です。Excelで作るものは、どうしてもVBA中心になって、VBAで作りこんでいくものだから、もし、システムとしたら、こうした掲示板では公開しにくいです。ある程度、質問者さん側にVBAの知識や技術がないと、システムとしては、ごちゃごちゃになって、さっぱり分からなくなってしまうと思うのです。

私のはインターネット・ブラウザのIEで開きますが、ハイパーリンクをやめてダブルクリックであけるように出来ています。おそらくは、ご質問者さんのイメージに近いような気がします。技術的にも、ハイパーリンクは、ハイパーリンクオブジェクトとして存在してしまうので、扱いが面倒なのです。見栄えも悪いです。

一応、サンプル程度ですが、ハイパーリンクの代わりに、イベントドリブン型のプロシージャを使います。

シートモジュールに書き込みます。シートの下のシートタブを右クリックして、「コードの表示」で開く場所です。

ファイルリストは、以下では、2列目（B列）ということにしてあります。

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

If Target.Column <> 2 Then Exit Sub 'ファイル名は、2列目に書く
If IsEmpty(Target) Then Exit Sub
If InStr(1, Target.Value, ".xls", vbTextCompare) = 0 And _
　 InStr(1, Target.Value, ".csv", vbTextCompare) = 0 Then Exit Sub
If Dir(Target.Value) = "" Then Exit Sub

　Cancel = True
　On Error GoTo ErrHandler
　 Workbooks.Open (Target.Value)

ErrHandler:
　If Err.Number > 0 Then
　 MsgBox Err.Number & " : " & Err.Description
　End If

End Sub

ただ、以下のようなフルファイルネームは、本来は、別の場所に書いておいて、列を隠しておいて、

C:\Documents and Settings\UserName\My Documents\Excel\test1.xls

見える部分には、

test1.xls

としておいてもよいと思います。フルファイル名を書かない場合は、一般的には、デフォルトのフォルダになります。

このような長いファイル名が多く出てくるようでしたら、マクロは、Target.Offset(,5).Value として、ファイル名を取得するようにすると、表としてすっきりとします。

補足

ありがとうございます。出来ました。
もう少し教えてください。

2列目に書くファイル名ですが
フルファイルネームの名前の一部だけ一覧表に
test1←を入力し
C:\Documents and Settings\UserName\My Documents\Excel\　＋　.xlsを入力しない方法はありますか？

回答No.1

popesyu

構文って・・・一つの関数ぐらいで出来るシステムではないんですが。
具体的な仕様をもう少し煮詰めて、一つ一つ作っていくしかないでしょう。
例えばあるフォルダ内のファイル一覧を取得する方法
http://www.asahi-net.or.jp/~ef2o-inue/vba_o/sub05_110_080.html
特定のファイルを検索する方法
http://www.asahi-net.or.jp/~ef2o-inue/vba_o/sub05_110_130.html

この辺の機能を組み合わせて作っていくことになります。

手抜きで良いのならエクセル+VBAでなんちゃって管理システムはできますが、例えばアクセスとかそちらの方で作りこんだ方がもっとマシなものが出来ると思いますが。まぁどういうところまで一体化させるか次第ですけど。