Perlのサブルーチンの引数に配列やハッシュをCall by Valueすることはできない？

質問

タイトルどおりなんですが・・・。

　Perlのサブルーチンに配列やハッシュを実体渡ししようとしたんですが，どうやってもできません．あきらめて，参照渡しにしたら，なんかうまくいっている模様です．

　これは，そもそも，はじめから参照渡ししか用意されていない、ということでしょうか？．それとも，何か実体渡しする方法があるのでしょうか？．

　後，余談なんですが，配列やハッシュの要素に別の配列やハッシュの実体を入れることはできるのですか？．これもちょっと試してみたらできなさそうだったのですが，あちこちのWebにある入門マニュアルみたいなページを見ても，その辺の話が「できる」とも「できない」ともほとんどの場合かいてなくて，自分の試し方が悪いのか，それとも無駄なことを延々とやっているのかがわからなくて疲れます．

回答No.6

leaz024

■パラメータ渡しの仕組みについて

サブルーチンへのパラメータの渡され方ですが、まず、呼出側で指定したパラメータは１つのリストに展開されます。
そしてサブルーチン側では、そのリストの「別名配列」として @_ が用意されます。
@_ はパラメータリストの別名なので、$_[n] を操作することは、パラメータに指定した変数を直接操作していることと同じになります。
つまりPerlでは、常に「別名渡し」が行われます。
（即値やハッシュのキーのように別名が作れないものは、一時領域に値がコピーされ、その別名が渡るようです。）
ちなみにパラメータが即値である場合、変更しようとするとエラーになります。

■「値渡し」と「リファレンス渡し」について

サブルーチン側でのパラメータの操作を、呼出側の変数に反映させたくない場合は、パラメータを「値渡し」にします。
Perlでの値渡しは、サブルーチン側で用意した my（または local）変数に @_ の値をコピーすることで実現します。
また、呼出側の変数の値を操作したい場合でも、$_[n] の内容を直接編集することはあまりなく、普通はリファレンスを渡し、それをデリファレンスして値を操作します。
# 「実体渡し」とは、何が渡ることを望んでいるのでしょうか？

■複数の配列やハッシュの渡し方

パラメータは、全てが１つのリストに展開されるため、複数の配列やハッシュを渡したい場合は注意が必要です。
例えば、次のように２つの配列を渡しても、
　　@x = qw(abc def);
　　@y = (1, 2, 3);
　　&f2(@x, @y);
　　sub f2 {
　　　　my (@a, @b) = @_;　　　# ２つの配列が欲しいのでこうしたが・・・
　　　　print "a:[@a]\n";
　　　　print "b:[@b]\n";
　　}
　実行結果：
　　a:[abc def 1 2 3]
　　b:[]
１つ目の配列に、全て入ってしまいます。
これを回避するには、リファレンスを渡します。
　　&f3(\@x, \@y);
　　sub f3 {
　　　　my ($a, $b) = @_;　　　# リファレンスはスカラーなので、$変数で受け取る。
　　　　print "a:[@$a]\n";
　　　　print "b:[@$b]\n";
　　}
　実行結果：
　　a:[abc def]
　　b:[1 2 3]

■サブルーチンからの戻値について

サブルーチンからの戻値は、呼出時のコンテキストに依存します。
例えば、配列やハッシュ、リストを返していても、$変数で受け取っていたり、演算式に組み込んだりすると、それぞれに応じたスカラー値が返ります。
それ以外では、基本的にはリスト値が返ります。（配列やハッシュも、リストに展開されて返されます。）
どちらの場合でも、勝手に別名やリファレンスが返されることはありません。戻値は常に値渡しです。
# ハッシュは return できない、とありましたが、もちろんできます。

■配列とリストについて

とかく同じ物と思われがちですが、これらは別物です。
例えば、それぞれをスカラーコンテキストで参照すると、配列は「要素数」が返るのに対し、リストでは「最後の要素」が返ります。
また、当然ながらリストには変数領域がないので、暗黙に配列へのリファレンスを引数に取る push 関数などには、リストは渡せません。
リストはあくまで、その場限りのものです。

■無名配列、無名ハッシュについて

これらは、変数の必要なしに、配列やハッシュの中身をメモリ上に生成するものです。
無名配列は　　　[ リスト ]
無名ハッシュは　{ リスト }
として、生成します。
これらの値は、それぞれ「配列へのリファレンス」「ハッシュへのリファレンス」です。
> 配列やハッシュの要素に、別の配列やハッシュを入れる
というのは、この無名＊＊を使います。（つまり、配列などの実体は入れられません。）
例えば、４×３の２次元配列は、次のように作ります。
　　my @a = ( [0,1,2,3],[4,5,6,7],[qw(a b c d)] );
各要素を見るときは、
　　foreach $row (@a) {
　　　　foreach $val (@$row) {
　　　　　　print "$val ";
　　　　}
　　　　print "\n";
　　}
とか、
　　foreach $r (0..2) {
　　　　foreach $c (0..3) {
　　　　　　print "$a[$r][$c] ";
　　　　}
　　　　print "\n";
　　}
とします。

■No.4 の補足について
タイプミスかもしれませんが、
　　sub subroutine {
　　　　my $sch = $_[0];
　　　　my $arr = @{ $_[1] };
　　　　my $hsh = %{ $_[2] };
　　}
これではダメです。
やるなら、
　　sub subroutine {
　　　　my $sch = $_[0];
　　　　my @arr = @{ $_[1] };
　　　　my %hsh = %{ $_[2] };
　　　　$arr[0] = …
　　　　$hsh{AAA} = …
　　}
とするか、
　　sub subroutine {
　　　　my $sch = $_[0];
　　　　my $arr = $_[1];
　　　　my $hsh = $_[2];
　　　　$arr->[0] = …
　　　　$hsh->{AAA} = …
　　}
とします。

分からない部分は補足してください。