条件に合うデーターを任意のセル間で累計、合計するには？２

質問

下記のような出荷予定表があります。非常に細かく数量、モデルは分かれておりますが、対応コードはＮＴ－２３３，２３６，３３４の３つなんですが（対象外の時もあり、空白が該当）この中で、対応コードの横列に各対応コード毎にまとめ、切替わる地点間の合計を出したいのですが、どうすればよいでしょうか?
　式をフィルドラッグで出したいのです。
　ＩＦ，ＳＵＭＩＦ関数を使うのは分かっていますが、対応コードが連続した間毎の累計合計を出すと言う条件設定、セル指定が理解記述できません。どなたかアドバイスお願いします。　　

　Ａ　　　　　Ｂ　　　　Ｃ　　　　　　　Ｄ
出荷モデル 数　量 対応コード　　　コード条件連続時累計合計
ＰＷ－Ｚ７　 ４０ 　　ＮＴ－２３３
ＰＷ－７１ 　６０ 　　ＮＴ－２３３　　１００と表示したい
ＰＷ－６３　 ８０ 　　ＮＴ－２３６
ＰＷ－Ｚ５ 　２０ 　　ＮＴ－２３６
ＰＷ－５０ 　３０ 　　ＮＴ－２３６
ＰＷ－Ｚ４ 　４０ 　　ＮＴ－２３６
ＰＷ－４０ 　５０ 　　ＮＴ－２３６　　２２０と表示したい
ＰＷ－３６ 　６０
ＰＷ－Ｚ４ 　５０ 　　ＮＴ－２３６
ＰＷ－４０ 　１５０ 　ＮＴ－２３３
ＰＷ－４０ 　４０ 　　ＮＴ－２３６
ＰＷ－２８ 　７０
ＰＷ－２８ １８０
ＰＷ－Ｚ２ ４５０
ＰＷ－Ｚ２ ４４０ 　　ＮＴ－３３４
ＰＷ－２５ 　７０ 　　ＮＴ－３３４
ＰＷ－２５ 　７５ 　　ＮＴ－３３４
ＰＷ－２２ 　６０ 　　ＮＴ－３３４
ＰＷ－２２ １６０ 　　ＮＴ－３３４
ＰＷ－Ｚ２ １８５ 　　ＮＴ－３３４　　　９８５と表示したい
ＰＷ－ＥＺ 　３０ 　　ＮＴ－２３６
ＰＷ－ＥＺ 　５０ 　　ＮＴ－２３６　　　　８０と表示したい
ＰＷ－ＥＺ 　２０
ＰＷ－ＥＺ １００
ＰＷ－ＥＺ 　８０ 　　ＮＴ－３３４
ＰＷ－ＥＺ 　５０ 　　ＮＴ－３３４　　　１３０と表示したい

回答No.2

noname#40742 · ベストアンサー

再びNo.1 です。

=IF(AND(C2<>"",C2<>C3),SUMIF($C$2:C2,C2,$B$2:B2)-SUMIF($C$1:C1,C2,$D$1:D1),"")

前半のSUMIF は、同一コードの累計、
後半のSUMIF は、同一コードの既出累計（D列）の合計、
その差を求めることで、その行まで連続している累計をだしています。
最初の行からの累計しかでないとなると、後半のSUMIF が生きていないようです。

こちらではフィルドラッグして正しく反映しています。

お礼

重ね重ねの回答有難うございました。
もう一度、慎重に入力した結果、正確に値を出せました。D2セルに入れる式をD1セルに入れていたからおかしくなっていたと思います。

　有難うございました。

回答No.3

noname#204879

原始的な方法ですが…
１．セル E2、F2、G2、D2 にそれぞれ次式を入力
　　E2: =IF(C2="","",C2<>C3)
　　F2: =IF(C2="","",C2<>C1)
　　G2: =IF(E2=FALSE,IF(F2=TRUE,1,G1+1),IF(F2=FALSE,G1+1,""))
　　D2: =IF(C2="","",IF(AND(E2,NOT(F2)),SUM(OFFSET(B2,-G2+1,0,G2,1)),""))
２．範囲 D2:G2 を下方にズズーッと複写

お礼

回答有難うございます。NO.1の方のアドバイスで何とかできましたが、mike_gさんの回答方式でも再現できました。

　私はオフセット、アドレス等の関数は苦手であまり使いませんが、基本を覚える意味では大いに参考になりました。

　有難うございました。

回答No.1

noname#40742

連続しない行（たとえば「２２０と表示したい」行の下２行目から４行目までの
単独行）も数字表示してよければ、

Ｄ２：=IF(AND(C2<>"",C2<>C3),SUMIF($C$2:C2,C2,$B$2:B2)-SUMIF($C$1:C1,C2,$D$1:D1),"")

補足

ご回答有難うございます。早速実行してみましたが、私のやり方が悪いせいもあるのか、先頭行からの累計が表示されてしまいます。

　説明不足で申し訳ありませんが、スタート行からの累計ではなく、同じ対応コードが連続する範囲のみ、その区間だけの合計をフィルドラッグで出さればいいなーと思っているのですが。
　スキルが低くて申し訳ありません。教えいただいた数式で後半の)-SUMIF($C$1:C1,C2,$D$1:D1)の部分が今一、理解できてないようです。

　もう一度、試してみます。すみません。