【Excel】オプションボタンで選択したら〇で囲む

質問

ご教授ください。

エクセルにてオプションボタンで選択したら選択した項目に〇をつけたいです。

例
〇男 〇女 〇その他
（↑このオプションボタンをどれか選択）

―――――――――

男 ←丸で囲われる） 女 その他

集計ではなく〇で囲われた方を印刷して使用したいです。
マクロを使用するのかルールで表示させる事が可能なのかどのようなやり方がスムーズなのかたどり着けません。

よろしくお願いいたします

回答No.2

HohoPapa · ベストアンサー

一般にVBAで実現する課題と思います。

コードと画面sampleをポストしますので
よかったら参考にしてください。

'以下をSheet1モジュールに貼り付けます。

Option Explicit

Private Sub OptionButton1_Click()
　sample
End Sub

Private Sub OptionButton2_Click()
　sample
End Sub

Private Sub OptionButton3_Click()
　sample
End Sub

'以下を標準モジュールに貼り付けます。

Option Explicit

Sub sample()

　If Sheet1.OptionButton1.Value = True Then
　　MaruKakomi 1
　End If
　If Sheet1.OptionButton2.Value = True Then
　　MaruKakomi 2
　End If
　If Sheet1.OptionButton3.Value = True Then
　　MaruKakomi 3
　End If

End Sub

Sub MaruKakomi(ButtonNum As Long)

　Dim Sh As Worksheet
　Dim Nm As String
　Dim Bx As Double
　Dim By As Double
　Dim Wi As Double
　Dim Hi As Double
　Dim Cr As Long
　Dim tgRng

　tgRng = Array("", "B6", "C6", "D6")

　Set Sh = ThisWorkbook.Sheets("Sheet1")
　Nm = "Maru"
　Bx = Sh.Range(tgRng(ButtonNum)).Left
　By = Sh.Range(tgRng(ButtonNum)).Top
　Wi = Sh.Range(tgRng(ButtonNum)).Width
　Hi = Sh.Range(tgRng(ButtonNum)).Height
　Cr = rgbRed
　MakeCircle Sh, Nm, Bx, By, Wi, Hi, Cr

End Sub

'//-----------------------
'//　楕円描写プロシジャー
'//-----------------------
Sub MakeCircle(Sh As Worksheet, _
　　Nm As String, _
　　Bx As Double, By As Double, Wi As Double, Hi As Double, _
　　Cr As Long)

　Dim shp As Shape

　On Error Resume Next
　Set shp = Sh.Shapes(Nm)
　shp.Delete
　On Error GoTo 0

　Set shp = Sh.Shapes.AddShape(msoShapeOval, Bx, By, Wi, Hi)
　shp.Name = Nm
　shp.Fill.Visible = msoFalse
　shp.Line.Visible = msoTrue
　shp.Line.ForeColor.RGB = vbRed
　shp.Line.Transparency = 0

End Sub

回答No.1

iyonohanamuko

別シートに同じようなものを作成し、

ラジオボタンで選択したものをクエリで表示させるようにして、

そのシートを印刷してみてはいかがでしょうか？