Vba UserForm SetFocus

質問

• ExcelのVbaでタイピング練習のソフトを作成する際、UserForm上のテキストボックス間のフォーカス移動について困っています。
• コントロールのイベントについての理解が不足しており、タイミングや連鎖、終了に関するエラーが発生しています。
• どなたかこれらの問題の解決策を教えていただけないでしょうか。よろしくお願いします。

回答No.1

real beatin（@realbeatin）

こんにちは。
ネスト構造を整理して考えたら矛盾に気が付くのでは。

Sub CommandButton1_Click()
　TextBox3.SetFocus
　┃上記処理実行中
　┣ Sub TextBox3_Enter
　┣　┣ MsgBox "In TextBox3"
　┣　┣ TextBox2.SetFocus
　┣ End Sub
　┗上記処理確定
End Sub

↑これは処理そのものの階層構造（ネストレベル）を示すとともに、
　処理を時系列順に並べたものです。

TextBox3.SetFocus の処理確定のタイミングで、
フォーカスがTextBox2にあるという結果に対して、
TextBox3.SetFocus 処理は失敗したことになります。
メソッドが失敗すれば、それはエラーになりますし、
.SetFocusメソッドは戻り値を持たない
（FunctionではなくてSub）タイプのメソッドですので、
エラーは即ち実行停止につながります。
Private Sub CommandButton1_Click()
　　On Error Resume Next
　　TextBox3.SetFocus '　・・・（１）
　　On Error GoTo 0
End Sub
のようにすれば実行時エラーでも停止しないようにはできますが、
元々のTextBox3.SetFocus→TextBox2.SetFocus
という不自然な連続フォーカス移動自体、
ネストすることが間違いです。
何故、そういったことをしたいのか説明して貰えれば、
他に方法を提案することも可能です。
どうしてもその連続フォーカス移動を実現させる必要がある、
ということでしたら、
メソッドのネスト
【メソッドの実行が終る前に他のメソッドを実行させ結果に影響を与えること】
を解いて、
非同期でそれぞれの処理を順番に実行→終了させるような手段として、
メソッドをイベント内に書くのはやめて、
別途Sub（サブルーチン）として標準モジュ－ルに記述したものを、
Application.OnTimeメソッドで呼び出すやり方が
一般的な対処です。

' ' // 標準モジュール
Private Sub SetFocusTxb3()
　　UserForm1.TextBox3.SetFocus
　　Debug.Print "SF3"
End Sub
Private Sub SetFocusTxb2()
　　UserForm1.TextBox2.SetFocus
　　Debug.Print "SF2"
End Sub
' ' // UserForm1モジュール
Private Sub CommandButton1_Click()
　　Debug.Print 1
　　Application.OnTime Now, "SetFocusTxb3"
　　Debug.Print 2
End Sub
Private Sub TextBox3_Enter()
　　MsgBox "In TextBox3"
　　Debug.Print 3
　　Application.OnTime Now, "SetFocusTxb2"
　　Debug.Print 4
End Sub

Debug.Printはトレース（デバッグ）用の記載ですが、
これによって、
すべて指示した順番に処理が完了していること
それぞれのプロシージャを抜けてから次のプロシージャに進んでいること
つまり、ネストが解かれていることが確認できると思います。
ただ、このやり方が本件の解決策として正しいかは疑問です。
今一度、何をやりたいのかよく整理するようにして、
処理フローの最適化を図ってみた方がいいのかも、です。

尚、気になさっている、TabStop,TabIndexに関しては、
今回の問題に影響を与えるものではありません。
ただ、それ以外の面で、CommanButtonについては、
TabStopが必要か、TakeFocusOnClickが必要か、
よく考えて決めた方がいいと思います。

以上、ご参考まで。

お礼

realbeatinさん、早速の回答ありがとうございます。以前何度かお世話になり、その節は大変勉強させていただきました。「OKAWAVEでは質問する前に関連しそうなQ&Aを調べ、目を通しておく」というマナーを忘れていました。申し訳ございません。関連Q&Aに目を通す前に返事を書かせてもらいます。
ネスト構造を示していただき、よく分かりました。
＞元々のTextBox3.SetFocus→TextBox2.SetFocus
＞という不自然な連続フォーカス移動自体、
＞ネストすることが間違いです。
自分の理解のための質問用に作りました。ごめんなさい。
＞【メソッドの実行が終る前に他のメソッドを実行させ結果に影響を与えること】
＞・・・
＞Application.OnTimeメソッドで呼び出すやり方が一般的な対処です。
全く知りませんでした。勉強します。
現在作成中の英単語タイピングソフトでイベントメソッドの連鎖が本当に必要か検討したいと思います。必要なら、イベントメッソドの中で別のイベントメッソドを呼び出すときは終了と連鎖に注意しながら利用したいと思います。
解決できない場合、再度質問したいと考えています。その際にはよろしくお願いします。
本当にありがとうございました。