二つのタブを開き、二つ目のタブに対して、操作し

質問

vbaのie操作で
一つ目はタブはグーグルメール
二つ目のタブはドコモメールを開きたいのですが、
ドコモメールはPWをVBAで入れないと進めないので入れたいのですが

Sub test()
Dim myObj As Object
Dim objIE As InternetExplorer

Set objIE = CreateObject("InternetExplorer.Application")

With objIE
.Visible = True
.Navigate "https://mail.google.com/mail/u/0/?pli=1#inbox"　’グーグル
End With

objIE.Navigate2 "https://mail.smt.docomo.ne.jp/mail/#fid=10000000&page=1", 2048　’ドコモ

For Each myObj In objIE.document.all.tags("input")
If myObj.ID = "persistent" Then
myObj.Value = "PW"
Exit For
End If
Next

Set objIE = Nothing
End Sub

だと、
For Each myObj In objIE.document.all.tags("input")
は、グーグルメールを参照しています。

LocationURLを見てみたら、
"https://mail.google.com/mail/u/0/#inbox" になっていました。

このように、二つのタブを開き、二つ目のタブに対して、操作したい場合
どうすればいいでしょうか？

回答No.2

real beatin（@realbeatin） · ベストアンサー

こんにちは。

' ' 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓
' ' 参照設定 ■ Microsoft Internet Controls ■ SHDocVw
Sub ReW9095183()
Const navOpenInNewTab = 2048
Dim myObj As Object
Dim objIE As InternetExplorer
Dim objIE2 As InternetExplorer
Dim objShell As Object　'　As Shell32.Shell　'　■ Microsoft Shell Controls And Automation ■ Shell32
Dim cnWnd As Long
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
　　Const GOOGLE = "https://mail.google.com/mail/u/0/?pli=1#inbox"
　　Const DOCOMO = "https://mail.smt.docomo.ne.jp/mail/#fid=10000000&page=1"
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
' ' objShell.Windows で 逐一 エクスプローラ を捉える為のShell オブジェクト
　　Set objShell = CreateObject("Shell.Application")　'　　Set objShell = New Shell32.Shell
' ' objShell.Windows.Count ＝ エクスプローラ（Windows+Internet）の数、現在値
　　cnWnd = objShell.Windows.Count
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
　　Set objIE = CreateObject("InternetExplorer.Application")
　　With objIE
　　　　.Visible = True
　　　　.Navigate GOOGLE　 '　グーグル
　　　　.Navigate2 DOCOMO, navOpenInNewTab　'　navOpenInNewTab = 2048　'　ドコモ
　　End With
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
' ' objShell.Windows.Count で 追加タブの エクスプローラ が読み込まれるまで待機
　　Do While objShell.Windows.Count < cnWnd + 2
　　　　DoEvents
　　Loop
' ' objShell.Windows の 最後にあるのが 追加タブの エクスプローラ
　　Set objIE2 = objShell.Windows(cnWnd + 1)　'　ドコモ
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
　　With objIE　 '　グーグル
　　　　Do While .Busy Or .ReadyState <> READYSTATE_COMPLETE　'　 READYSTATE_COMPLETE = 4
　　　　　　DoEvents
　　　　Loop
　　' ' グーグル 処理　？
　　End With
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
　　With objIE2　'　ドコモ
　　　　Do While .Busy Or .ReadyState <> READYSTATE_COMPLETE
　　　　　　DoEvents
　　　　Loop
　　' ' ドコモ 処理
'　　　　.Document.getElementById("Di_Uid").Value = "ID"　'　? 必要ならイキ　アカウントID要指定
　　　　.Document.getElementById("Di_Pass").Value = "PassWord"　'　? パスワード要指定
'　　　　.Visible = False
'　　　　.Document.getElementsByClassName("button_submit nextaction")(0).Click　'　? ログインするならイキ
'　　　　.Visible = true
　　End With
' '　ーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーーー
'　　objIE2.Quit:　　objIE.Quit　'　? 必要ならイキ
　　Set objIE = Nothing:　　Set objIE2 = Nothing
End Sub
' ' 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓

参考URL：

http://okwave.jp/qa/q8939992.html

お礼

回答ありがとうございました。

回答No.1

heburusu

Shell.Application を使って、IEのタブを列挙＆操作できるみたいです。

参考URL：

http://vba-code.net/ie/open-link-in-new-tab/

お礼

回答ありがとうございました。