excel VBA で条件の設定方を教えて下さい。

質問

今、斜線を引きその斜線データの最初のセルに数値で（１とか３とかの数値の）条件をつけて置き、その条件で、太さ、色等を変えて斜線を引きたいのですがうまくいきません。何方か教えて頂けませんか。
---------------------
dim myrange as range
workheets("補助計算").range("c8:c47").value = worksheets("時刻").range("c8:c47").value
workheets("補助計算").range("g8:h47").value = worksheets("時刻").range("g8:h47").value
with worksheets("時刻")
　　　　v=worksheets("時刻").range("m2").value+12'描画本数
　　　 for i = 12 to v step 1'設定可能本数50本
set myrage = worksheets("補助計算").range("t3:t47")
myrange.value = .range(.cells(3,i),.cells(48,i)).value
for cnt = 75 to 113 step 2
e = worksheets("ダイヤ").cells(cnt,10).value
　　　　　　f = worksheets("ダイヤ").cells(cnt,11).value
　　　　　　g = worksheets("ダイヤ").cells(cnt+1,10).value
　　　　　　h = worksheets("ダイヤ").cells(cnt+1,11).value
with worksheets("ダイヤ").shapes.addline(e,f,g,h)
.line.weight = 1.1
.line.forecolor.rgb = vbblue
end with
next cnt
next i
end with
-----------------------
上記コードで、斜線が何本か引かれます、その際、データ元のセルに数値の条件、例えば、1
とか3とかの数値を入力されているときは、それによって、斜線の色、又は線の太さをかえたいのですが、指定の仕方は、時刻シートの時刻の上欄セルに、線の指定のセル、太さ指定のセルに別々に指定おき、それを参照して、線の色、太さをかえたいのですが、いろいろ試みましたがうまくいきません。上記コードにどのように追加コードをすればよいか何方か教えていただけませんか。できれば、線の色は３色以上設定できればありがたいです。、

回答No.4

kagakusuki · ベストアンサー

申し訳御座いません。回答No.3で挙げたVBAの中に一部誤りが御座いました。

With .Range("J" & 75 +(i - 1)* 2)

において、使用する変数をcntとすべきところを、誤ってiにしておりました。
　それと、

myLine(1) = .Offset(1,0).Value '始点のy座標の値を変数に格納

と

myLine(2) = .Offset(0,1).Value '終点のx座標の値を変数に格納

で、参照するセルが逆になっておりました。

　ですから、正しくは以下の通りです。

Sub QNo8947661()

Dim cnt, j As Long
Dim myLine(7), myWeight(2) As Single
Dim myColor(3, 2) As Byte

myWeight(0) = 1.1 '線の太さのパターンその1
myWeight(1) = 2.5 '線の太さのパターンその2
myWeight(2) = 3.5 '線の太さのパターンその3
myColor(0, 0) = 0 '線色のパターンその1のRの値
myColor(0, 1) = 1 '線色のパターンその1のGの値
myColor(0, 2) = 2 '線色のパターンその1のBの値
myColor(1, 0) = 255 '線色のパターンその2のRの値
myColor(1, 1) = 3 '線色のパターンその2のGの値
myColor(1, 2) = 4 '線色のパターンその2のBの値
myColor(2, 0) = 5 '線色のパターンその3のRの値
myColor(2, 1) = 255 '線色のパターンその3のGの値
myColor(2, 2) = 6 '線色のパターンその3のBの値
myColor(3, 0) = 7 '線色のパターンその4のRの値
myColor(3, 1) = 8 '線色のパターンその4のGの値
myColor(3, 2) = 255 '線色のパターンその4のBの値

With Sheets("ダイヤ")
For cnt = 1 To 20
With .Range("J" & 75 + (cnt - 1) * 2)
myLine(0) = .Offset(0, 0).Value '始点のx座標の値を変数に格納
myLine(1) = .Offset(0, 1).Value '始点のy座標の値を変数に格納
myLine(2) = .Offset(1, 0).Value '終点のx座標の値を変数に格納
myLine(3) = .Offset(1, 1).Value '終点のy座標の値を変数に格納
myLine(4) = myWeight(.Offset(0, 2).Value) '線の太さの値を変数に格納
For j = 0 To 2
myLine(5 + j) = myColor(.Offset(1, 2).Value, j) '線色の値を変数に格納
Next j
End With
With .Shapes.AddLine(myLine(0), myLine(1), myLine(2), myLine(3)).Line '線を引く
.Weight = myLine(4) '線の太さの設定を線に反映
.ForeColor.RGB = RGB(myLine(5), myLine(6), myLine(7)) '線色の設定を線に反映
End With
Next cnt
End With

End Sub

お礼

こんなに詳しくありがとう御座います。
ＮＯ1.2で教えて頂きました考え方で線の太さの変更はできました。とはいっても、ワークシート関数をふんだんに使い、ＶＢＡなのか普通のエクセルなのかわからないようなものですが、見た目には、ＶＢＡといったものです。今回こんなにご検討いただきましたので、正真正銘のＶＢＡコードといったものにしたいと思います。
今回は本当にお世話になりました。
今後ともよろしくお願いいたします。　７４歳♂

回答No.3

kagakusuki

>3つのセルの条件を格納し,個々に順序よく変化させるとなると、かなり難しいようです

　色を指定する3つのセルに加えて、線の太さを指定する条件もありますから、セルを4つ増やす必要がありますね。
　既に現在、

　　e = worksheets("ダイヤ").cells(cnt,10).value
　　f = worksheets("ダイヤ").cells(cnt,11).value
　　g = worksheets("ダイヤ").cells(cnt+1,10).value
　　h = worksheets("ダイヤ").cells(cnt+1,11).value

というやり方で、線の両端の座標を示す4つの値を、J列～K列の奇数行と偶数行合わせて4つ1組のセルに入力しておき、個々に順序良く変化させておられるのですから、それと同じやり方で、空いている列を2列使用して、その2列の奇数行と偶数行合わせて4つ1組のセルに線の太さ、線色の赤色の値(R)、線色の緑色の値(G)、線色の青色の値(B)を入力しておいて、それらの条件を各変数に格納し、個々に順序良く変化させれば良いだけだと思います。
　それから、もし、線の色の種類や線の太さが少数のパターンに限られている場合には、それら決まったパターンごとの各色や太さに関する値を配列変数に格納しておき、描く線の種類を指定する際には「その配列変数の何番目の所に格納されている条件を使用するのか」で指定する様にしておきますと、増やさねばならない列を1列だけで済ます様にする事も出来ます。
　例えば、配列変数myWeight()に3種類の線の太さのパターンを、
配列変数myColor()に4種類の線の色のパターンを格納しておき、
L列の奇数列のセルに、線の太さのパターンの内のどれを用いるのかを指定するための情報である0～2の整数値を、
L列の偶数列のセルに、線色パターンの内のどれを用いるのかを指定するための情報である0～3の整数値を
それぞれ入力しておき、
これから線を引く上で必要となる8種類(両端の座標の数値4+線の太さの数値1+線色の数値3)の数値情報を配列変数myLine()に格納して使用するものとしますと、一例としては次の様な構文となります。
　尚、線の太さやRGBの各数値は暫定的に記述したものに過ぎませんので、質問者様の好みに合わせて適時変更して下さい。

Sub QNo8947661()

Dim cnt, j As Long
Dim myLine(7), myWeight(2) As Single
Dim myColor(3,2) As Byte

myWeight(0) = 1.1　'線の太さのパターンその1
myWeight(1) = 2.5　'線の太さのパターンその2
myWeight(2) = 3.5　'線の太さのパターンその3
myColor(0,0) = 0　'線色のパターンその1のRの値
myColor(0,1) = 1　'線色のパターンその1のGの値
myColor(0,2) = 2　'線色のパターンその1のBの値
myColor(1,0) = 255　'線色のパターンその2のRの値
myColor(1,1) = 3　'線色のパターンその2のGの値
myColor(1,2) = 4　'線色のパターンその2のBの値
myColor(2,0) = 5　'線色のパターンその3のRの値
myColor(2,1) = 255　'線色のパターンその3のGの値
myColor(2,2) = 6　'線色のパターンその3のBの値
myColor(3,0) = 7　'線色のパターンその4のRの値
myColor(3,1) = 8　'線色のパターンその4のGの値
myColor(3,2) = 255　'線色のパターンその4のBの値

With Sheets("ダイヤ")
For cnt = 1 to 20
With .Range("J" & 75 +(i - 1)* 2)
myLine(0) = .Offset(0,0).Value '始点のx座標の値を変数に格納
myLine(1) = .Offset(1,0).Value '始点のy座標の値を変数に格納
myLine(2) = .Offset(0,1).Value '終点のx座標の値を変数に格納
myLine(3) = .Offset(1,1).Value '終点のy座標の値を変数に格納
myLine(4) = myWeight(.Offset(0,2).Value) '線の太さの値を変数に格納
For j = 0 to 2
myLine(5 + j) = myColor(.Offset(1,2).Value , j) '線色の値を変数に格納
Next j
End With
With .Shapes.Addline(myLine(0), myLine(1), myLine(2), myLine(3)).Line '線を引く
.Weight = myLine(4) '線の太さの設定を線に反映
.ForeColor.RGB = RGB(myLine(5), myLine(6), myLine(7)) '線色の設定を線に反映
End With
Next cnt
End With

End Sub

　後、質問者様のVBAでは、

with worksheets("時刻")

によってワークシートを指定するWithステートメントが使われている中で、更に

with worksheets("ダイヤ").shapes.addline(e,f,g,h)

というワークシートの情報を含むWithステートメントが入れ子になっていますが、なるべくならワークシート等の同種のオブジェクトを指定する情報を含んでいるWithステートメントを入れ子にして使うのは避けた方が宜しいのではないかと思います。
　Withステートメントを入れ子にして使うのは、上位のレベルのオブジェクトを指定するWithステートメントの中に、下位のレベルのオブジェクトを指定するWithステートメントを入れ子にする場合などに限定された方が無難だと思います。

　それから、質問者様のVBAには、workheets("補助計算")やworksheets("時刻")等のワークシートが登場している様ですが、線を引く際に使われている変数の決め方を拝見しますと、線を引く事に関してworkheets("補助計算")やworksheets("時刻")は全く関わって来ない様に思います。
　それにもかかわらず何故、質問者様のVBAではworkheets("補助計算")やworksheets("時刻")等のワークシートが登場しているのでしょうか？
　補助計算シートや時刻シートは、本件のマクロには不要ではないでしょうか？
　ですから、

dim myrange as range
workheets("補助計算").range("c8:c47").value = worksheets("時刻").range("c8:c47").value
workheets("補助計算").range("g8:h47").value = worksheets("時刻").range("g8:h47").value
with worksheets("時刻")
　　　　v=worksheets("時刻").range("m2").value+12'描画本数
　　　 for i = 12 to v step 1'設定可能本数50本
set myrage = worksheets("補助計算").range("t3:t47")
myrange.value = .range(.cells(3,i),.cells(48,i)).value

の部分と末尾の

next i
end with

の部分は本件のマクロには不要ではないでしょうか？

　又、

workheets("補助計算").range("c8:c47").value = worksheets("時刻").range("c8:c47").value
workheets("補助計算").range("g8:h47").value = worksheets("時刻").range("g8:h47").value

という具合に、補助計算シート上に時刻シートと全く同じ情報をコピーするのは無意味だと思います。
　その様な事をせずとも、補助計算!C8:C47や補助計算!G8:H47の範囲内のセルを参照する必要がある処理を行う際には、補助計算シートを参照するのではなく、時刻!C8:C47や時刻!G8:H47の範囲内のセルの方を直接参照する様にされた方が宜しいのではないかと思います。

お礼

すみません。何とか一人立ちして、挑戦しようと思いましたが、もう一度教えてください。
とりあえず、コードを写し取り実行してみました。何らかの状況のへんかがあらわれるかと思いましたが、実行時エラー、「インデックスが有効範囲にありません」と次のコードで出ます
myline(4)=myweight(.offset(0,2).value
これをスルーさせると
myline(5+j)=mycolor(.offset(1,2).value,j) でやはり同じコメントのエラーが
これをスルーさせると
with .shapes.addline(myline(0),myline(1),myline(2),myline(3)).line
で出エラーがでます。
ネットでヘルプで確認しましたが　offise 2013 について　の説明で　「インデックスが有効範囲にありません（エラー９）」
の説明がありますが、残念ながら理解できません。

写しミスがあるかと思い、ご解答の部分をコピーしてみましたが、やはり同じ箇所で同じエラーがでます

そのまま私のところで実行は、無謀かと思いましたが、それなりに何か状況が変わるかもとの思いで、実行してしまいました。すみません。

こちらの様子を想像してコードを検討して頂きましたので、まったく申し訳ありません、私としてどのような部分を注意しチッエク修正したらよいでしょうか、お手数ですがもう一度お願いできませんか。
お願いいたします。

回答No.2

kagakusuki

そのVBAの構文の中の

with worksheets("ダイヤ").shapes.addline(e,f,g,h)
.line.weight = 1.1
.line.forecolor.rgb = vbblue
end with

という箇所において、

.line.weight = 1.1

の1.1という値を変数を用いて変更可能にすれば線の太さを変える様にする事が出来ます。(変数の名称は何でも構わないのですが、「weight =」の値を設定するための変数でしたら、myWeightなどとした方が、何のための変数なのか判り易くなるかと思います)
　又、

.line.forecolor.rgb = vbblue

のvbblueという値を変数を用いて変更可能にすれば、線の色を変える様にする事が出来ます。
　尚、

.line.weight = 1.1
.line.forecolor.rgb = vbblue

は、いずれも.lineが付いている事は共通なのですから、

with worksheets("ダイヤ").shapes.addline(e,f,g,h) .line
.weight = 1.1
.forecolor.rgb = vbblue
end with

としてしまった方が良いと思います。
　それと、色の設定は

.ForeColor.RGB = RGB(赤色の数値,緑色の数値,青色の数値)

の形式で設定されるものなのですから、例えば

.ForeColor.RGB = RGB(myRed,myGreen,myBlue)

等の様に3つの変数myRed、myGreen、myBlueで設定される様にしておき、その上でmyRed、myGreen、myBlueの各々の値を、3つのセルにそれぞれ入力された数値の条件に合わせて変える様にされると良いと思います。
　尚、色設定値として有効な数値は0～255の範囲の整数値です。

　後、質問者様が投稿したVBAに関する別の質問の時も気になっていた事なのですが、変数を使う時にはちゃんとDimで定義してからにして下さい。
　今回のVBAでも、定義されているのはmyrangeだけで、他はv、i、e、f、g、h、vbblueなど、定義されていない変数ばかりです。

お礼

ご解答ありがとう御座います。
たしかに、RGBの数値を手動で変更してみると、全斜線がきれいに変化します、したがってやるべきことはわかりましたが、3つのセルの条件を格納し,個々に順序よく変化させるとなると、かなり難しいようですが
チャレンジします。

変数の宣言がおろそかになっていることについては、申し訳ありません、ご指摘の東リです。動作するかどうか結果だけ追いかけてしまい見苦しいコードを書きはずかしいです。
VBAがどういうものかまだ全然理解しておりません。できるだけ注意し取組たいとおもいます。

まづは、受信のお礼まで、ありがとう御座います。

回答No.1

noname#206655

線の色とか幅が正しいとして、セル値が変数なら
　color＝Cells(a,b)　

ってのを考えて、ペアレント（親）が　worksheets("ダイヤ")　で、どうでしょう？

お礼

ご解答ありがとう御座います。
もうお一方の、kagakusuki様からもお解答いただきました。私の力では、簡単にはいかないようですが
挑戦したいと思います。
まづは。受信のおれいまで、ありがとう御座います。