VBA Replaceで

質問

Win７、Excel２０１０使用。

VBAにて下記のコードを作成。
シート内のある範囲において、セル中に漢字と数字（算用）が
混在した文字列があり、Replaceにて数字を取り除く為に作成
しましたが、実行したところ、正常に動作して全て取り除ける場合と、
そのまま数字が全て残る場合があります。

指定した範囲は、別のブックから値のみコピーして
貼り付けたもので、書式は「標準」にしています。
※元データも「標準」の文字列です。

下記コード以外でもいくつか試しましたが、改善見られなかっ為、
コードの問題ではなく、文字列の問題なのかなとも思いましたが、
よくわかりませんでした。

解決策などがありましたら教えて頂けると助かります。
よろしくお願いします。

＝（VBAコード）＝
Sub NumDell()
'余分な数字を削除します。
Application.Calculation = xlCalculationManual
Dim r As Long
Dim c As Long
Dim i As Long

　Call hen　'Public変数を設定。単独実行時のみ

For r = 53 To Lr2 Step 2
For c = 3 To dc
If c = 9 Then
Stop
End If

With Cells(r, c)
For i = 1 To 9
.Replace CStr(i), ""
.Replace StrConv(CStr(i), vbNarrow), ""
Next i
End With
Next c
Next r
Application.Calculation = xlCalculationAutomatic
End Sub
-------------------------
※変数は、関連コードあるため、Public変数を使用しています。

回答No.1

cj_mover · ベストアンサー

こんにちは。

' /// 余分な数字を削除します。
Sub Re8766547()
　　Application.Calculation = xlCalculationManual
Dim r As Long
' Dim c As Long　'　以下の記述では使っていません
Dim i As Long

　　Call hen　'単独実行時のみPublic変数を設定します。

　　For r = 53 To Lr2 Step 2
　　　　For i = 0 To 9
　　　　　　Cells(r, 3).Resize(, dc - 2).Replace _
　　　　　　　　What:=CStr(i), Replacement:="", _
　　　　　　　　LookAt:=xlPart, SearchOrder:=xlByRows, _
　　　　　　　　MatchByte:=False
　　　　Next i
　　Next r

　　Application.Calculation = xlCalculationAutomatic
End Sub

Replace メソッドを使う例としては以上のような感じです。
（単セル毎に処理するのは非効率なので）セルブロック毎（各行毎）に置換処理すること
と、
名前付き引数 LookAt MatchByte について正しく理解した上で活用すること
が、
ポイントになります。
ＶＢＡのヘルプでもいいですから、.Replace メソッドの各引数の意味等について
確認してみて下さい。

因みにCStr()関数は使っても使わなくても結果は一緒です。
∵名前付き引数 What はVariant型だから。

それと。Stop ステートメントについてですが、
特に説明が無いようですから、
これは、専ら、デバッグ＆トレース用、動作の確認用
の記述という判断で、こちらが書いたコードには反映させていません。
敢えて Stop させるなら、Next i と Next r の間の行あたりでしょうか。

以上です。

お礼

早速の回答ありがとうございます。
おかげさまで正常に動作するようになりました。

独学だった為、知識がまだまだ不十分で、
引数についても、あまり気にすることなく
スルーに近い状態でした。

コードの作成方法についても
大変勉強になりました。

もっとスキルアップしていきたいと思います。