エクセル2013 既存コードを用いて修正

質問

Clean関数をマクロに取り込みたいのですが
下記コードの　Trim部分をCleanにしただけではダメでした。

どのようなコードを組んだら宜しいでしょうか？
ご教示ください。

Sub Clean()
Dim rng As Range
For Each rng In Selection
rng.Value = Trim(rng.Value) '←TrimをCleanにしただけではダメでした
Next rng
End Sub

実際は　AからL列まで入力されています。

D列の最終入力セルを取得してB,E,F列をCleanにしたいです。
(ＡからLでも構いません)

ブックはパスワードで保護されています。

データは8行目から入力されています。
(7行目は見出し)

回答No.2

nishi6 · ベストアンサー

質問には「Clean関数」に関することと、

＞D列の最終入力セルを取得してB,E,F列をCleanにしたいです。
＞(ＡからLでも構いません)
＞データは8行目から入力されています。

とあるので、参考にモジュールを書いてみました。シートのコードウィンドウを使っています。（当方、Excel2010です）

Sub 制御文字の削除()
　　Dim rg As Range　　　　 'セル
　　Dim lastRow As Long　　 '最終行
　　Dim strRange As String '処理セル範囲

　　lastRow = Range("D" & Rows.Count).End(xlUp).Row
　　　　'B、E、F列指定
　　　　strRange = "B8:B@, E8:E@, F8:F@" 'とりあえず最終行は@
　　　　strRange = Replace(strRange, "@", lastRow) '置き換え

　　For Each rg In Range(strRange)
　　　　rg.Value = Application.Clean(rg.Value)
　　Next

End Sub

質問にある「Trim関数」についてですが、この質問を参考にすると、提示の
　　「rng.Value = Trim(rng.Value) 」
はワークシート関数をマクロに取り込もうとしているように思えますが、このままでは、VBAのTrim関数を使っています。意図的にそうしてあれば、以下は読み飛ばしてください。

●Trim関数について

■VBA構文
　LTrim(String)　　先頭のスペース削除
　RTrim(String)　　末尾のスペース削除
　Trim(String)　　 先頭と末尾のスペース削除

■ワークシート関数のTrim関数
　先頭と末尾の空白を削除し、さらに文字列中に連続する空白があった場合、空白を1つにして残りを削除します。

　従って、VBAで直接 rg.Value = Trim(rg.Value) としてもワークシート関数のTrim関数と同じ結果にはなりません。VBAのTrim関数では、文字列中の空白を削除することはできないため、文字列中の空白を削除する場合は、Replace関数を使うことになります。

　どちらを使うかで Application を付けたり付けなかったりします。ワークシート関数がVBAで使えても、同じ結果になるとは保障されません。十分確認することが必要です。Trim関数よりも有名な違いのある関数にRound関数があります。（「excel round関数 違い vba」くらいでググってみてください）
　ExcelとAccessでDateDifとDateDiffとか面白い？例が結構あります。ご参考に。

お礼

丁寧な説明と指示をありがとうございます。

提示されたコードを利用させていただきたいと思います。

回答No.3

WindFaller

Clean関数というのは、本来、印刷に影響あるバイナリコードを除去する目的で作られたというのが、建前です。実際は、現代では意味がありませんが、昔、ワークシートをエラー起こすバイナリコードが入り込むのを除去する目的だったようです。

>TrimをCleanにしただけではダメでした
一体、何をターゲットとして、除去するのでしょうか？

Trim と　Clean関数の性格はかなり違うものですが……。

以下のコードは、今とは違う書き方をしていますが、ネットで見つけた文書などから、空白を除去する目的で、10年ぐらい前に作ったコードです。半角のスペースは残してあります。もし、全部のスペースを取る場合は、VBA関数のReplaceで、Space(1)で、TextCompare にすればよいです。

当時は、このぐらいしか書けませんでしたが、今でも、使えます。

'-------------------
　 Dim strVal As String
　 Dim c As Range
　 Dim Rng As Range
　 If Not Selection Is Nothing Then
　　　Set Rng = Selection
　 End If
　 For Each c In Rng
　　　strVal = Application.Clean(c.Value)
　　　strVal = Application.Substitute(strVal, ChrW(160), "")
　　　strVal = Application.Substitute(strVal, "　", "")　'全角空白
　　　c.Value = Trim(strVal)
　 Next
'-------------------

とりあえず、ご参考まで。

お礼

いつもお世話になっております。

私にはまだまだ難しすぎて、理解できません。(すみません)
しかし今後のためにも、参考にさせて頂きます。
ありがとうございました。

回答No.1

keithin

rng.value = application.clean(trim(rng.value))
みたいな。

ワークシート関数のCLEANを使うなら、application.worksheetfunctionの下に書かなきゃなりません。
TrimのようにVBA側で用意されている関数があるのか無いのか、参考書やオブジェクトブラウザなどで勉強しながら使います。

お礼

今回は色々とありがとうございました。