Excelマクロのことで教えて下さい

質問

初歩的なことですみません。
E列の値をF列に値を入れるために下記のマクロを組みました。

Sub test()

Worksheets("Sheet1").Select
Dim i As Long
For i = 2 To Cells(Rows.Count, 4).End(xlUp).Row
Range("F2").Value = "=E2/1024/1024"
Cells(i, 6).FillDown

Range(Cells(2, 6), Cells(i, 6)).Copy
Range("F2").PasteSpecial Paste:=xlValues

Next i
End Sub

ところがF列に「値のみを貼り付け」をした時に、途中から同じ値のみがコピーされてしまい困っています。
（画像参照）

うまく貼り付けることができるマクロをお教え下さい。
よろしくお願いいたします。

回答No.3

WindFaller · ベストアンサー

こんばんは。

元のコードを直してみました。ご質問のようなコードでは、ループは必要ないのですが、こういう書き方は、少し手慣れた人が書く方法で、難易度が高くなります。しかし、必ずしもちゃんとしたマクロとはいえません。

本来は、Test2() のような、ワークシートの数式は用いずに、VBAマクロのみにしましょう。なお、ループ式で量的に多い場合、必要に応じて、Application.ScreenUpdating = False, Application.ScreenUpdating = Trueを、始めと終わりに入れてください。また、VBA/VB6では、変数の宣言は、プロシージャ名の後に入れてください。

'//以下のようなコードは、あまり関心しません。
Sub TestR()
　Dim i As Long
　Worksheets("Sheet1").Select
　i = Cells(Rows.Count, 4).End(xlUp).Row
　Range("F2").FormulaLocal = "=E2/1024/1024"
　Range(Cells(2, 6), Cells(i, 6)).FillDown
　Range(Cells(2, 6), Cells(i, 6)).Copy
　Range("F2").PasteSpecial Paste:=xlValues
　Application.CutCopyMode = False
End Sub

'//　難易度を下げたマクロ（標準Moduleに限ります）
Sub Test2()
　Dim i As Long
　Worksheets("Sheet1").Select
　For i = 2 To Cells(Rows.Count, 4).End(xlUp).Row
　　Cells(i, 6).Value = Cells(i, 5).Value / 1024 / 1024
　Next i
End Sub

お礼

ありがとうございます！

切り貼りしながら覚えたマクロだったので、苦戦してました。
Test2の形でマクロができるのは意外でした、これは眼から鱗です。

あとでじっくり調べて、学ばせていただきます。

回答No.2

tom04

No.1です！
たびたびごめんなさい。

もう一度質問のコードを見直してみました。
F2セルにはちゃんと　E2/1024/1024　の結果が表示されますね！
これをD列最終行までオートフィルでコピーし、値として表示したい訳ですよね？

No.1のコードでも同じ結果になると思いますが、極力お示しのコード通りオートフィルでやってみると

Sub test1()
Worksheets("Sheet1").Select
Dim i As Long
i = Cells(Rows.Count, "D").End(xlUp).Row
Range("F2").Value = "=E2 / 1024 / 1024"
Range("F2").Select
Selection.AutoFill Destination:=Range(Cells(2, "F"), Cells(i, "F")), Type:=xlFillDefault
With Range(Cells(2, "F"), Cells(i, "F"))
.Value = .Value
End With
End Sub

といった感じでも大丈夫だと思います。
何度も失礼しました。m(_ _)m

お礼

ありがとうございます！
このマクロで正常に値のみ貼り付けができました。

中身はじっくり調べて、色々学ばせていただきます。

回答No.1

tom04

こんばんは！

結局E列数値を1024で2回割った結果をF列に表示したい！というコトですよね？
＞Range("F2").Value = "=E2/1024/1024"
の部分はダブルクォーテーションでくくってあるために、文字列になってしまうと思います。

ごく単純に

Sub Sample1()
Dim lastRow As Long
Worksheets("Sheet1").Select
lastRow = Cells(Rows.Count, "D").End(xlUp).Row
If lastRow > 1 Then
With Range(Cells(2, "F"), Cells(lastRow, "F"))
.Formula = "=E2/1024/1024"
.Value = .Value
End With
End If
End Sub

ではどうでしょうか？m(_ _)m