excel2003の入力を省力化したい

質問

写真のように
A，Ｃ，Ｅ列に記号
Ｂ，Ｄ，Ｆ列に文字が入っています。

そこで、Ａ～Ｆ列に何かしら入力した場合、
Ｇ列、Ｈ列には、それぞれ　Ａ－Ｃ－Ｅ、Ｂ－Ｄ－Ｆを
ハイフンで連結した文字を、自動で表示させたいです。

ただし、Ａ～Ｆ列の値を消した場合、Ｇ列とＨ列の値もクリア
させたいです。

どうか、ＶＢＡの記述を教えていただけないでしょうか？
できれば、早くて、負荷の少ない記述が助かります。

回答No.3

tom04 · ベストアンサー

こんにちは！
すでに回答は出ていますが、参考程度で・・・
Sheetモジュールです。

A～F列に空白セルが一つでもあればG・H列は表示しないようにしています。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Long
If Intersect(Target, Range("A:F")) Is Nothing Then Exit Sub
i = Target.Row
If i > 1 Then
If WorksheetFunction.CountBlank(Cells(i, "A").Resize(, 6)) = 0 Then
With Cells(i, "G")
.NumberFormatLocal = "@"
.Value = Cells(i, "A") & "-" & Cells(i, "C") & "-" & Cells(i, "E")
.Offset(, 1) = Cells(i, "B") & "-" & Cells(i, "D") & "-" & Cells(i, "F")
End With
Else
Cells(i, "G").Resize(, 2).ClearContents
End If
End If
End Sub

こんな感じではどうでしょうか？m（_ _）m

お礼

回答ありがとうございました。

とても合理的で、素晴らしい記述だと思います。

大変勉強になりました。使わせていただきます。

回答No.2

kybo

VBA的には該当シートのシートモジュールに以下のような感じでよろしいかと思います。

Private Sub Worksheet_Change(ByVal Target As Range)
Dim C As Range
For Each C In Target
If Not Intersect(C, Range("A:A,C:C,E:E")) Is Nothing Then
Application.EnableEvents = False
If Cells(C.Row, "A").Value = "" And Cells(C.Row, "C").Value = "" And Cells(C.Row, "E").Value = "" Then
Cells(C.Row, "G").ClearContents
Else
Cells(C.Row, "G").Value = Cells(C.Row, "A") & "-" & Cells(C.Row, "C") & "-" & Cells(C.Row, "E")
End If
Application.EnableEvents = True
ElseIf Not Intersect(C, Range("B:B,D:D,F:F")) Is Nothing Then
Application.EnableEvents = False
If Cells(C.Row, "B").Value = "" And Cells(C.Row, "D").Value = "" And Cells(C.Row, "F").Value = "" Then
Cells(C.Row, "H").ClearContents
Else
Cells(C.Row, "H").Value = Cells(C.Row, "B") & "-" & Cells(C.Row, "D") & "-" & Cells(C.Row, "F")
End If
Application.EnableEvents = True
End If
Next C
End Sub

お礼

回答ありがとうございます。
私がやろうとしていた、イメージに近い記述でした。
勉強になりました。

回答No.1

noname#203218

関数で対応可能ですのでマクロでなくても良いのではないのでしょうか。

G2式=IF(COUNTIF(A2:F2,"")=0,A2&"-"&C2&"-"&E2,"")
H2式=IF(COUNTIF(A2:F2,"")=0,B2&"-"&D2&"-"&F2,"")

下方にフィルコピー

0から始まる数値はテキストで入力されてるものとしています。

数字１桁だけ入力し、セルの表示型式で先頭に0を表示させているのでしたら、違う関数になります。
例えば数値が２桁限定であれば下記で可能です。２桁３桁が混在すると処理できません。
G2式=IF(COUNTIF(A2:F2,"")=0,RIGHT("0"&A2,2)&"-"&RIGHT("0"&C2,2)&"-"&RIGHT("0"&E2,2),"")

お礼

回答ありがとうございます。仰せられる通り全て文字列です。
説明不足ですみません。
関数でのやりかたは、分かるのですが、行が増えてファイルを重くしたくない。
他のユーザーに関数を操作あせたくない、等の理由でvbaを希望します。