マクロでの検索の仕方をお教えください。

質問

２４時間表示でデーター並んでいますが
マクロで9:00:00検索をすると21:00:00もヒットしてしまいます

セルの書式は　yyyy/m/d h:mm
表示は　2013/8/29 9:00
セルには　2013/8/29 9:00:00
　　　　　　　2013/8/29 10:00:00
１時間ごとに２４時間５００日くらいデータがＡ列にあります
　21:00:00　にヒットしないようにしたいのです
宜しくお願いします。
またときにはオブジェクト変数またはWith ブロック変数が設定されていません。
というエラーになるときもありどうすればよいのかわかりません。
どうかよきアドバイスをお願いいたします。

回答No.2

cj_mover · ベストアンサー

２パターン挙げてみます。

Sub Re8289389()
　　Dim r As Range
　　For Each r In Range("A1:A" & Cells(Rows.Count, "A").End(xlUp).Row)
　　　　If r.Text Like "* 9:00" Then

　　　　　　' ' 見つかった場合の処理
　　　　　　Debug.Print r.Row

　　　　End If
　　Next
End Sub

Sub Re8289389j()
　　Dim r As Range
　　For Each r In Range("A1:A" & Cells(Rows.Count, "A").End(xlUp).Row)
　　　　If IsDate(r.Value) Then
　　　　　　If Hour(r.Value) = 9 Then

　　　　　　　　' ' 見つかった場合の処理
　　　　　　　　Debug.Print r.Row

　　　　　　End If
　　　　End If
　　Next
End Sub

お礼

早速の回答ありがとうございました。
　Sub Re8289389()のパターンで希望がかないました
　色々なパターンのご教授ありとうございました。

回答No.3

cj_mover

Findメソッドを使いたかったのですね。
それなら、

Sub Re8289389c()
　　Dim c As Range
　　Dim n1stRow As Long
　　With Range("A1:A" & Cells(Rows.Count, "A").End(xlUp).Row)
　　　　Set c = .Find(What:=TimeValue("9:00"), After:=.Cells(.Cells.Count), _
　　　　　　　　LookIn:=xlFormulas, LookAt:=xlPart)
　　　　If Not c Is Nothing Then
　　　　　　n1stRow = c.Row
　　　　　　Do

　　　　　　　　' ' 見つかった場合の処理
　　　　　　　　Debug.Print c.Row

　　　　　　　　Set c = .FindNext(c)
　　　　　　Loop While Not c Is Nothing And c.Row > n1stRow
　　　　End If
　　End With
End Sub

お礼

早速の回答ありがとうございました。
　Sub Re8289389()のパターンで希望がかないました
　色々なパターンのご教授ありとうございました。

回答No.1

sora1515

あまり確認していませんが以下でどうでしょうか。
Sub test()
Dim c As Range
For Each c In Range("A1:A30")　　'検索範囲
　　If Hour(c) = "9" Then　　　　　　'9時検索
　　　　MsgBox (c.Row & "行目で見つかりました")
　　End If
Next c
End Sub

※見易さの為半角スペースを全角にしております。

お礼

cj_mover様の回答で無事解決できました
　これに懲りずお教えくださいますようお願いいたします。
　ありがとうございました。

補足

早速の回答ありがとうございます。
　さっそくテストしましたがうまくいきません
実行時エラー'13':
型が一致しません。
　というエラーになります
どう対処すればよいのかわかりません
Ａ列の日時データをいじってみたのですが
うまくいきませんでした
　お手数をおかけしますがよろしく
　お願いいたします。