エクセルでひとつのセルから複数表示したいです

質問

エクセル2007を使っています
うまくキーワードが思いつかず、
”ひとつのセル　検索　複数セル表示”
”セル検索　連続データ”のようにインターネットで
調べてみましたが、思っているものにつながらず困っています
自分で考えてみたのはvlookupですが、自分のおもうようにいきませんでした
もしかしたらエクセルでは無理なことなのでしょうか．．．
どなたか詳しい方教えてくださると助かります。

内容ですが、エクセルのファイルが
”管理ファイル”
”商品一覧ファイル”
の2個あり、

管理ファイルに入力すると、
商品一覧ファイルより検索して該当する部分を表示したいと思っています

商品一覧ファイルの中身は次のようになっています
　　Ａ　　　　　　Ｂ　　　　　Ｃ
1　分類番号　商品番号　商品名
2　Ｆ100　　　　10　　　　　みかん
3　　　　　　　　20　　　　　りんご
4
5　V500　　　　10　　　　　にんじん
6　　　　　　　　20　　　　　たまねぎ
7　　　　　　　　30　　　　　かぼちゃ
・
・600行くらいデータがはいっています
・

管理ファイルは商品一覧ファイルと同じような形です
Ａの列の日付とＢの列の分類番号だけ手入力します
Ｂの列に入力した分類番号で登録してある
みかんとりんごが表示されるようにしたいです。
　　Ａ　　　　Ｂ　　　　　　Ｃ
1　日付　　分類番号　商品番号　商品名
2　7/30　　Ｆ100　　　　10　　　　　みかん
3　　　　　　　　　　　　　20　　　　　りんご
4
5　7/31　　F100　　　　10　　　　　みかん
6　　　　　　　　　　　　　20　　　　　りんご
7　　　　　　　　　　　　　
8　　　　　　V500　　　　10　　　　　にんじん
9　　　　　　　　　　　　　20　　　　　たまねぎ
10　　　　　　　　　　　　30　　　　　かぼちゃ
・
・

両方のファイルに作業行を追加してVLOOKUPで検索等してみたのですが
分類番号が空白のものをすぐ上に入力してある番号をどうやって認識させるのか、
商品番号を自動で表示させるのにはどうしたらよいのか．．．
うまく説明ができていないかもしれません、すみません力をかしてください
よろしくお願いします。

回答No.2

KURUMITO · ベストアンサー

商品一覧のシート名、例えばシート1にお示しの表が有るとして作業列をD列に作り、D2セルには次の式を入力して下方にドラッグコピーします。

=IF(AND(C2="",C1=""),"",IF(A2<>"",A2&"/1",LEFT(D1,FIND("/",D1)-1)&"/"&COUNTIF(D$1:D1,"*"&LEFT(D1,FIND("/",D1)-1)&"*")+1))

管理ファイルの或るシートのC2セルには次の式を入力してD2セルまで横にドラッグコピーしたのちに下方にもドラッグコピーします。

=IF(ISERROR(INDEX([商品一覧.xlsx]シート名!$B:$C,MATCH(INDEX($B:$B,MATCH(10^10,$A$1:$A2))&"/"&ROW()-MATCH(10^10,$A$1:$A2)+1,[商品一覧.xlsx]シート名!$D:$D,0),COLUMN(A1))),"",IF(INDEX([商品一覧.xlsx]シート名!$B:$C,MATCH(INDEX($B:$B,MATCH(10^10,$A$1:$A2))&"/"&ROW()-MATCH(10^10,$A$1:$A2)+1,[商品一覧.xlsx]シート名!$D:$D,0),COLUMN(A1))="","",INDEX([商品一覧.xlsx]シート名!$B:$C,MATCH(INDEX($B:$B,MATCH(10^10,$A$1:$A2))&"/"&ROW()-MATCH(10^10,$A$1:$A2)+1,[商品一覧.xlsx]シート名!$D:$D,0),COLUMN(A1))))

お礼

朝早くの回答ありがとうございます。

回答いただいた式を貼り付けてみたら
商品番号、商品名表示されました。

ありがとうございました。
大変助かります。

回答No.1

keithin

とりあえず簡易に、商品一覧の分類番号ごとの商品が最大１０ほど含まれているとして

管理のＤ２には
=IF(C2="","",VLOOKUP(C2,OFFSET([商品一覧.xlsx]シート名!$B$1:$C$10,MATCH(INDEX(B:B,MATCH("*",$B$1:B2,-1)),[商品一覧.xlsx]シート名!$A:$A)-1,0),2,FALSE))
とでもしておきます。

言わずもがなですが各ブックの拡張子を含めた正しいファイル名や、正しいシート名はキチンと修正して数式を作成します。

「実際の」あなたのエクセルに応用する前に、まずご相談でご自分が書かれた通りにサンプルを作成して数式が作動する事を確認してから、改めて実際のエクセルに応用してください。

もうひとつ言わずもがなで、ご相談に掲示されているように「半角のF」と「全角のＦ」がごっちゃになったみたいな、間違ったデータになっていない事もしっかり確認してから計算してください。

お礼

はやい回答ありがとうございます
質問してから、回答いただくまですごく早くて
驚きました。すばらしい知識をお持ちなのですね。

回答いただいた式を貼り付けてみましたら、
商品名でました。すごく助かります。

ご指摘の半角と全角の文字ですが、気づきませんでした。
ありがとうございます。