エクセルのコピー

質問

エクセルで下の規則でコピーがわかりません。

A1=B3+B4
A2=B5＋B6
A3=B7+B8

単純にA1をこぴーしてA2から下に数列貼付をすると
A1=B3+B4
A2=B4＋B5
A3=B5+B6
となってしまします。

もう一つ別の規則コピーで

A1=C2+C4
A2=C5+C７
A3=C8+C10

とA4以降の下にコピーをしたいです。

よろしくお願いします。

回答No.1

xls88 · ベストアンサー

＞A1=B3+B4
＞A2=B5＋B6
＞A3=B7+B8
≪手作業の例≫
A1に、=B3+B4
A1:A2 を選択（A2は空白）
選択枠の右下角の■（フィルハンドル）を掴んで下方にドラッグ
ドラッグ範囲が選択状態のまま
Ctrl＋G　で「ジャンプ」ダイアログ表示
Alt＋S　で「セル選択」から「選択オプション」ダイアログ表示
ｋ　で「空白」オプション選択
Enter　で「OK」して空白セルのみを選択
Ctrl＋－（マイナス）　で選択した空白セルを「上方向にシフト」で削除

≪数式の例≫
=INDIRECT("B"&ROW(A1)*2+1)+INDIRECT("B"&ROW(A1)*2+2)
あるいは
=OFFSET(B3,ROW(A2)-2,0)+OFFSET(B4,ROW(A2)-2,0)

＞A1=C2+C4
＞A2=C5+C７
＞A3=C8+C10
もう一つの例は上記内容を応用してください。

回答No.5

MarcoRossiItaly

オートフィルで作るには、No.1 さんの前半の方法が簡単です。別法としては、次のようにしても、できます。

C1　b3
C2　b5
D1　b4
D2　b6
E1　="="&c1&"+"&d1

入力後、次のとおり操作。

(1) C1:D2 のセル範囲を選択して、下方向にドラッグ・オートフィル。
(2) E1 セルを選択してカーソルの右下隅の角をダブルクリックすることにより、下方向にオートフィル。
(3) E 列にできたデータ全体を選択・コピーし、A1 に値複写。
(4) A 列に貼られたデータ全体または列全体を選択した状態で、リボンまたはメニューバーにおいて「データ＞区切り位置＞完了」とクリック。

お礼

細かい部分まで教えて頂き、ありがとうございます。
参考にさせて頂きます。

回答No.4

K Kazz（@JazzCorp）

その１：
=SUM(OFFSET($B$3,(ROW()-1)*2,0),OFFSET($B$4,(ROW()-1)*2,0))
その２：
=SUM(OFFSET($C$2,(ROW()-1)*3,0),OFFSET($C$4,(ROW()-1)*3,0))
以下、コピー

回答No.3

某HN クロメート(Chromate)（@CoalTar）

ワークシート上に入力するOFFSET、INDIRECT関数は、計算とは関係のないセルの入力や削除でも再計算するので、多用すると支障が出るので注意が必要です。

数式なら
=INDEX(B:B,ROW()*2+1)+INDEX(B:B,ROW()*2+2)
と
=INDEX(C:C,ROW()*3-1)+INDEX(C:C,ROW()*3+1)

行を後で追加しないなら、No.1さんの手作業が一番良いと思います

お礼

ありがとうございます。
参考にさせて頂きます。

回答No.2

noname#204879

最初の規則
　　　A1: =SUM(OFFSET(B$3,(ROW(A1)-1)*2,,2))
もう一つ別の規則
　　　A1: =SUM(OFFSET(C$2,(ROW(A1)-1)*3,,3))-OFFSET(C$3,(ROW(A1)-1)*3,)

お礼

ありがとうございます。
参考にさせて頂きます。