マクロを使用した選択セルの値のコピーについて

質問

Ａ　　　Ｂ　　　Ｃ　　　Ｄ　　　Ｅ　　　Ｆ　　　Ｇ
１　１０　　１５　　　　　　　９　　　２３　　３３　　５５
２　　　　　　　　　　　　　１０　　　３３　　４４　　５６
３　　　　　　　　　　　　　１１　　　４４　　５５　　５７　　　　　　　　　　　
４　　　　　　　　　　　　　１２　　　５５　　６６　　７６
５　　　　　　　　　　　　　１３　　　２３　　７７　　８７
６　　　　　　　　　　　　　１４　　　３３　　８８　　８８
７　　　　　　　　　　　　　１５　　　４５　　９９　　９９
８　　　　　　　　　　　　　１６　　　５５　　２１　　５６
９　　　　　　　　　　　　　１７　　　６６　　４５　　７６
１０　　　　　　　　　　　　１８　　　７７　　５２　　５４

質問です
Ａ１の値が１０
Ｂ１の値が１５
でＡ１とＢ１の値は各データによって異なって入力されています。
決まりとしては、
Ａ１＜Ｂ１で,
必ず、Ａ１の値とＢ１の値はＤ列に存在します。

Ａ１の値とＢ１の値をマクロで取得し、
Ｄ列でその選択範囲を検索し、Ｄ列の１０～１５の値の選択範囲で、
Ｄ２：Ｇ７までをうまくコピーし、違う場所に張り付けしたいのです。
もし、詳しい方がいらっしゃいまして、簡単にできる方法がありましたら、
ご指導の程お願い致します。

回答No.2

watabe007 · ベストアンサー

>『型が一致しません』とデバッグが生じました。
A1の値またはB1の値、またはどちらも見つからないまま
Range(Cells(myR1, "D"), Cells(myR2, "D")).Resize(, 4).Copy Range("J1")
を実行すると、そのようなエラーが出ます。

Sub Test()
　　Dim myR1 As Variant, myR2 As Variant

　　myR1 = Application.Match(Range("A1").Value, Range("D:D"), 0)
　　myR2 = Application.Match(Range("B1").Value, Range("D:D"), 0)
　　If IsError(myR1) Then
　　　　MsgBox "A1セルの値 " & Range("A1").Value & " がD列に見当たりません。"
　　　　Exit Sub
　　End If
　　If IsError(myR2) Then
　　　　MsgBox "B1セルの値 " & Range("B1").Value & " がD列に見当たりません。"
　　　　Exit Sub
　　End If
　　'検索範囲をJ1セルに貼付
　　Range(Cells(myR1, "D"), Cells(myR2, "D")).Resize(, 4).Copy Range("J1")
End Sub

回答No.1

watabe007

>決まりとしては、Ａ１＜Ｂ１で,必ず、Ａ１の値とＢ１の値はＤ列に存在します。

Sub Test()
　　Dim myR1 As Variant, myR2 As Variant

　　myR1 = Application.Match(Range("A1").Value, Range("D:D"), 0)
　　myR2 = Application.Match(Range("B1").Value, Range("D:D"), 0)
　　'検索範囲をJ1セルに貼付
　　Range(Cells(myR1, "D"), Cells(myR2, "D")).Resize(, 4).Copy Range("J1")
End Sub

お礼

ありがとうございます。早速実行してみましたが、
Range(Cells(myR1, "D"), Cells(myR2, "D")).Resize(, 4).Copy Range("J1")
のところで、『型が一致しません』とデバッグが生じました。
どのように対処したらよろしいでしょうか？？