指定セルが空欄の時、上のセルの値で計算するには？

質問

皆様、よろしくお願いいたします。

VLOOKUPで使う固定データを持ちます。
セル[A２０からA２５]まで人名、[B２０からB２５]まで時間。

例：
[A２０]：aさん　　[B２０]：0:05
[A２１]：bさん　　[B２１]：0:10
[A２２]：cさん　　[B２２]：0:15
[A２３]：dさん　　[B２３]：0:20
[A２４]：eさん　　[B２４]：0:25
[A２５]：fさん　　[B２５]：0:30

セル[A１からA５]まで人の名前、[B１からB５]まで時間を入力する欄を持ちます。
しかし入力されるデータ数は、その都度違います。

例１：
ある時は、
[A１]：aさん　　[B１]：0:30
[A２]：bさん　　[B２]：0:45
[A３]：cさん　　[B３]：1:00
[A４]：dさん　　[B４]：1:30
[A５]：eさん　　[B５]：2:00

例２：またある時は、
[A１]：cさん　　[B１]：0:30
[A２]：dさん　　[B２]：1:00
[A３]：aさん　　[B３]：1:45
など

データの入力される数はその都度違います。
その時、一番下の人の時間からVLOOKUP用データの時間を引いた値を「A１０」セルに入力したいです。

例１では、「B５」の値　- VLOOKUP用データ eさんの0:25、つまり [2:00 - 0:25]の値をA１０に。
例２では、「B３」の値　- VLOOKUP用データ aさんの0:05、つまり [1:45 - 0:05]の値をA１０に。

A５（or B５）から上方向に順番にデータが入っているかの判別が必要だと思いますが、うまく出来ませんでした。

どなたかご教授いただけたらと思います。

よろしくお願いいたします。

回答No.3

sige1701 · ベストアンサー

keithin　さんの回答の方がいいと思いますが・・・

=IF(A1="","",LOOKUP(1,B1:B5)-VLOOKUP(LOOKUP(1,B1:B5,A1:A5),A20:B25,2,0))
B列が24時間未満ということで、

お礼

sige1701さん、返信が遅くなり申し訳ありません。

シンプルで分かり易くしていただき、ありがとうございます。

上記回答で完ぺきでした！

回答No.2

keithin

前提としてＡ１から「上から順に詰めて」記入していきます。

Ｂ１０には
=IF(A1="","",INDEX(B1:B5,COUNT(B1:B5))-VLOOKUP(INDEX(A1:A5,COUNTA(A1:A5)),検索対象範囲,2,FALSE))
といった具合に。

お礼

返信遅れました、すみません。

keithinさんの式でうまくいきました。

ありがとうございます。

また機会があればお願いいたします。

回答No.1

tom04

こんばんは！
一例です。

A10セル（セルの表示形式は「時刻」）に

=IF(COUNTA(A1:A5),INDEX(B1:B5,MAX(IF(A1:A5<>"",ROW(A1:A5))))-VLOOKUP(INDEX(A1:A5,MAX(IF(A1:A5<>"",ROW(A1:A5)))),A20:B25,2,0),"")

これは配列数式になってしまいますので、Shift＋Ctrl＋Enterキーで確定します。
この画面からコピー＆ペーストする場合はA10セルに貼り付け後、数式バー内で一度クリック！
編集可能になりますので、Shift＋Ctrlキーを押しながらEnterキーで確定！
数式の前後に｛　｝マークが入り配列数式になります。

※　もっと簡単な式になる方法があるかもしれません。
参考になりますかね？m(_ _)m

お礼

返信が遅れました。

tom04さん、回答ありがとうございます。

うまく出来ましたが、ちょっとこの式は私には難しい・・・

また何かあればお願いいたします。