エクセルで2行あきのデータの最小値を抽出したいです

質問

エクセル2007を使って、2行あきのデータの最小金額と、
その最小値の品物を表示させたいと思っています。

↓データはこのようになっています。
ファイルは、
・品物購入シート
・最小値抽出シート　の2シートあり、
品物購入シートの2行おきの最小値を　最小値抽出シートへ
表示させたいと思っています。
　2行おきにしたいのは、品物の名前が、順番に合板、ペンキ、ネジ、
合板、ペンキ、ネジ．．．と同じ順番んで並んでいるためなのですが、
INDEXやMATCH関数を使ってみましたが、エラーで結果がでません
でした。

《品物購入シート》
　　　Ａ、　　Ｂ、　　Ｃ、
1　金額、品物、購入日
2　120、合板、7/1
3　400、ペンキ、7/1
4　100、ネジ、6/1
5　240、合板、6/1
6　200、ペンキ、6/2
7　150、ネジ、7/2
・
・
データが40行くらいあります。

《最小値抽出シート》
　　　Ａ、　　Ｂ、　　Ｃ、
1　金額、品物、購入日
2　120、合板、7/1
3　200、ペンキ、6/2
4　150、ネジ、7/2

最少金額を↓このように考えてみましたが、VALUEのエラーがでてしまいました。
=IF(COUNT(MOD(ROW(),2)),MIN(MOD(ROW(),2),"-"))

説明がうまくできず申し訳ないですが、詳しい方どうか教えてください
よろしくお願いします。

回答No.1

keithin · ベストアンサー

「２行おき」のように不確定な計算ではなく，しっかり品目名をキーにして集計してみます。

手順：
抽出シートのＢ２，Ｂ３，Ｂ４にそれぞれ「合板」「ペンキ」「ねじ」を記入します。
Ａ２には
=MIN(IF(購入!B:B=B2,購入!A:A))
と記入し，コントロールキーとシフトキーを押しながらEnterします

Ｃ２には
=MIN(IF((購入!A:A=A2)*(購入!B:B=B2),購入!C:C))
と記入し，コントロールキーとシフトキーを押しながらEnterします
日付の書式を施し，下向けにコピーします

お礼

早い回答ありがとうございました。

試してみたらうまくできました。

すごく助かりました。
ありがとうございました。

回答No.5

imogasi

配列数式で許される件数なら
例データ　Ａ２：Ｅ１３
だたし、Ｃ，Ｄ，Ｅ列は参考のためにＢ列と同じ数字を列をずらして書いているだけ。
元データはＡ，Ｂ列
a 12 12
b 21 - 21
c 14 - - 14
a 12 12
b 9 - 9
c 24 - - 24
a 7 7
b 15 - 15
c 13 - - 13
a 32 32
b 14 - 14
c 23 - - 23
ーーーー
最大値と最小値を出してみると
Ｓ＋Ｃ＋ＥはＳｈｉｆｔｔｐＣＴＲＬとＥｎｔｅｒキーを同時押しすること
Ｆ３の式　=MAX(IF(MOD(ROW($A$2:$A$14),3)=0,$B$2:$B$13,0))　と入れて　Ｓ＋Ｃ＋Ｅ
Ｇ３は　=MIN(IF(MOD(ROW($A$2:$A$14),3)=0,$B$2:$B$13,""))　と入れて　Ｓ＋Ｃ＋Ｅ
Ｆ４は　=MAX(IF(MOD(ROW($A$2:$A$13),3)=1,$B$2:$B$13,0))　と入れて　Ｓ＋Ｃ＋Ｅ
Ｇ４は　=MIN(IF(MOD(ROW($A$2:$A$13),3)=1,$B$2:$B$13,""))　と入れて　Ｓ＋Ｃ＋Ｅ
Ｆ５は　=MAX(IF(MOD(ROW($A$2:$A$13),3)=2,$B$2:$B$13,0))　と入れて　Ｓ＋Ｃ＋Ｅ
Ｇ５は　=MIN(IF(MOD(ROW($A$2:$A$13),3)=2,$B$2:$B$13,""))　と入れて　Ｓ＋Ｃ＋Ｅ
ーー
結果　Ｆ３：Ｇ５
21 9
24 13
32 7
上記データ例のＣ，Ｄ，Ｅ列のデータで確認できる。

お礼

配列関数詳しくキーボードの打ち方も書いてくださり
ありがとうございます。

質問以外の応用できる
最大値の出し方も書いてくださてありがとうございました。

配列関数はかなり多いデータでもできるのですね。

回答ありがとうございました。

回答No.4

mu2011

関数を使用しない方法は如何でしょうか。
（１）最小値抽出シートにデータコピー
（２）金額列で並び替え（昇順）
（３）金額列で重複削除
因みにマクロ記録させておくと操作が簡単です。

お礼

回答ありがとうございます。

関数やピボットテーブル以外にも
方法があるのですね

勉強しなります。

ありがとうございました。

回答No.3

KURUMITO

最小値抽出シートのA列には品物名を入力することにしてA2セルには合板、A3セルにはペンキ、A4セルにはネジのように入力します。
B列には金額を表示させることにしてB2セルには次の式を入力し式を確定する段階でCtrlキーとShiftキーを押しながらEnterキーを押します。その後に式を下方にオートフィルドラッグします。

=IF(A2="","",MIN(IF(品物購入!B$1:B$50=A2,品物購入!A$1:A$50)))

C列には購入日を表示させることにしてC2セルには次の式を入力して下方にオートフィルドラッグします。

=IF(A2="","",INDEX(品物購入!C$1:C$50,SUMPRODUCT((品物購入!B$1:B$50=A2)*（品物購入!A$1:A$50=B2)*ROW(A$1:A$50))))

なお、C列の表示形式は日付にします。

お礼

丁寧に回答いただいてすごくわかりやすかったです。
ありがとうございます。

試してみたらうまくいきました。

回答ありがとうございました。

回答No.2

muunoy

関数ではなく、ピボットテーブルを使ってみてはどうですか？
結果をどのように使用しているかわからないので、参考にならなかったらごめんなさい。

全データあわせて、何行あるのかわからないので、最良の方法とは言えないかもしれません。

お礼

ピボットテーブル知らなかったので検索してみました、
初めて機能をしりました。
エクセル＝関数みたいに思っていたので
勉強になりました。

たくさんデータ、抽出項目がある時
また勉強して使ってみたいです。

回答ありがとうございました。