Excel計算式 条件によって計算範囲を変えたい

質問

Ａ　　　　　Ｂ　　　　Ｃ　　　　　Ｄ　　　　Ｅ　　　　　Ｆ　　　　Ｇ　　　　Ｈ　　　・・・　
１　日　　　　月　　　　火　　　　水　　　　木　　　　金　　　　土　　　　日　　　・・・
２　100　　　　　　 　　　　　　　500　　　　　　　　　200　　　　　　　　　100　　・・・
３ 2000　　5000　　　6000　　7000　　　4000　　3000　　　5000　　3000 ・・・
４

上記の表において、4行目に下記の計算をしたいです。
どのような計算式を組めば可能でしょうか？

・1行目が”日”または”月”→（３行目の数値）-（４列前までの2行目の合計）
例）Ｈ４＝3000-（500+200+100）＝2200

・1行目が”日””月”以外→（3行目の数値）-（３列前までの２行目の合計）
例）Ｇ4＝5000-（500+200）＝4300

ＯＲ、ＩＦなど組み合わせてみましたがうまくいきません。
回答よろしくお願いいたします。

回答No.6

keithin · ベストアンサー

３行目－（３列前まで）がデフォルトで，日月だけもう一つ余計に引き算するのでＯＫです。

Ｈ４に
=H3-SUM(E2:H2)-IF(OR(H1={"日","月"}),D2)
と記入し，左右のセルにコピーしておきます。

お礼

ありがとうございます！！
無事にできました。
私の知っている関数のみででき、感動したので
keithin様をベストアンサーにさせていただきます。

他の回答者様も、すべて試させていただき、
とても勉強になりました。

ありがとうございました。

回答No.7

mt2008

ANo.2です
特別な計算をするのは土日では無くて日月でしたね。失礼しました。
E4に入れるのは↓にしてください

曜日が文字列の場合
=E3-SUM(B2:E2)-(OR(E1="日",E1="月")*A2)

曜日がシリアル値の場合
=E3-SUM(B2:E2)-(WEEKDAY(E1)<3)*A2

回答No.5

mt2008

ANo.2です。

もし1行目の曜日が実際には日付のシリアル値が入っていて書式で曜日を表示しているなら、E4には↓を入れて右にコピーしてください。
=E3-SUM(B2:E2)-(WEEKDAY(E1+1)<3)*A2

回答No.4

mt2008

ANo.2です。

> A4:D4は、空欄でかまいませんのでよろしくお願いします。

では、E4セルに↓を入れて右にコピーでいかがでしょう
=E3-SUM(B2:E2)-(OR(E1="日",E1="土")*A2)

回答No.3

KURUMITO

A４セルには次の式を入力して右横方向にオートフィルドラッグします。

=IF(A$3="","",IF(OR(A1="日",A1="月"),A3-SUM(OFFSET(A2,0,-MIN(COUNTA($A$1:A$1)-1,4)):OFFSET(A2,0,0)),A3-SUM(OFFSET(A2,0,-MIN(COUNTA($A$1:A$1)-1,3)):OFFSET(A2,0,0))))

回答No.2

mt2008

補足願います。
A4:C4はどうするんですか？
３列前までの２行目の合計が出せませんよね？

補足

すみませんでした！
Ｄ４も４列前までの合計が出ないからダメですね。
（上記の表では日曜始まりですが、そうでない表も有りうるとして）
A4:D4は、空欄でかまいませんのでよろしくお願いします。

回答No.1

mshr1962

G4=G3-SUM(OFFSET(G2,,IF(OR(G1="日",G1="月"),-4,-3),,IF(OR(G1="日",G1="月"),5,4)))
H4=H3-SUM(OFFSET(H2,,IF(OR(H1="日",H1="月"),-4,-3),,IF(OR(H1="日",H1="月"),5,4)))