コマンドプロンプトの出力内容の加工の仕方について

質問

こんにちは、はじめまして。

コマンドプロンプトで、
あるフォルダの1つ下の階層にあるサブフォルダとの容量を一覧表示する事を考えています。
そのためには、diruseというコマンドがあるのですが、このコマンドでは、
フォルダ名の日本語の部分が表示されません。
そこでいろいろ調べてみて、
http://www.piedey.co.jp/softs/du.html　
からダウンロードしてきた、du.exeというコマンドを使ってみたのですが、
このコマンドは容量をバイト単位でしか表示できないようです。
具体的には、以下のような出力になります。

C:\Users\kei>du -t e:\
2387 e:\.ssh
10526355 e:\C++
79263 e:\Contacts

中略

8408619 e:\重要メール
3118299758 e:\

以下のようにduコマンドを実行した結果の1列目を、
1024(キロバイト単位)または1024×1024(メガバイト単位)で割った数値に変換し、
それ以外の部分はそのままで表示させる方法を、
Perlなどのテキスト処理ツールを使って試行錯誤しているのですが、
なかなかうまくいきません。
Cなどのプログラム言語を使わなくていい方法が知りたいと考えています。
何かいい方法が思い浮かぶ方がいらっしゃれば、アドバイスを頂きたいと思います。

以上、よろしくお願い致します。

回答No.1

Chronos198 · ベストアンサー

切り分けにはforを使う
計算にはset /aを使う
ただしset/aは小数点以下の計算が出来ないから、そこは自分で作る

具体的には
@echo off

for /f "usebackq tokens=1,*" %%i in ( `du -t e:\` ) do (
echo %%iB %%j
call :b2k %%i "%%j"
call :b2m %%i "%%j"
echo.
)
pause>NUL

exit 0

:b2k
set num=%~1
set /a K=1024
set /a int=%1 / %K%
set /a dec1= (( %num% %% %K% ) * 10 ) / %K%
set /a dec2=(((( %num% %% %K% ) * 10 ) %% %K% ) * 10 ) / %K%
set KB=%int%.%dec1%%dec2%
echo %KB%KB %~2
exit /b 0

:b2m
set num=%~1
set /a M=1024*1024
set /a int=%1 / %M%
set /a dec1= (( %num% %% %M% ) * 10 ) / %M%
set /a dec2=(((( %num% %% %M% ) * 10 ) %% %M% ) * 10 ) / %M%
set MB=%int%.%dec1%%dec2%
echo %MB%MB %~2
exit /b 0
みたいな感じ。

ざっくり作ったんで小数点以下第二位までの表示、かつ第三位の四捨五入とかはしてないです。
適当にいじってみてください。

お礼

Chronos198さん
大変ご丁寧な説明をありがとうございます。
是非、参考にさせていただきます。

補足

かなりスキルがある方のようだったので、追加で質問をさせていただきたいと思います。

コマンドプロンプトのバッチファイルを実行した場合、
コマンド履歴が消えてしまい、↑ボタンでコマンドをさかのぼれなくなってしまうようです。
これを回避する方法はないのでしょうか?