エクセルで納品書を作りたいです。

質問

エクセルで納品書を作りたいです。

シート１の当日出荷リストの並びは得意先が順不同。

Ａ１：得意先番号　　Ｂ１：商品名　　Ｃ１：数量
100　　　　　　　　　　りんご　　　　　　　２０
110　　　　　　　　　　ぶどう　　　　　　　１０
100　　　　　　　　　　みかん　　　　　　 ２０
110 　　 メロン　　　　　　　　５
120　　　　　　　　　　いちご　　　　　　 ３０
100　　　　　　　　　　りんご　　　　　　　１０
　・
　・
　・
１０００行まで得意先が不順に並んでいる中から

シート２に関数を使いリンクさせ納品書を作る方法を教えて下さい。

シート２のＡ１に得意先番号１００を入力すると・・・

Ｂ２に　　りんご　　　Ｃ２に　２０
Ｂ３に　　みかん　　 Ｃ３に　２０
Ｂ４に　　りんご　　　Ｃ４に　１０

というようにシート１より抜粋させたいのですが、関数を教えてください。

回答No.2

tom04 · ベストアンサー

こんばんは！
一例です。
↓の画像で説明させていただきます。

まず、Sheet1に作業用の列を設けています。
作業列D2セルに
=IF(OR(Sheet2!$A$2="",A2<>Sheet2!$A$2),"",ROW(A1))
という数式を入れ、フィルハンドルの（＋）マークでダブルクリック、又はオートフィルで下へコピーします。

そして、Sheet2のB2セルに
=IF(COUNT(Sheet1!$D$2:$D$2000)<ROW(A1),"",INDEX(Sheet1!B$2:B$2000,SMALL(Sheet1!$D$2:$D$2000,ROW(A1))))
という数式を入れ、列方向と行方向にオートフィルでコピーすると
画像のような感じになります。
尚、数式はSheet1の2000行目まで対応できるようにしています。

以上、参考になれば幸いです。m(__)m

回答No.4

某HN クロメート(Chromate)（@CoalTar）

>>同じようなことをしたい問い合わせが過去にありますので、参考にしてください。
リンクが張り付いていないので補足
http://okwave.jp/qa/q5917603.html
ほかに
EXCELのどの関数を使って操作すればいいのかわかりません！！
http://okwave.jp/qa/q5922094.html

オートフィルタでコピペが楽なような気もしますが、数式で
D1セル 0
D2セル =(A2=$G$1)+D1
G2セル =MAX(D:D)
F5セル =IF(ROW(A1)>$G$2,"",ROW(A1))
I5セル =MATCH(F5-1,D:D)+1
G5セル =IF($F5="","",INDEX(B:B,I5)) 右へオートフィル
F5:I5セル範囲を下へオートフィル
F:I列をきりとって 別シートへ貼り付け
添付図参照 参考まで

回答No.3

keithin

既に回答は出ていますので，参考に少し簡単な方法です。

添付図：
シート１
Ａ列番号　A2　=IF(B2=Sheet2!$A$2,COUNT($A$1:A1)+1,"")
Ｂ列得意先番号
Ｃ列商品
Ｄ列数量

シート２
得意先番号　　A2　100　など
Ａ列納品番号　A5　=IF(ROW(A1)>MAX(Sheet1!A:A),"",ROW(A1))
Ｂ列商品　　　B5　=IF($A5="","",VLOOKUP($A5,Sheet1!$A:$D,3))
Ｃ列数量　　　C5　=IF($A5="","",VLOOKUP($A5,Sheet1!$A:$D,4))

回答No.1

layy

同じようなことをしたい問い合わせが過去にありますので、参考にしてください。
OFFICEカテゴリにて
「エクセル、マクロにて月を指定して別シートに表示はできるのでしょうか？」
シート２にて検索条件を入力し、シート１の該当する明細を判定し
結果をシート２に列挙するものです。４ページ目付近、最近です。

関数ではなく、ＶＢＡを使うと実現します。
範囲の先頭から順番にセルの値を判定し、
セル位置を下（＝１０００）へ順番にカウントアップしていきます。
値がヒットした場合は、セル内容をシート２へ設定、
値がヒットしない場合は、セル位置を１つ下へ移動、
これの繰り返しです。
シート１の内容をシート２へ、というのはセル指定の前にシート名を付与すると
できます。

ＶＢＡについてはこういうサイトを探してみることです。
ExcelVBAへの道
http://www.voicechatjapan.com/excelvba/p4.html

補足

アドバイスありがとうございます。
エクセルは初心者の為、ExcelVBAへの道でＶＢＡの手順など見てみたのですが
良く分かりません。
手順を教えていただけると助かります。宜しくお願いいたします。