sedを使用しないで改名する方法

質問

Windows2003 Serverでデーターを月1でデーターを取得するバッチファイルを使用しているのですがセキュリティポリシーでマイクロソフトが提供しているソフト、またはWSHかバッチしか使用できなくなり、sedの使用が出来なくなりました。
教えていただきたいのは、sedを使用せず改名をする方法が存在するのでしょうか？

現在の仕様
毎月1日に、前月分の1日から最新のデーターを取得する。
例：10月1日に実行の場合は、9月1日のデーターから最新まで取得

バッチファイル
date/t > date.txt
sed -e s/\//-/g date.txt > date1.txt
sed -e s/[0-9][0-9]//1 -e s/[0-9][0-9]//2 -e s/[0-9][0-9]//2 -e s/-//g date1.txt > date2.txt
FOR /F %%Y IN (date2.txt) DO SET YY=%%Y
sed -e s/[0-9][0-9]//1 -e s/[0-9][0-9]//1 -e s/[0-9][0-9]//2 -e
sed -e s/[0-9][0-9]//1 -e s/[0-9][0-9]//1 -e s/[0-9][0-9]//2 -e s/-//g date1.txt > date3.txt
FOR /F %%M IN (date3.txt) DO SET DT=%%M

if %YY%%DT%==0901 set MM=12
if %YY%%DT%==0901 set YY=08
if %YY%%DT%==1001 set MM=12
if %YY%%DT%==1001 set YY=09
if %YY%%DT%==1101 set MM=12
if %YY%%DT%==1101 set YY=10

if %DT%==02 set MM=01
if %DT%==03 set MM=02
if %DT%==04 set MM=03
if %DT%==05 set MM=04
if %DT%==06 set MM=05
if %DT%==07 set MM=06
if %DT%==08 set MM=07
if %DT%==09 set MM=08
if %DT%==10 set MM=09
if %DT%==11 set MM=10
if %DT%==12 set MM=11

mkdir c:\%YY%%MM%

xcopy C:\"Program Files"\AAA\LOG\MAIN* c:\%YY%%MM% /d:%MM%-01-%YY%

回答No.2

pita-gora · ベストアンサー

提示されているバッチファイルを見ると、sedを使って date /t の出力から年（下2桁）と
月を取得して、それぞれYYとDTに代入し、最終的に1ヶ月前の月をMMに代入しているように
見受けられます（間違っていたらご指摘ください）。

この前提に従ってsedを使わずにバッチだけで記述した場合のサンプルです。
2003 Server での確認ができないのでXPで動作確認しています。

:--------------------------------------------- sample.bat

:現在日付の取得（"/"の削除）
set tmpdate=%date:/=%

:計算のためYYYYMMを6桁で取得
set YYYYMM=%tmpdate:~0,6%

:前月を求める
set /a YYYYMM=YYYYMM-1

:年をまたがる場合
if %YYYYMM:~-2%==00 set /a YYYYMM=YYYYMM - 100 + 12

:YYYYMMから年下2桁と月を取得
set YY=%YYYYMM:~2,2%
set MM=%YYYYMM:~-2%

mkdir c:\%YY%%MM%

xcopy C:\"Program Files"\AAA\LOG\MAIN* c:\%YY%%MM% /d:%MM%-01-%YY%

回答No.1

6chan

VBScript には、「RegExp」という正規表現用のオブジェクトが用意されています。 wshで、sedに相当するスクリプトを記述できるのではないでしょうか。