マクロの記録で作ったのですが、バックヤードで可動するようにできないでしょうか？よろしくお願いします

質問

下記のマクロを記録で作成したのですが素人のためこれ以上がわかりません。
やりたいことは、バックヤードで可動するようにしたいのと、
（現在はシートが移動したりマウスを動かすと読み込む時間がずれます）
実行間隔を任意で指定したセルから実行間隔を取得したいのですが。
よろしくお願いします。
下記のマクロはデータロガーから信号を定期的に記録でするにしてあります。

Sub Macro2()
'

Sheets("表示").Select
Range("B10:D10").Select
Selection.Copy
Sheets("DATA").Select
Range("A1").Select
Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
False, Transpose:=False
Application.CutCopyMode = False
Selection.Insert Shift:=xlDown
If Range("J8").Value = 999 Then
Application.Run "ストップ3"
Else
Application.Run "Macro3"
End If

End Sub

Sub Macro3()

Sheets("DATA").Select
Range("J8").Select
Selection.ClearContents
実行間隔 = Now + TimeValue("00:00:05")

Application.OnTime TimeValue(実行間隔), "Macro2"

End Sub
Sub ストップ3()
Sheets("DATA").Select
Range("J8").Value = 999
End Sub

回答No.2

merlionXX · ベストアンサー

> 動きが渋くなり実行間隔が延びてしまいます。

このマクロ以外に別のコードを走らせてデータを取得しているのでしょう？
その処理に時間がかかるのではないでしょうか。
下記のコードをこちらのエクセル2000で実行すると、5秒を指定するとほぼ5秒間隔で作動しました。（これ以外何のマクロも動かしてないからでしょうけど）

Sub Macro2()
With Sheets("DATA")
Application.Calculation = xlCalculationManual
.Range("A1:C1").Value = Sheets("表示").Range("B10:D10").Value
.Range("A1:C1").Insert Shift:=xlDown
Application.Calculation = xlCalculationAutomatic
If .Range("J8").Value = 999 Then
Application.Run "ストップ3"
Else
Application.Run "Macro3"
End If
End With
End Sub

Sub Macro3()
Dim s As String
With Sheets("DATA")
.Range("J8").ClearContents
s = "00:00:" & Format(.Range("J7"), "00")
Application.OnTime Now + TimeValue(s), "Macro2"
End With
End Sub

Sub ストップ3()
Sheets("DATA").Range("J8").Value = 999
End Sub

お礼

すいません。マクロの残骸が動いていたようです。
本当に助かりました、ありがとうございます。
がんばってVBAを勉強していきたいと思います。

回答No.1

merlionXX

勘違いしているかもしれませんが、マクロ作動時にシートが自動的に切り替わるのをやめ、実行間隔の秒数を任意のセルの数値とするということでしょうか。
秒数を入れるセルをDATAのJ7にした場合の例です。

Sub Macro2()
With Sheets("DATA")
.Range("A1:C1").Value = Sheets("表示").Range("B10:D10").Value
.Range("A1:C1").Insert Shift:=xlDown
If .Range("J8").Value = 999 Then
Application.Run "ストップ3"
Else
Application.Run "Macro3"
End If
End With
End Sub

Sub Macro3()
Dim s As String
With Sheets("DATA")
.Range("J8").ClearContents
s = "00:00:" & Format(.Range("J7"), "00")
実行間隔 = Now + TimeValue(s)
Application.OnTime TimeValue(実行間隔), "Macro2"
End With
End Sub

Sub ストップ3()
Sheets("DATA").Range("J8").Value = 999
End Sub

お礼

ありがとうございます。
試してみたのですが、動きが渋くなり実行間隔が延びてしまいます。
どうすれば良いのでしょうか？
例 5秒設定にすると、10秒ぐらい間隔で取得します。