エクセルで部分一致による自動計算

質問

先日も似たような質問をしたのですが、新たな問題が発生したので、
よろしくお願いいたします。
http://okwave.jp/qa4303345.html

sheet1のA列のセルには名前、B列のセルにはポイントが入力されているとします。
sheet2のA1セルに”田中”と入力した時にB1のセルに田中の総ポイントが自動表示されるにはどのようにすればよいでしょうか？

sheet1
　　　　A　　　　　B
１　田中・鈴木　　 ５
２　　 伊藤　　　　　８
３　　 田中　　　　　４

Sheet2
　　　　A　　　　　B
１　　 田中　 　 ９

回答No.1

mu2011 · ベストアンサー

一例です。
Sheet2のB1に=SUMPRODUCT(NOT(ISERROR(FIND($A1,Sheet1!$A$1:$A$100)))*Sheet1!$B$1:$B$100)として、下方向にコピー

お礼

前回に続きありがとうございました。
上式により無事出来上がりました！

回答No.3

chie65536

=SUM(IF(FIND(A1,Sheet1!A$1:A$100&A1,1)<LEN(Sheet1!A$1:A$100),Sheet1!B$1:B$100,0))
の式でCtrl+Shift+Enter

この式はSUMPRODUCTよりも高速（SUMPRODUCTだと、要素数１００個の行列同士の積算になるので処理が遅くなる）

なお、上記の式では、以下のように「谷さんと谷本さんが区別出来ない」ので注意する事。

sheet1
　　　　A　　　　　B
１　谷・鈴木　　　　 ５
２　　 伊藤　　　　　８
３　　 谷本　　　　　４

Sheet2
　　　　A　　　　　B
１　　 谷　　 　 ９←ここは本当は５にならないといけない

このように「誰かの苗字が、他の人の苗字の一部になっている場合」は、FIND関数では「うまく判断できない」ので注意する事。こういう場合は、以下のようにデータの方を工夫する。

　　　　A　　　　　B
１　[谷]・鈴木　　　 ５
２　　 伊藤　　　　　８
３　　 谷本　　　　　４

Sheet2
　　　　A　　　　　B
１　　 [谷]　　 　 ５

先の例では「谷・鈴木」「谷本」の２つの中に「谷」が見付かるので誤動作する。

後の例では「[谷]・鈴木」のみの中に「[谷]」が見付かるので正常に動作する。

こういう例は「長谷川と長谷」や「小林と林」や「成瀬川と成瀬」などでも起きるので注意。

お礼

丁寧なご回答ありがとうございます。
苗字の重なりによる誤動作には注意ですね。

回答No.2

sige1701

こんな感じかな
=SUMIF(Sheet1!A:A,"*"&A1&"*",Sheet1!B:B)